kde-apps/kdepimlibs/kdepimlibs-4.14.10.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 KDE_HANDBOOK="optional"
   8 CPPUNIT_REQUIRED="optional"
   9 EGIT_BRANCH="KDE/4.14"
  10 inherit kde4-base
  11
  12 DESCRIPTION="Common library for KDE PIM apps"
  13 KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
  14 LICENSE="LGPL-2.1"
  15 IUSE="debug ldap prison"
  16
  17 # some akonadi tests timeout, that probaly needs more work as its ~700 tests
  18 RESTRICT="test"
  19
  20 DEPEND="
  21         !kde-misc/akonadi-social-utils
  22         >=app-crypt/gpgme-1.1.6
  23         >=app-office/akonadi-server-1.12.90[qt4]
  24         >=dev-libs/boost-1.35.0-r5:=
  25         dev-libs/libgpg-error
  26         >=dev-libs/libical-0.48-r2:=
  27         dev-libs/cyrus-sasl
  28         >=dev-libs/qjson-0.8.1
  29         media-libs/phonon[qt4]
  30         x11-misc/shared-mime-info
  31         prison? ( media-libs/prison:4 )
  32         ldap? ( net-nds/openldap )
  33 "
  34 # boost is not linked to, but headers which include it are installed
  35 # bug #418071
  36 RDEPEND="${DEPEND}
  37         !=kde-apps/kdepim-runtime-4.10*
  38         !=kde-apps/kdepim-runtime-4.11*
  39         !<kde-apps/kdepim-runtime-4.4.11.1-r2:4
  40 "
  41
  42 PATCHES=( "${FILESDIR}/${PN}-4.9.1-boostincludes.patch" )
  43
  44 src_configure() {
  45         local mycmakeargs=(
  46                 $(cmake-utils_use_build handbook doc)
  47                 $(cmake-utils_use_find_package ldap)
  48                 $(cmake-utils_use_find_package prison)
  49         )
  50
  51         kde4-base_src_configure
  52 }
  53
  54 src_install() {
  55         kde4-base_src_install
  56         rm "${ED}"/usr/share/apps/cmake/modules/FindQtOAuth.cmake #Collides with net-im/choqok
  57 }