gnome-extra/gucharmap/gucharmap-3.0.1-r200.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6 GNOME2_LA_PUNT="yes"
   7 GNOME_TARBALL_SUFFIX="bz2"
   8
   9 inherit gnome2
  10
  11 DESCRIPTION="Unicode character map viewer library"
  12 HOMEPAGE="https://wiki.gnome.org/Apps/Gucharmap"
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="alpha amd64 arm ia64 ppc ppc64 sh sparc x86 ~x86-fbsd"
  17 IUSE="cjk debug doc +introspection"
  18
  19 RDEPEND="
  20         >=dev-libs/glib-2.16.3:2
  21         >=x11-libs/pango-1.2.1[introspection?]
  22         >=x11-libs/gtk+-2.14.0:2[introspection?]
  23         introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
  24 "
  25 DEPEND="${RDEPEND}
  26         dev-util/gtk-doc-am
  27         >=dev-util/intltool-0.40
  28         sys-devel/gettext
  29         virtual/pkgconfig
  30 "
  31
  32 src_prepare() {
  33         # .desktop and schema files are only needed for the gucharmap program
  34         sed -e 's:desktop_DATA\s*=.*:desktop_DATA = :' \
  35                 -e 's:schema_DATA\s*=.*:schema_DATA = :' \
  36                 -i Makefile.* || die "sed Makefile.* failed"
  37
  38         eapply "${FILESDIR}/${PN}-3.4.1.1-fix-doc.patch" # bug 436710, fixed in 3.6
  39
  40         gnome2_src_prepare
  41 }
  42
  43 src_configure() {
  44         gnome2_src_configure \
  45                 --disable-static \
  46                 --with-gtk=2.0 \
  47                 --disable-charmap \
  48                 --disable-gconf \
  49                 $(use_enable cjk unihan) \
  50                 $(use_enable debug) \
  51                 $(use_enable introspection)
  52 }
  53
  54 pkg_postinst() {
  55         gnome2_pkg_postinst
  56         if ! has_version "gnome-extra/gucharmap:2.90" ; then
  57                 ewarn "Note: ${PF} includes only the gucharmap-2 library."
  58                 ewarn "If you need the gucharmap program, emerge gucharmap:2.90"
  59         fi
  60 }