kde-apps/ark/ark-18.12.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_HANDBOOK="forceoptional"
   7 KDE_TEST="optional"
   8 VIRTUALX_REQUIRED="test"
   9 inherit kde5
  10
  11 DESCRIPTION="KDE Archiving tool"
  12 HOMEPAGE="https://www.kde.org/applications/utilities/ark
  13 https://utils.kde.org/projects/ark/"
  14 KEYWORDS="amd64 ~arm64 x86"
  15 IUSE="bzip2 lzma zip"
  16
  17 BDEPEND="
  18         sys-devel/gettext
  19 "
  20 RDEPEND="
  21         $(add_frameworks_dep karchive)
  22         $(add_frameworks_dep kcompletion)
  23         $(add_frameworks_dep kconfig)
  24         $(add_frameworks_dep kconfigwidgets)
  25         $(add_frameworks_dep kcoreaddons)
  26         $(add_frameworks_dep kcrash)
  27         $(add_frameworks_dep kdbusaddons)
  28         $(add_frameworks_dep ki18n)
  29         $(add_frameworks_dep kiconthemes)
  30         $(add_frameworks_dep kio)
  31         $(add_frameworks_dep kitemmodels)
  32         $(add_frameworks_dep kjobwidgets)
  33         $(add_frameworks_dep kparts)
  34         $(add_frameworks_dep kpty)
  35         $(add_frameworks_dep kservice)
  36         $(add_frameworks_dep kwidgetsaddons)
  37         $(add_frameworks_dep kxmlgui)
  38         $(add_qt_dep qtdbus)
  39         $(add_qt_dep qtgui)
  40         $(add_qt_dep qtwidgets)
  41         app-arch/libarchive:=[bzip2?,lzma?,zlib]
  42         sys-libs/zlib
  43         zip? ( >=dev-libs/libzip-1.2.0:= )
  44 "
  45 DEPEND="${RDEPEND}
  46         $(add_qt_dep qtconcurrent)
  47 "
  48
  49 # bug #560548, last checked with 16.04.1
  50 RESTRICT+=" test"
  51
  52 src_configure() {
  53         local mycmakeargs=(
  54                 $(cmake-utils_use_find_package bzip2 BZip2)
  55                 $(cmake-utils_use_find_package lzma LibLZMA)
  56                 $(cmake-utils_use_find_package zip LibZip)
  57         )
  58
  59         kde5_src_configure
  60 }
  61
  62 pkg_postinst() {
  63         kde5_pkg_postinst
  64
  65         if [[ -z "${REPLACING_VERSIONS}" ]]; then
  66                 if ! has_version app-arch/rar; then
  67                         elog "For creating/extracting rar archives, installing app-arch/rar is required."
  68                         if ! has_version app-arch/unar && ! has_version app-arch/unrar; then
  69                                 elog "Alternatively, for only extracting rar archives, install app-arch/unar (free) or app-arch/unrar (non-free)."
  70                         fi
  71                 fi
  72
  73                 has_version app-arch/p7zip || \
  74                         elog "For handling 7-Zip archives, install app-arch/p7zip."
  75
  76                 has_version app-arch/lrzip || \
  77                         elog "For handling lrz archives, install app-arch/lrzip."
  78         fi
  79 }