kde-apps/marble/marble-19.04.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_HANDBOOK="optional" # see src/apps/marble-kde/CMakeLists.txt
   7 KDE_SUBSLOT="true"
   8 KDE_TEST="forceoptional"
   9 VIRTUALX_REQUIRED="test"
  10 inherit kde5
  11
  12 DESCRIPTION="Virtual Globe and World Atlas to learn more about Earth"
  13 HOMEPAGE="https://marble.kde.org/"
  14
  15 KEYWORDS="amd64 arm64 x86"
  16 IUSE="aprs +dbus designer gps +kde nls phonon +geolocation shapefile +webengine"
  17
  18 # FIXME (new package): libwlocate, WLAN-based geolocation
  19 BDEPEND="
  20         aprs? ( dev-lang/perl )
  21         nls? ( $(add_qt_dep linguist-tools) )
  22 "
  23 DEPEND="
  24         $(add_qt_dep qtconcurrent)
  25         $(add_qt_dep qtdeclarative)
  26         $(add_qt_dep qtgui)
  27         $(add_qt_dep qtnetwork)
  28         $(add_qt_dep qtprintsupport)
  29         $(add_qt_dep qtsql)
  30         $(add_qt_dep qtsvg)
  31         $(add_qt_dep qtwidgets)
  32         $(add_qt_dep qtxml)
  33         aprs? ( $(add_qt_dep qtserialport) )
  34         dbus? ( $(add_qt_dep qtdbus) )
  35         designer? ( $(add_qt_dep designer) )
  36         geolocation? ( $(add_qt_dep qtpositioning) )
  37         gps? ( sci-geosciences/gpsd )
  38         kde? (
  39                 $(add_frameworks_dep kconfig)
  40                 $(add_frameworks_dep kconfigwidgets)
  41                 $(add_frameworks_dep kcoreaddons)
  42                 $(add_frameworks_dep kcrash)
  43                 $(add_frameworks_dep ki18n)
  44                 $(add_frameworks_dep kio)
  45                 $(add_frameworks_dep knewstuff)
  46                 $(add_frameworks_dep kparts)
  47                 $(add_frameworks_dep krunner)
  48                 $(add_frameworks_dep kservice)
  49                 $(add_frameworks_dep kwallet)
  50         )
  51         phonon? ( media-libs/phonon[qt5(+)] )
  52         shapefile? ( sci-libs/shapelib:= )
  53         webengine? ( $(add_qt_dep qtwebengine 'widgets') )
  54 "
  55 RDEPEND="${DEPEND}"
  56
  57 # bug 588320
  58 RESTRICT+=" test"
  59
  60 src_prepare() {
  61         if use kde; then
  62                 sed -e "/add_subdirectory(marble-qt)/ s/^/#DONT/" \
  63                         -i src/apps/CMakeLists.txt \
  64                         || die "Failed to disable marble-qt"
  65         fi
  66
  67         kde5_src_prepare
  68 }
  69
  70 src_configure() {
  71         local mycmakeargs=(
  72                 $(cmake-utils_use_find_package aprs Perl)
  73                 $(cmake-utils_use_find_package geolocation Qt5Positioning)
  74                 -DBUILD_MARBLE_TESTS=$(usex test)
  75                 -DWITH_DESIGNER_PLUGIN=$(usex designer)
  76                 -DWITH_libgps=$(usex gps)
  77                 -DWITH_KF5=$(usex kde)
  78                 -DWITH_Phonon4Qt5=$(usex phonon)
  79                 -DWITH_libshp=$(usex shapefile)
  80                 $(cmake-utils_use_find_package webengine Qt5WebEngine)
  81                 $(cmake-utils_use_find_package webengine Qt5WebEngineWidgets)
  82                 -DWITH_libwlocate=OFF
  83                 # bug 608890
  84                 -DKDE_INSTALL_CONFDIR="/etc/xdg"
  85         )
  86         kde5_src_configure
  87 }