kde-apps/marble/marble-17.08.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_HANDBOOK="forceoptional"
   7 KDE_SUBSLOT="true"
   8 KDE_TEST="forceoptional"
   9 VIRTUALX_REQUIRED="test"
  10 inherit kde5
  11
  12 DESCRIPTION="Virtual Globe and World Atlas to learn more about Earth"
  13 HOMEPAGE="https://marble.kde.org/"
  14 KEYWORDS="amd64 x86"
  15
  16 IUSE="aprs +dbus designer gps +kde nls phonon +geolocation shapefile +webkit"
  17
  18 # FIXME (new package): libwlocate, WLAN-based geolocation
  19 RDEPEND="
  20         $(add_qt_dep qtconcurrent)
  21         $(add_qt_dep qtdeclarative)
  22         $(add_qt_dep qtgui)
  23         $(add_qt_dep qtnetwork)
  24         $(add_qt_dep qtprintsupport)
  25         $(add_qt_dep qtsql)
  26         $(add_qt_dep qtsvg)
  27         $(add_qt_dep qtwidgets)
  28         $(add_qt_dep qtxml)
  29         aprs? ( $(add_qt_dep qtserialport) )
  30         dbus? ( $(add_qt_dep qtdbus) )
  31         designer? ( $(add_qt_dep designer) )
  32         geolocation? ( $(add_qt_dep qtpositioning) )
  33         gps? ( sci-geosciences/gpsd )
  34         kde? (
  35                 $(add_frameworks_dep kconfig)
  36                 $(add_frameworks_dep kconfigwidgets)
  37                 $(add_frameworks_dep kcoreaddons)
  38                 $(add_frameworks_dep kcrash)
  39                 $(add_frameworks_dep ki18n)
  40                 $(add_frameworks_dep kio)
  41                 $(add_frameworks_dep knewstuff)
  42                 $(add_frameworks_dep kparts)
  43                 $(add_frameworks_dep krunner)
  44                 $(add_frameworks_dep kservice)
  45                 $(add_frameworks_dep kwallet)
  46         )
  47         phonon? ( media-libs/phonon[qt5(+)] )
  48         shapefile? ( sci-libs/shapelib:= )
  49         webkit? ( $(add_qt_dep qtwebkit) )
  50 "
  51 DEPEND="${RDEPEND}
  52         aprs? ( dev-lang/perl )
  53         nls? ( $(add_qt_dep linguist-tools) )
  54 "
  55
  56 # bug 588320
  57 RESTRICT+=" test"
  58
  59 src_prepare() {
  60         if use kde; then
  61                 sed -e "/add_subdirectory(marble-qt)/ s/^/#DONT/" \
  62                         -i src/apps/CMakeLists.txt \
  63                         || die "Failed to disable marble-qt"
  64         fi
  65
  66         kde5_src_prepare
  67 }
  68
  69 src_configure() {
  70         local mycmakeargs=(
  71                 $(cmake-utils_use_find_package aprs Perl)
  72                 $(cmake-utils_use_find_package geolocation Qt5Positioning)
  73                 -DBUILD_MARBLE_TESTS=$(usex test)
  74                 -DWITH_DESIGNER_PLUGIN=$(usex designer)
  75                 -DWITH_libgps=$(usex gps)
  76                 -DWITH_KF5=$(usex kde)
  77                 -DWITH_Phonon4Qt5=$(usex phonon)
  78                 -DWITH_libshp=$(usex shapefile)
  79                 $(cmake-utils_use_find_package webkit Qt5WebKit)
  80                 $(cmake-utils_use_find_package webkit Qt5WebKitWidgets)
  81                 -DWITH_libwlocate=OFF
  82                 # bug 608890
  83                 -DKDE_INSTALL_CONFDIR="/etc/xdg"
  84         )
  85         kde5_src_configure
  86 }