kde-apps/artikulate/artikulate-18.12.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_HANDBOOK="optional"
   7 inherit kde5
   8
   9 DESCRIPTION="Language learning application that helps improving pronunciation skills"
  10 HOMEPAGE="https://edu.kde.org/applications/language/artikulate"
  11 KEYWORDS="amd64 ~arm64 x86"
  12 IUSE="+gstreamer qtmedia"
  13
  14 REQUIRED_USE="|| ( gstreamer qtmedia )"
  15
  16 DEPEND="
  17         $(add_frameworks_dep karchive)
  18         $(add_frameworks_dep kconfig)
  19         $(add_frameworks_dep kconfigwidgets)
  20         $(add_frameworks_dep kcoreaddons)
  21         $(add_frameworks_dep kcrash)
  22         $(add_frameworks_dep ki18n)
  23         $(add_frameworks_dep knewstuff)
  24         $(add_frameworks_dep kwidgetsaddons)
  25         $(add_frameworks_dep kxmlgui)
  26         $(add_qt_dep qtdeclarative)
  27         $(add_qt_dep qtgui)
  28         $(add_qt_dep qtsql)
  29         $(add_qt_dep qtwidgets)
  30         $(add_qt_dep qtxml)
  31         $(add_qt_dep qtxmlpatterns)
  32         gstreamer? ( >=media-libs/qt-gstreamer-1.2.0[qt5(+)] )
  33         qtmedia? ( $(add_qt_dep qtmultimedia) )
  34 "
  35 RDEPEND="${DEPEND}"
  36
  37 src_configure() {
  38         local mycmakeargs=(
  39                 -DBUILD_GSTREAMER_PLUGIN=$(usex gstreamer)
  40                 -DBUILD_QTMULTIMEDIA_PLUGIN=$(usex qtmedia)
  41         )
  42
  43         kde5_src_configure
  44 }