kde-apps/okular/okular-17.08.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_HANDBOOK="forceoptional"
   7 KDE_TEST="forceoptional"
   8 VIRTUALX_REQUIRED="test"
   9 inherit kde5
  10
  11 DESCRIPTION="Universal document viewer based on KDE Frameworks"
  12 HOMEPAGE="https://okular.kde.org https://www.kde.org/applications/graphics/okular"
  13 KEYWORDS="amd64 x86"
  14 IUSE="chm crypt djvu epub +image-backend mobi mobile +pdf plucker +postscript speech +tiff"
  15
  16 DEPEND="
  17         $(add_frameworks_dep kactivities)
  18         $(add_frameworks_dep karchive)
  19         $(add_frameworks_dep kbookmarks)
  20         $(add_frameworks_dep kcompletion)
  21         $(add_frameworks_dep kconfig)
  22         $(add_frameworks_dep kconfigwidgets)
  23         $(add_frameworks_dep kcoreaddons)
  24         $(add_frameworks_dep kio)
  25         $(add_frameworks_dep kjs)
  26         $(add_frameworks_dep kparts)
  27         $(add_frameworks_dep kpty)
  28         $(add_frameworks_dep kwallet)
  29         $(add_frameworks_dep threadweaver)
  30         $(add_qt_dep qtdbus)
  31         $(add_qt_dep qtgui)
  32         $(add_qt_dep qtprintsupport)
  33         $(add_qt_dep qtsvg)
  34         $(add_qt_dep qtwidgets)
  35         media-libs/freetype
  36         media-libs/phonon[qt5(+)]
  37         sys-libs/zlib
  38         chm? (
  39                 $(add_frameworks_dep khtml)
  40                 dev-libs/chmlib
  41         )
  42         crypt? ( app-crypt/qca:2[qt5] )
  43         djvu? ( app-text/djvu )
  44         epub? ( app-text/ebook-tools )
  45         image-backend? (
  46                 $(add_kdeapps_dep libkexiv2)
  47                 $(add_qt_dep qtgui 'gif,jpeg,png')
  48         )
  49         mobi? ( $(add_kdeapps_dep kdegraphics-mobipocket) )
  50         pdf? ( app-text/poppler[qt5,-exceptions(-)] )
  51         plucker? ( virtual/jpeg:0 )
  52         postscript? ( app-text/libspectre )
  53         speech? ( $(add_qt_dep qtspeech) )
  54         tiff? ( media-libs/tiff:0 )
  55 "
  56 RDEPEND="${DEPEND}
  57         image-backend? ( $(add_frameworks_dep kimageformats) )
  58         mobile? (
  59                 $(add_frameworks_dep kirigami)
  60                 $(add_qt_dep qtquickcontrols)
  61         )
  62 "
  63
  64 # bug 603116
  65 RESTRICT+=" test"
  66
  67 PATCHES=( "${FILESDIR}/${P}-cmake-3.10.patch" )
  68
  69 src_prepare() {
  70         kde5_src_prepare
  71         use mobile || cmake_comment_add_subdirectory mobile
  72         use test || cmake_comment_add_subdirectory conf/autotests
  73 }
  74
  75 src_configure() {
  76         local mycmakeargs=(
  77                 $(cmake-utils_use_find_package chm CHM)
  78                 $(cmake-utils_use_find_package crypt Qca-qt5)
  79                 $(cmake-utils_use_find_package djvu DjVuLibre)
  80                 $(cmake-utils_use_find_package epub EPub)
  81                 $(cmake-utils_use_find_package image-backend KF5KExiv2)
  82                 $(cmake-utils_use_find_package mobi QMobipocket)
  83                 $(cmake-utils_use_find_package pdf Poppler)
  84                 $(cmake-utils_use_find_package plucker JPEG)
  85                 $(cmake-utils_use_find_package postscript LibSpectre)
  86                 $(cmake-utils_use_find_package speech Qt5TextToSpeech)
  87                 $(cmake-utils_use_find_package tiff TIFF)
  88         )
  89
  90         kde5_src_configure
  91 }