kde-apps/kmail/kmail-19.04.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_HANDBOOK="forceoptional"
   7 KDE_TEST="forceoptional"
   8 VIRTUALX_REQUIRED="test"
   9 inherit kde5
  10
  11 DESCRIPTION="Email client, supporting POP3 and IMAP mailboxes."
  12 HOMEPAGE="https://kde.org/applications/internet/kmail/"
  13 LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
  14 KEYWORDS="amd64 arm64 x86"
  15 IUSE=""
  16
  17 BDEPEND="
  18         dev-libs/libxslt
  19         test? ( $(add_kdeapps_dep akonadi 'tools') )
  20 "
  21 COMMON_DEPEND="
  22         $(add_frameworks_dep kbookmarks)
  23         $(add_frameworks_dep kcmutils)
  24         $(add_frameworks_dep kcodecs)
  25         $(add_frameworks_dep kcompletion)
  26         $(add_frameworks_dep kconfig)
  27         $(add_frameworks_dep kconfigwidgets)
  28         $(add_frameworks_dep kcoreaddons)
  29         $(add_frameworks_dep kcrash)
  30         $(add_frameworks_dep kdbusaddons)
  31         $(add_frameworks_dep kguiaddons)
  32         $(add_frameworks_dep ki18n)
  33         $(add_frameworks_dep kiconthemes)
  34         $(add_frameworks_dep kitemviews)
  35         $(add_frameworks_dep kio)
  36         $(add_frameworks_dep kjobwidgets)
  37         $(add_frameworks_dep knotifications)
  38         $(add_frameworks_dep knotifyconfig)
  39         $(add_frameworks_dep kparts)
  40         $(add_frameworks_dep kservice)
  41         $(add_frameworks_dep ktextwidgets)
  42         $(add_frameworks_dep kwidgetsaddons)
  43         $(add_frameworks_dep kwindowsystem)
  44         $(add_frameworks_dep kxmlgui)
  45         $(add_frameworks_dep sonnet)
  46         $(add_kdeapps_dep akonadi)
  47         $(add_kdeapps_dep akonadi-contacts)
  48         $(add_kdeapps_dep akonadi-mime)
  49         $(add_kdeapps_dep akonadi-search)
  50         $(add_kdeapps_dep kcalcore)
  51         $(add_kdeapps_dep kcontacts)
  52         $(add_kdeapps_dep kdepim-apps-libs)
  53         $(add_kdeapps_dep kidentitymanagement)
  54         $(add_kdeapps_dep kmailtransport)
  55         $(add_kdeapps_dep kmime)
  56         $(add_kdeapps_dep kontactinterface)
  57         $(add_kdeapps_dep kpimtextedit)
  58         $(add_kdeapps_dep libgravatar)
  59         $(add_kdeapps_dep libkdepim)
  60         $(add_kdeapps_dep libkleo)
  61         $(add_kdeapps_dep libksieve)
  62         $(add_kdeapps_dep libktnef)
  63         $(add_kdeapps_dep mailcommon)
  64         $(add_kdeapps_dep messagelib)
  65         $(add_kdeapps_dep pimcommon)
  66         $(add_qt_dep qtdbus)
  67         $(add_qt_dep qtgui)
  68         $(add_qt_dep qtnetwork)
  69         $(add_qt_dep qtwebengine 'widgets')
  70         $(add_qt_dep qtwidgets)
  71         >=app-crypt/gpgme-1.7.1[cxx,qt5]
  72 "
  73 DEPEND="${COMMON_DEPEND}
  74         $(add_kdeapps_dep kcalutils)
  75         $(add_kdeapps_dep kldap)
  76         test? ( $(add_kdeapps_dep akonadi 'sqlite') )
  77 "
  78 RDEPEND="${COMMON_DEPEND}
  79         !kde-apps/kdepim-common-libs:4
  80         !kde-apps/kdepim-l10n
  81         !kde-apps/ktnef
  82         $(add_kdeapps_dep kdepim-runtime)
  83         $(add_kdeapps_dep kmail-account-wizard)
  84 "
  85
  86 PATCHES=( "${FILESDIR}/${P}-missing-header.patch" )
  87
  88 RESTRICT+=" test" # bug 616878
  89
  90 src_prepare() {
  91         kde5_src_prepare
  92
  93         if ! use handbook; then
  94                 sed -i ktnef/CMakeLists.txt -e "/add_subdirectory(doc)/ s/^/#DONT/" || die
  95         fi
  96 }
  97
  98 pkg_postinst() {
  99         kde5_pkg_postinst
 100
 101         pkg_is_installed() {
 102                 echo "${1} ($(has_version ${1} || echo "not ")installed)"
 103         }
 104
 105         if [[ -z "${REPLACING_VERSIONS}" ]]; then
 106                 elog "KMail supports the following runtime dependencies:"
 107                 elog "  Virus detection:"
 108                 elog "    $(pkg_is_installed app-antivirus/clamav)"
 109                 elog "  Spam filtering:"
 110                 elog "    $(pkg_is_installed mail-filter/bogofilter)"
 111                 elog "    $(pkg_is_installed mail-filter/spamassassin)"
 112                 elog "  Fancy e-mail headers and various useful plugins:"
 113                 elog "    $(pkg_is_installed kde-apps/kdepim-addons:${SLOT})"
 114                 elog "  Crypto config and certificate details GUI:"
 115                 elog "    $(pkg_is_installed kde-apps/kleopatra:${SLOT})"
 116         fi
 117 }