gnome-extra/gucharmap/gucharmap-9.0.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6 VALA_USE_DEPEND="vapigen"
   7
   8 inherit gnome2 vala
   9
  10 DESCRIPTION="Unicode character map viewer and library"
  11 HOMEPAGE="https://wiki.gnome.org/Apps/Gucharmap"
  12
  13 LICENSE="GPL-3"
  14 SLOT="2.90"
  15 KEYWORDS="alpha amd64 arm ~ia64 ppc ~ppc64 ~sh sparc x86 ~x86-fbsd"
  16
  17 IUSE="debug +introspection test vala"
  18 REQUIRED_USE="vala? ( introspection )"
  19
  20 COMMON_DEPEND="
  21         >=app-i18n/unicode-data-${PV}
  22         >=dev-libs/glib-2.32:2
  23         >=x11-libs/pango-1.2.1[introspection?]
  24         >=x11-libs/gtk+-3.16:3[introspection?]
  25         introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
  26 "
  27 RDEPEND="${COMMON_DEPEND}
  28         !<gnome-extra/gucharmap-3:0
  29 "
  30 DEPEND="${RDEPEND}
  31         app-text/yelp-tools
  32         dev-util/desktop-file-utils
  33         >=dev-util/gtk-doc-am-1
  34         >=dev-util/intltool-0.40
  35         sys-devel/gettext
  36         virtual/pkgconfig
  37         test? ( app-text/docbook-xml-dtd:4.1.2 )
  38         vala? ( $(vala_depend) )
  39 "
  40
  41 src_prepare() {
  42         # prevent file collisions with slot 0
  43         sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
  44                 -i configure.ac configure || die "sed configure.ac configure failed"
  45
  46         # avoid autoreconf
  47         sed -e 's/-Wall //g' -i configure || die "sed failed"
  48
  49         use vala && vala_src_prepare
  50         gnome2_src_prepare
  51 }
  52
  53 src_configure() {
  54         # unihan is not really conditional
  55         # https://bugzilla.gnome.org/show_bug.cgi?id=768210#c5
  56         gnome2_src_configure \
  57                 --disable-static \
  58                 --with-unicode-data=/usr/share/unicode-data \
  59                 --enable-unihan \
  60                 $(usex debug --enable-debug=yes ' ') \
  61                 $(use_enable introspection) \
  62                 $(use_enable vala)
  63 }