kde-apps/kmail/kmail-17.08.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_HANDBOOK="forceoptional"
   7 KDE_TEST="forceoptional"
   8 VIRTUALX_REQUIRED="test"
   9 inherit kde5
  10
  11 DESCRIPTION="Email client, supporting POP3 and IMAP mailboxes."
  12 HOMEPAGE="https://www.kde.org/applications/internet/kmail/"
  13 LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
  14 KEYWORDS="amd64 x86"
  15 IUSE=""
  16
  17 COMMON_DEPEND="
  18         $(add_frameworks_dep kbookmarks)
  19         $(add_frameworks_dep kcmutils)
  20         $(add_frameworks_dep kcodecs)
  21         $(add_frameworks_dep kcompletion)
  22         $(add_frameworks_dep kconfig)
  23         $(add_frameworks_dep kconfigwidgets)
  24         $(add_frameworks_dep kcoreaddons)
  25         $(add_frameworks_dep kcrash)
  26         $(add_frameworks_dep kdbusaddons)
  27         $(add_frameworks_dep kguiaddons)
  28         $(add_frameworks_dep ki18n)
  29         $(add_frameworks_dep kiconthemes)
  30         $(add_frameworks_dep kitemviews)
  31         $(add_frameworks_dep kio)
  32         $(add_frameworks_dep kjobwidgets)
  33         $(add_frameworks_dep knotifications)
  34         $(add_frameworks_dep knotifyconfig)
  35         $(add_frameworks_dep kparts)
  36         $(add_frameworks_dep kservice)
  37         $(add_frameworks_dep ktextwidgets)
  38         $(add_frameworks_dep kwidgetsaddons)
  39         $(add_frameworks_dep kwindowsystem)
  40         $(add_frameworks_dep kxmlgui)
  41         $(add_frameworks_dep sonnet)
  42         $(add_kdeapps_dep akonadi)
  43         $(add_kdeapps_dep akonadi-contacts)
  44         $(add_kdeapps_dep akonadi-mime)
  45         $(add_kdeapps_dep akonadi-search)
  46         $(add_kdeapps_dep kcalcore)
  47         $(add_kdeapps_dep kcontacts)
  48         $(add_kdeapps_dep kdepim-apps-libs)
  49         $(add_kdeapps_dep kidentitymanagement)
  50         $(add_kdeapps_dep kmailtransport)
  51         $(add_kdeapps_dep kmime)
  52         $(add_kdeapps_dep kontactinterface)
  53         $(add_kdeapps_dep kpimtextedit)
  54         $(add_kdeapps_dep libgravatar)
  55         $(add_kdeapps_dep libkdepim)
  56         $(add_kdeapps_dep libkleo)
  57         $(add_kdeapps_dep libksieve)
  58         $(add_kdeapps_dep libktnef)
  59         $(add_kdeapps_dep mailcommon)
  60         $(add_kdeapps_dep messagelib)
  61         $(add_kdeapps_dep pimcommon)
  62         $(add_qt_dep qtdbus)
  63         $(add_qt_dep qtgui)
  64         $(add_qt_dep qtnetwork)
  65         $(add_qt_dep qtwebengine 'widgets')
  66         $(add_qt_dep qtwidgets)
  67         $(add_qt_dep qtxml)
  68         >=app-crypt/gpgme-1.7.1[cxx,qt5]
  69 "
  70 DEPEND="${COMMON_DEPEND}
  71         $(add_kdeapps_dep kcalutils)
  72         $(add_kdeapps_dep kldap)
  73         dev-libs/libxslt
  74         test? ( $(add_kdeapps_dep akonadi 'sqlite,tools') )
  75 "
  76 RDEPEND="${COMMON_DEPEND}
  77         !kde-apps/kdepim-common-libs:4
  78         !kde-apps/kdepim-l10n
  79         !kde-apps/ktnef
  80         $(add_kdeapps_dep kdepim-runtime)
  81 "
  82
  83 RESTRICT+=" test" # bug 616878
  84
  85 src_prepare() {
  86         cmake-utils_src_prepare
  87
  88         if ! use handbook; then
  89                 sed -i ktnef/CMakeLists.txt -e "/add_subdirectory(doc)/ s/^/#DONT/" || die
  90         fi
  91 }
  92
  93 pkg_postinst() {
  94         kde5_pkg_postinst
  95
  96         pkg_is_installed() {
  97                 echo "${1} ($(has_version ${1} || echo "not ")installed)"
  98         }
  99
 100         elog "KMail supports the following runtime dependencies:"
 101         elog "  Virus detection:"
 102         elog "    $(pkg_is_installed app-antivirus/clamav)"
 103         elog "  Spam filtering:"
 104         elog "    $(pkg_is_installed mail-filter/bogofilter)"
 105         elog "    $(pkg_is_installed mail-filter/spamassassin)"
 106         elog "  Fancy e-mail headers and various useful plugins:"
 107         elog "    $(pkg_is_installed kde-apps/kdepim-addons:${SLOT})"
 108         elog "  Crypto config and certificate details GUI:"
 109         elog "    $(pkg_is_installed kde-apps/kleopatra:${SLOT})"
 110 }