kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-18.12.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KMNAME="dolphin-plugins"
   7 KDE_HANDBOOK="false"
   8 MY_PLUGIN_NAME="hg"
   9 inherit kde5
  10
  11 DESCRIPTION="Dolphin plugin for Mercurial integration"
  12 KEYWORDS="amd64 x86"
  13 IUSE=""
  14
  15 DEPEND="
  16         $(add_frameworks_dep kcompletion)
  17         $(add_frameworks_dep kconfig)
  18         $(add_frameworks_dep kcoreaddons)
  19         $(add_frameworks_dep ki18n)
  20         $(add_frameworks_dep kio)
  21         $(add_frameworks_dep kservice)
  22         $(add_frameworks_dep ktexteditor)
  23         $(add_frameworks_dep ktextwidgets)
  24         $(add_frameworks_dep kwidgetsaddons)
  25         $(add_kdeapps_dep dolphin)
  26         $(add_qt_dep qtgui)
  27         $(add_qt_dep qtwidgets)
  28 "
  29 RDEPEND="${DEPEND}
  30         !kde-apps/dolphin-plugins:5
  31         dev-vcs/mercurial
  32 "
  33
  34 src_prepare() {
  35         kde5_src_prepare
  36         # kxmlgui, qtnetwork only required by dropbox
  37         punt_bogus_dep Qt5 Network
  38         punt_bogus_dep KF5 XmlGui
  39         # delete non-${PN} translations
  40         if [[ ${KDE_BUILD_TYPE} = release ]]; then
  41                 find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
  42         fi
  43 }
  44
  45 src_configure() {
  46         local mycmakeargs=(
  47                 -DBUILD_${MY_PLUGIN_NAME}=ON
  48                 -DBUILD_bazaar=OFF
  49                 -DBUILD_dropbox=OFF
  50                 -DBUILD_git=OFF
  51                 -DBUILD_svn=OFF
  52         )
  53         kde5_src_configure
  54 }