gnome-extra/zenity/zenity-3.32.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit gnome2
   6
   7 DESCRIPTION="Tool to display dialogs from the commandline and shell scripts"
   8 HOMEPAGE="https://wiki.gnome.org/Projects/Zenity"
   9
  10 LICENSE="LGPL-2+"
  11 SLOT="0"
  12 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
  13 IUSE="debug libnotify webkit"
  14
  15 # TODO: X11 dependency is automagically enabled
  16 RDEPEND="
  17         >=dev-libs/glib-2.8:2
  18         x11-libs/gdk-pixbuf:2
  19         >=x11-libs/gtk+-3:3[X]
  20         x11-libs/libX11
  21         x11-libs/pango
  22         libnotify? ( >=x11-libs/libnotify-0.6.1:= )
  23         webkit? ( >=net-libs/webkit-gtk-2.8.1:4 )
  24 "
  25 DEPEND="${RDEPEND}
  26         dev-util/itstool
  27         >=sys-devel/gettext-0.19.4
  28         virtual/pkgconfig
  29 "
  30
  31 src_configure() {
  32         gnome2_src_configure \
  33                 $(usex debug --enable-debug=yes ' ') \
  34                 $(use_enable libnotify) \
  35                 $(use_enable webkit webkitgtk) \
  36                 PERL=$(type -P false)
  37 }
  38
  39 src_install() {
  40         gnome2_src_install
  41
  42         # Not really needed and prevent us from needing perl
  43         rm "${ED}/usr/bin/gdialog" || die "rm gdialog failed!"
  44 }