gnome-extra/gucharmap/gucharmap-3.16.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="yes"
   7 VALA_MIN_API_VERSION="0.16"
   8 VALA_USE_DEPEND="vapigen"
   9
  10 inherit gnome2 vala
  11
  12 DESCRIPTION="Unicode character map viewer and library"
  13 HOMEPAGE="https://live.gnome.org/Gucharmap"
  14
  15 LICENSE="GPL-3"
  16 SLOT="2.90"
  17 KEYWORDS="alpha amd64 arm ia64 ppc ppc64 ~sh sparc x86 ~x86-fbsd"
  18 IUSE="cjk +introspection test vala"
  19 REQUIRED_USE="vala? ( introspection )"
  20
  21 COMMON_DEPEND="
  22         >=dev-libs/glib-2.32:2
  23         >=x11-libs/pango-1.2.1[introspection?]
  24         >=x11-libs/gtk+-3.16:3[introspection?]
  25
  26         introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
  27 "
  28 RDEPEND="${COMMON_DEPEND}
  29         !<gnome-extra/gucharmap-3:0
  30 "
  31 DEPEND="${RDEPEND}
  32         app-text/yelp-tools
  33         dev-util/desktop-file-utils
  34         >=dev-util/gtk-doc-am-1
  35         >=dev-util/intltool-0.40
  36         sys-devel/gettext
  37         virtual/pkgconfig
  38         test? ( app-text/docbook-xml-dtd:4.1.2 )
  39         vala? ( $(vala_depend) )
  40 "
  41
  42 src_prepare() {
  43         # prevent file collisions with slot 0
  44         sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
  45                 -i configure.ac configure || die "sed configure.ac configure failed"
  46
  47         # avoid autoreconf
  48         sed -e 's/-Wall //g' -i configure || die "sed failed"
  49
  50         use vala && vala_src_prepare
  51         gnome2_src_prepare
  52 }
  53
  54 src_configure() {
  55         # Do not add ITSTOOL=$(type -P true); yelp-tools is a true required
  56         # dependency here for some LINGUAS.
  57         gnome2_src_configure \
  58                 --disable-static \
  59                 $(use_enable introspection) \
  60                 $(use_enable cjk unihan) \
  61                 $(use_enable vala)
  62 }