gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.22.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit gnome2 python-r1
   9
  10 DESCRIPTION="Tool to customize GNOME 3 options"
  11 HOMEPAGE="https://wiki.gnome.org/action/show/Apps/GnomeTweakTool"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15
  16 IUSE=""
  17 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  18
  19 KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 x86"
  20
  21 # Newer pygobject needed due upstream bug #723951
  22 COMMON_DEPEND="
  23         ${PYTHON_DEPS}
  24         dev-libs/glib:2[dbus]
  25         >=dev-python/pygobject-3.10.2:3[${PYTHON_USEDEP}]
  26         >=gnome-base/gsettings-desktop-schemas-3.21.2
  27 "
  28 # g-s-d, gnome-desktop, gnome-shell etc. needed at runtime for the gsettings schemas
  29 RDEPEND="${COMMON_DEPEND}
  30         >=gnome-base/gnome-desktop-3.6.0.1:3=[introspection]
  31         >=x11-libs/gtk+-3.12:3[introspection]
  32
  33         net-libs/libsoup:2.4[introspection]
  34         x11-libs/libnotify[introspection]
  35
  36         >=gnome-base/gnome-settings-daemon-3
  37         gnome-base/gnome-shell
  38         >=gnome-base/nautilus-3
  39 "
  40 DEPEND="${COMMON_DEPEND}
  41         >=dev-util/intltool-0.40.0
  42         virtual/pkgconfig
  43 "
  44
  45 src_prepare() {
  46         # Add contents of Gentoo's cursor theme directory to cursor theme list
  47         eapply "${FILESDIR}/${PN}-3.10.1-gentoo-cursor-themes.patch"
  48
  49         gnome2_src_prepare
  50         python_copy_sources
  51 }
  52
  53 src_configure() {
  54         python_foreach_impl run_in_build_dir gnome2_src_configure
  55 }
  56
  57 src_compile() {
  58         python_foreach_impl run_in_build_dir gnome2_src_compile
  59 }
  60
  61 src_test() {
  62         python_foreach_impl run_in_build_dir default
  63 }
  64
  65 src_install() {
  66         install_python() {
  67                 gnome2_src_install
  68                 python_doscript gnome-tweak-tool || die
  69         }
  70         python_foreach_impl run_in_build_dir install_python
  71 }