gui-apps/waybar/waybar-0.7.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit meson
   7
   8 DESCRIPTION="Highly customizable Wayland bar for Sway and Wlroots based compositors."
   9 HOMEPAGE="https://github.com/Alexays/Waybar"
  10
  11 if [[ ${PV} == 9999 ]]; then
  12         inherit git-r3
  13         EGIT_REPO_URI="https://github.com/Alexays/${PN^}.git"
  14 else
  15         SRC_URI="https://github.com/Alexays/${PN^}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  16         KEYWORDS="~amd64"
  17 fi
  18
  19 LICENSE="MIT"
  20 SLOT="0"
  21 IUSE="libcxx mpd network pulseaudio tray +udev"
  22
  23 DEPEND="
  24         dev-cpp/gtkmm:3.0
  25         dev-libs/jsoncpp:=
  26         dev-libs/libinput:=
  27         dev-libs/libsigc++:2
  28         >=dev-libs/libfmt-5.3.0:=
  29         >=dev-libs/spdlog-1.3.1:=
  30         dev-libs/wayland
  31         dev-libs/wayland-protocols
  32         gui-libs/wlroots
  33         libcxx? ( sys-libs/libcxx )
  34         mpd? ( media-libs/libmpdclient )
  35         network? ( dev-libs/libnl:3 )
  36         pulseaudio? ( media-sound/pulseaudio )
  37         tray? ( dev-libs/libdbusmenu[gtk3] )
  38         udev? ( virtual/libudev:= )"
  39
  40 RDEPEND="${DEPEND}"
  41
  42 BDEPEND="virtual/pkgconfig"
  43
  44 if [[ ${PV} != 9999 ]]; then
  45         S="${WORKDIR}/${PN^}-${PV}"
  46 fi
  47
  48 src_configure() {
  49         local emesonargs=(
  50                 $(meson_use libcxx)
  51                 $(meson_feature mpd)
  52                 $(meson_feature network libnl)
  53                 $(meson_feature pulseaudio)
  54                 $(meson_feature tray dbusmenu-gtk)
  55                 $(meson_feature udev libudev)
  56         )
  57         meson_src_configure
  58 }