kde-apps/konqueror/konqueror-16.04.3-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 KDE_HANDBOOK="optional"
   8 KMNAME="kde-baseapps"
   9 inherit flag-o-matic kde4-meta
  10
  11 DESCRIPTION="Web browser and file manager"
  12 HOMEPAGE="
  13         https://www.kde.org/applications/internet/konqueror/
  14         https://konqueror.org/
  15 "
  16 KEYWORDS="amd64 ~arm x86"
  17 IUSE="+bookmarks debug +filemanager svg"
  18 # 4 of 4 tests fail. Last checked for 4.0.3
  19 RESTRICT="test"
  20
  21 DEPEND="
  22         $(add_kdeapps_dep libkonq)
  23         filemanager? (
  24                 $(add_kdebase_dep kactivities '' 4.13)
  25                 media-libs/phonon[qt4]
  26                 x11-libs/libXrender
  27         )
  28 "
  29
  30 # bug #544630: evince[nsplugin] crashes konqueror
  31 RDEPEND="${DEPEND}
  32         $(add_kdeapps_dep kfind)
  33         $(add_kdeapps_dep kfmclient)
  34         $(add_kdeapps_dep kurifilter-plugins)
  35         bookmarks? ( $(add_kdeapps_dep keditbookmarks) )
  36         filemanager? (
  37                 $(add_kdeapps_dep kdebase-kioslaves)
  38                 $(add_kdeapps_dep kfind)
  39                 $(add_kdeapps_dep konsolepart)
  40                 !kde-apps/dolphin:4
  41         )
  42         svg? ( $(add_kdeapps_dep svgpart) )
  43         !app-text/evince[nsplugin]
  44 "
  45
  46 KMEXTRA="
  47         dolphin/
  48 "
  49
  50 KMEXTRACTONLY="
  51         konqueror/client/
  52         lib/konq/
  53 "
  54
  55 src_prepare() {
  56         [[ ${CHOST} == *-solaris* ]] && append-ldflags -lmalloc
  57
  58         # required for dolphin
  59         sed -e "/konq_copytomenu.h/ s/# //" \
  60                 -e "/konq_copytomenu.h/ s/ - anyone needs it?//" \
  61                 -i lib/konq/CMakeLists.txt \
  62                 || die "Failed to fix libkonq CMakeLists.txt"
  63
  64         kde4-meta_src_prepare
  65
  66         use filemanager || cmake_comment_add_subdirectory dolphin
  67
  68         # Do not install *.desktop files for kfmclient
  69         sed -e "/kfmclient\.desktop/d" -i konqueror/CMakeLists.txt \
  70                 || die "Failed to omit .desktop files"
  71 }
  72
  73 src_configure() {
  74         local mycmakeargs
  75
  76         if use filemanager ; then
  77                 mycmakeargs=(
  78                         -DWITH_Baloo=OFF
  79                         -DWITH_BalooWidgets=OFF
  80                         -DWITH_KFileMetaData=OFF
  81                 )
  82         fi
  83
  84         kde4-meta_src_configure
  85 }
  86
  87 pkg_postinst() {
  88         kde4-meta_pkg_postinst
  89
  90         if use filemanager && ! has_version media-gfx/icoutils ; then
  91                 elog "For .exe file preview support, install media-gfx/icoutils."
  92         fi
  93
  94         if ! has_version virtual/jre ; then
  95                 elog "To use Java on webpages install virtual/jre."
  96         fi
  97 }