gnome-extra/yelp/yelp-3.32.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6
   7 inherit autotools gnome2
   8
   9 DESCRIPTION="Help browser for GNOME"
  10 HOMEPAGE="https://wiki.gnome.org/Apps/Yelp"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 IUSE=""
  15 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
  16
  17 RDEPEND="
  18         app-arch/bzip2:=
  19         >=app-arch/xz-utils-4.9:=
  20         dev-db/sqlite:3=
  21         >=dev-libs/glib-2.38:2
  22         >=dev-libs/libxml2-2.6.5:2
  23         >=dev-libs/libxslt-1.1.4
  24         >=gnome-extra/yelp-xsl-3.27.1
  25         >=net-libs/webkit-gtk-2.19.2:4
  26         >=x11-libs/gtk+-3.13.3:3
  27         x11-themes/adwaita-icon-theme
  28 "
  29 DEPEND="${RDEPEND}
  30         dev-libs/appstream-glib
  31         >=dev-util/gtk-doc-am-1.13
  32         dev-util/glib-utils
  33         dev-util/itstool
  34         >=sys-devel/gettext-0.19.8
  35         virtual/pkgconfig
  36 "
  37
  38 src_prepare() {
  39         # Fix compatibility with Gentoo's sys-apps/man
  40         # https://bugzilla.gnome.org/show_bug.cgi?id=648854
  41         eapply "${FILESDIR}"/${PN}-3.20.0-man-compatibility.patch
  42
  43         eautoreconf
  44         gnome2_src_prepare
  45 }
  46
  47 src_configure() {
  48         gnome2_src_configure \
  49                 --disable-static \
  50                 --enable-bz2 \
  51                 --enable-lzma \
  52                 APPSTREAM_UTIL=""
  53 }
  54
  55 src_install() {
  56         gnome2_src_install
  57         exeinto /usr/libexec/
  58         doexe "${S}"/libyelp/yelp-groff
  59 }