gnome-extra/nm-applet/nm-applet-1.8.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6 GNOME_ORG_MODULE="network-manager-applet"
   7
   8 inherit gnome2
   9
  10 DESCRIPTION="GNOME applet for NetworkManager"
  11 HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 IUSE="+introspection gcr +modemmanager selinux teamd"
  16 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
  17
  18 RDEPEND="
  19         app-crypt/libsecret
  20         >=dev-libs/glib-2.32:2[dbus]
  21         >=dev-libs/dbus-glib-0.88
  22         >=sys-apps/dbus-1.4.1
  23         >=sys-auth/polkit-0.96-r1
  24         >=x11-libs/gtk+-3.4:3[introspection?]
  25         >=x11-libs/libnotify-0.7.0
  26
  27         app-text/iso-codes
  28         >=net-misc/networkmanager-1.7:=[introspection?,modemmanager?,teamd?]
  29         net-misc/mobile-broadband-provider-info
  30
  31         introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
  32         virtual/freedesktop-icon-theme
  33         virtual/libgudev:=
  34         gcr? ( >=app-crypt/gcr-3.14:= )
  35         modemmanager? ( net-misc/modemmanager )
  36         selinux? ( sys-libs/libselinux )
  37         teamd? ( >=dev-libs/jansson-2.3 )
  38 "
  39 DEPEND="${RDEPEND}
  40         >=dev-util/gtk-doc-am-1.0
  41         >=dev-util/intltool-0.50.1
  42         virtual/pkgconfig
  43 "
  44
  45 PDEPEND="virtual/notification-daemon" #546134
  46
  47 src_configure() {
  48         local myconf=(
  49                 --without-appindicator
  50                 --disable-lto
  51                 --disable-ld-gc
  52                 --disable-more-warnings
  53                 --disable-static
  54                 --localstatedir=/var
  55                 $(use_enable introspection)
  56                 $(use_with gcr)
  57                 $(use_with modemmanager wwan)
  58                 $(use_with selinux)
  59                 $(use_with teamd team)
  60         )
  61         gnome2_src_configure "${myconf[@]}"
  62 }