gnome-extra/gnome-software/gnome-software-3.34.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit gnome.org gnome2-utils meson xdg
   7
   8 DESCRIPTION="Gnome install & update software"
   9 HOMEPAGE="https://wiki.gnome.org/Apps/Software"
  10
  11 LICENSE="GPL-2+"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="+firmware gnome gtk-doc packagekit spell udev"
  15 RESTRICT="test" # writes to and deletes files in /var/tmp/self-test/
  16
  17 RDEPEND="
  18         >=dev-libs/appstream-glib-0.7.14:0
  19         >=x11-libs/gdk-pixbuf-2.32.0:2
  20         >=dev-libs/libxmlb-0.1.7
  21         net-libs/gnome-online-accounts:=
  22         >=x11-libs/gtk+-3.22.4:3
  23         >=dev-libs/glib-2.56:2
  24         >=dev-libs/json-glib-1.2.0
  25         >=net-libs/libsoup-2.52.0:2.4
  26         gnome? ( >=gnome-base/gnome-desktop-3.18.0:3= )
  27         spell? ( app-text/gspell:= )
  28         sys-auth/polkit
  29         packagekit? ( >=app-admin/packagekit-base-1.1.0 )
  30         firmware? ( >=sys-apps/fwupd-1.0.3 )
  31         udev? ( dev-libs/libgudev )
  32         >=gnome-base/gsettings-desktop-schemas-3.11.5
  33 "
  34 DEPEND="${RDEPEND}"
  35 BDEPEND="
  36         dev-libs/libxml2:2
  37         dev-util/gdbus-codegen
  38         >=sys-devel/gettext-0.19.8
  39         virtual/pkgconfig
  40         gtk-doc? (
  41                 dev-util/gtk-doc
  42                 app-text/docbook-xml-dtd:4.3 )
  43 "
  44 # test? ( dev-util/valgrind )
  45
  46 src_prepare() {
  47         xdg_src_prepare
  48         sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
  49         # We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
  50         sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
  51         # Trouble talking to spawned gnome-keyring socket for some reason, even if wrapped in dbus-run-session
  52         # TODO: Investigate; seems to work outside ebuild .. test/emerge
  53         sed -i -e '/g_test_add_func.*gs_auth_secret_func/d' lib/gs-self-test.c || die
  54 }
  55
  56 src_configure() {
  57         local emesonargs=(
  58                 -Dtests=false #$(meson_use test tests)
  59                 $(meson_use spell gspell)
  60                 $(meson_use gnome gnome_desktop) # Investigate purpose, in relation to shell_extensions too (is it ok to be same USE?)
  61                 -Dman=true
  62                 $(meson_use packagekit)
  63                 # -Dpackagekit_autoremove
  64                 -Dpolkit=true
  65                 -Deos_updater=false # Endless OS updater
  66                 $(meson_use firmware fwupd)
  67                 -Dflatpak=false
  68                 -Drpm_ostree=false
  69                 $(meson_use gnome shell_extensions) # Maybe gnome-shell USE?
  70                 -Dodrs=false
  71                 -Dwebapps=true
  72                 $(meson_use udev gudev)
  73                 -Dsnap=false
  74                 -Dexternal_appstream=false
  75                 -Dvalgrind=false
  76                 $(meson_use gtk-doc gtk_doc)
  77                 -Dhardcoded_popular=true
  78                 -Dmogwai=false #TODO?
  79         )
  80         meson_src_configure
  81 }
  82
  83 #src_test() {
  84 #       virtx meson_src_test
  85 #}
  86
  87 pkg_postinst() {
  88         xdg_pkg_postinst
  89         gnome2_schemas_update
  90 }
  91
  92 pkg_postrm() {
  93         xdg_pkg_postrm
  94         gnome2_schemas_update
  95 }