kde-apps/marble/marble-16.04.3.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 KDE_HANDBOOK="forceoptional"
   8 KDE_TEST="forceoptional"
   9 VIRTUALX_REQUIRED="test"
  10 inherit kde5
  11
  12 DESCRIPTION="Generic geographical map widget"
  13 HOMEPAGE="https://marble.kde.org/"
  14 KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
  15
  16 IUSE="aprs designer-plugin gps +kde phonon shapefile"
  17
  18 # FIXME (new packages):
  19 # libwlocate, WLAN-based geolocation
  20 # qextserialport, interface to old fashioned serial ports
  21 RDEPEND="
  22         $(add_qt_dep qtconcurrent)
  23         $(add_qt_dep qtdbus)
  24         $(add_qt_dep qtdeclarative)
  25         $(add_qt_dep qtgui)
  26         $(add_qt_dep qtnetwork)
  27         $(add_qt_dep qtopengl)
  28         $(add_qt_dep qtprintsupport)
  29         $(add_qt_dep qtscript)
  30         $(add_qt_dep qtsql)
  31         $(add_qt_dep qtsvg)
  32         $(add_qt_dep qtwebkit)
  33         $(add_qt_dep qtwidgets)
  34         $(add_qt_dep qtxml)
  35         gps? ( >=sci-geosciences/gpsd-2.95 )
  36         kde? (
  37                 $(add_frameworks_dep kconfig)
  38                 $(add_frameworks_dep kconfigwidgets)
  39                 $(add_frameworks_dep kcoreaddons)
  40                 $(add_frameworks_dep kcrash)
  41                 $(add_frameworks_dep ki18n)
  42                 $(add_frameworks_dep kio)
  43                 $(add_frameworks_dep knewstuff)
  44                 $(add_frameworks_dep kparts)
  45                 $(add_frameworks_dep krunner)
  46                 $(add_frameworks_dep kservice)
  47                 $(add_frameworks_dep kwallet)
  48         )
  49         phonon? ( media-libs/phonon[qt5] )
  50         shapefile? ( sci-libs/shapelib )
  51 "
  52 DEPEND="${RDEPEND}
  53         aprs? ( dev-lang/perl )
  54 "
  55
  56 # bug 588320
  57 RESTRICT=test
  58
  59 src_configure() {
  60         local mycmakeargs=(
  61                 $(cmake-utils_use_find_package aprs Perl)
  62                 -DBUILD_MARBLE_TESTS=$(usex test)
  63                 -DWITH_DESIGNER_PLUGIN=$(usex designer-plugin)
  64                 -DWITH_libgps=$(usex gps)
  65                 -DWITH_KF5=$(usex kde)
  66                 -DWITH_Phonon=$(usex phonon)
  67                 -DWITH_libshp=$(usex shapefile)
  68                 -DWITH_QextSerialPort=OFF
  69                 -DWITH_liblocation=0
  70         )
  71         kde5_src_configure
  72 }