kde-apps/marble/marble-15.12.3.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 KDE_HANDBOOK="forceoptional"
   8 KDE_TEST="forceoptional"
   9 inherit kde5
  10
  11 DESCRIPTION="Generic geographical map widget"
  12 HOMEPAGE="https://marble.kde.org/"
  13 KEYWORDS=" ~amd64 ~x86"
  14
  15 IUSE="aprs designer-plugin gps +kde phonon shapefile"
  16
  17 # FIXME (new packages):
  18 # libwlocate, WLAN-based geolocation
  19 # qextserialport, interface to old fashioned serial ports
  20 RDEPEND="
  21         $(add_qt_dep qtconcurrent)
  22         $(add_qt_dep qtdbus)
  23         $(add_qt_dep qtdeclarative)
  24         $(add_qt_dep qtgui)
  25         $(add_qt_dep qtnetwork)
  26         $(add_qt_dep qtopengl)
  27         $(add_qt_dep qtprintsupport)
  28         $(add_qt_dep qtscript)
  29         $(add_qt_dep qtsql)
  30         $(add_qt_dep qtsvg)
  31         $(add_qt_dep qtwebkit)
  32         $(add_qt_dep qtwidgets)
  33         $(add_qt_dep qtxml)
  34         gps? ( >=sci-geosciences/gpsd-2.95 )
  35         kde? (
  36                 $(add_frameworks_dep kconfig)
  37                 $(add_frameworks_dep kconfigwidgets)
  38                 $(add_frameworks_dep kcoreaddons)
  39                 $(add_frameworks_dep kcrash)
  40                 $(add_frameworks_dep ki18n)
  41                 $(add_frameworks_dep kio)
  42                 $(add_frameworks_dep knewstuff)
  43                 $(add_frameworks_dep kparts)
  44                 $(add_frameworks_dep krunner)
  45                 $(add_frameworks_dep kservice)
  46                 $(add_frameworks_dep kwallet)
  47         )
  48         phonon? ( media-libs/phonon[qt5] )
  49         shapefile? ( sci-libs/shapelib )
  50 "
  51 DEPEND="${RDEPEND}
  52         aprs? ( dev-lang/perl )
  53 "
  54
  55 src_configure() {
  56         local mycmakeargs=(
  57                 $(cmake-utils_use_find_package aprs Perl)
  58                 -DBUILD_MARBLE_TESTS=$(usex test)
  59                 -DWITH_DESIGNER_PLUGIN=$(usex designer-plugin)
  60                 -DWITH_libgps=$(usex gps)
  61                 -DWITH_KF5=$(usex kde)
  62                 -DWITH_Phonon=$(usex phonon)
  63                 -DWITH_libshp=$(usex shapefile)
  64                 -DWITH_QextSerialPort=OFF
  65                 -DWITH_liblocation=0
  66         )
  67         kde5_src_configure
  68 }