gnome-extra/gucharmap/gucharmap-3.18.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="yes"
   7 VALA_USE_DEPEND="vapigen"
   8
   9 inherit gnome2 vala
  10
  11 DESCRIPTION="Unicode character map viewer and library"
  12 HOMEPAGE="https://wiki.gnome.org/Apps/Gucharmap"
  13
  14 LICENSE="GPL-3"
  15 SLOT="2.90"
  16 KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc x86 ~x86-fbsd"
  17
  18 IUSE="cjk +introspection test vala"
  19 REQUIRED_USE="vala? ( introspection )"
  20
  21 COMMON_DEPEND="
  22         >=dev-libs/glib-2.32:2
  23         >=x11-libs/pango-1.2.1[introspection?]
  24         >=x11-libs/gtk+-3.16:3[introspection?]
  25         introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
  26 "
  27 RDEPEND="${COMMON_DEPEND}
  28         !<gnome-extra/gucharmap-3:0
  29 "
  30 DEPEND="${RDEPEND}
  31         app-text/yelp-tools
  32         dev-util/desktop-file-utils
  33         >=dev-util/gtk-doc-am-1
  34         >=dev-util/intltool-0.40
  35         sys-devel/gettext
  36         virtual/pkgconfig
  37         test? ( app-text/docbook-xml-dtd:4.1.2 )
  38         vala? ( $(vala_depend) )
  39 "
  40
  41 src_prepare() {
  42         # prevent file collisions with slot 0
  43         sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
  44                 -i configure.ac configure || die "sed configure.ac configure failed"
  45
  46         # avoid autoreconf
  47         sed -e 's/-Wall //g' -i configure || die "sed failed"
  48
  49         use vala && vala_src_prepare
  50         gnome2_src_prepare
  51 }
  52
  53 src_configure() {
  54         # Do not add ITSTOOL=$(type -P true); yelp-tools is a true required
  55         # dependency here for some LINGUAS.
  56         gnome2_src_configure \
  57                 --disable-static \
  58                 $(use_enable introspection) \
  59                 $(use_enable cjk unihan) \
  60                 $(use_enable vala)
  61 }