gnustep-libs/sope/sope-4.1.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit gnustep-2 vcs-snapshot
   7
   8 DESCRIPTION="A set of frameworks forming a complete Web application server environment"
   9 HOMEPAGE="http://www.sogo.nu/"
  10 SRC_URI="https://github.com/inverse-inc/sope/archive/SOPE-${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="LGPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="gnutls ldap libressl mysql postgres +ssl +xml"
  16
  17 RDEPEND="
  18         sys-libs/zlib
  19         ldap? ( net-nds/openldap )
  20         gnutls? ( net-libs/gnutls:= )
  21         !gnutls? (
  22                 !libressl? ( dev-libs/openssl:0= )
  23                 libressl? ( dev-libs/libressl:= )
  24         )
  25         mysql? ( dev-db/mysql-connector-c:= )
  26         postgres? ( dev-db/postgresql:= )
  27         xml? ( dev-libs/libxml2:2 )
  28 "
  29 DEPEND="${RDEPEND}"
  30
  31 pkg_pretend() {
  32         if use ssl && use gnutls && use libressl ; then
  33                 ewarn "You have enabled both gnutls and libressl, but only"
  34                 ewarn "one provider can be active. Using gnutls!"
  35         fi
  36 }
  37
  38 src_configure() {
  39         local ssl_provider
  40         if use ssl ; then
  41                 if use gnutls ; then
  42                         ssl_provider=gnutls
  43                 else
  44                         ssl_provider=ssl
  45                 fi
  46         else
  47                 ssl_provider=none
  48         fi
  49
  50         egnustep_env
  51
  52         # Non-standard configure script
  53         ./configure \
  54                 --disable-strip \
  55                 $(use_enable debug) \
  56                 $(use_enable ldap openldap) \
  57                 $(use_enable mysql) \
  58                 $(use_enable postgres postgresql) \
  59                 $(use_enable xml) \
  60                 --with-ssl="${ssl_provider}" \
  61                 --with-gnustep || die "configure failed"
  62 }