kde-apps/gwenview/gwenview-17.08.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_HANDBOOK="true"
   7 KDE_TEST="true"
   8 inherit kde5
   9
  10 DESCRIPTION="KDE image viewer"
  11 HOMEPAGE="
  12         https://www.kde.org/applications/graphics/gwenview/
  13         https://userbase.kde.org/Gwenview
  14 "
  15
  16 LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
  17 KEYWORDS="amd64 x86"
  18 IUSE="kipi raw semantic-desktop X"
  19
  20 # requires running environment
  21 RESTRICT+=" test"
  22
  23 COMMON_DEPEND="
  24         $(add_frameworks_dep kactivities)
  25         $(add_frameworks_dep kcompletion)
  26         $(add_frameworks_dep kconfig)
  27         $(add_frameworks_dep kconfigwidgets)
  28         $(add_frameworks_dep kcoreaddons)
  29         $(add_frameworks_dep ki18n)
  30         $(add_frameworks_dep kiconthemes)
  31         $(add_frameworks_dep kio)
  32         $(add_frameworks_dep kitemmodels)
  33         $(add_frameworks_dep kitemviews)
  34         $(add_frameworks_dep kjobwidgets)
  35         $(add_frameworks_dep knotifications)
  36         $(add_frameworks_dep kparts)
  37         $(add_frameworks_dep kservice)
  38         $(add_frameworks_dep ktextwidgets)
  39         $(add_frameworks_dep kwidgetsaddons)
  40         $(add_frameworks_dep kxmlgui)
  41         $(add_qt_dep qtgui)
  42         $(add_qt_dep qtopengl)
  43         $(add_qt_dep qtprintsupport)
  44         $(add_qt_dep qtsvg)
  45         $(add_qt_dep qtwidgets)
  46         media-gfx/exiv2:=
  47         media-libs/lcms:2
  48         media-libs/libpng:0=
  49         media-libs/phonon[qt5(+)]
  50         virtual/jpeg:0
  51         kipi? ( $(add_kdeapps_dep libkipi '' '' '5=') )
  52         raw? ( $(add_kdeapps_dep libkdcraw) )
  53         semantic-desktop? (
  54                 $(add_frameworks_dep baloo)
  55                 $(add_frameworks_dep kfilemetadata)
  56         )
  57         X? (
  58                 $(add_qt_dep qtx11extras)
  59                 x11-libs/libX11
  60         )
  61 "
  62 DEPEND="${COMMON_DEPEND}
  63         $(add_frameworks_dep kwindowsystem)
  64         $(add_qt_dep qtconcurrent)
  65 "
  66 RDEPEND="${COMMON_DEPEND}
  67         $(add_frameworks_dep kimageformats)
  68         $(add_qt_dep qtimageformats)
  69 "
  70
  71 src_configure() {
  72         local mycmakeargs=(
  73                 $(cmake-utils_use_find_package kipi KF5Kipi)
  74                 $(cmake-utils_use_find_package raw KF5KDcraw)
  75                 $(cmake-utils_use_find_package X X11)
  76         )
  77
  78         if use semantic-desktop; then
  79                 mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=Baloo)
  80         else
  81                 mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=None)
  82         fi
  83
  84         kde5_src_configure
  85 }
  86
  87 pkg_postinst() {
  88         kde5_pkg_postinst
  89
  90         if ! has_version kde-apps/svgpart:${SLOT} ; then
  91                 elog "For SVG support, install kde-apps/svgpart:${SLOT}"
  92         fi
  93
  94         if use kipi && ! has_version media-plugins/kipi-plugins ; then
  95                 elog "Plugins for the KIPI interface can be found in media-plugins/kipi-plugins"
  96         fi
  97 }