gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.24.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit gnome2 readme.gentoo-r1
   6
   7 DESCRIPTION="JavaScript extensions for GNOME Shell"
   8 HOMEPAGE="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
   9
  10 LICENSE="GPL-2"
  11 SLOT="0"
  12 IUSE="examples"
  13 KEYWORDS="amd64 x86"
  14
  15 COMMON_DEPEND="
  16         >=dev-libs/glib-2.26:2
  17         >=gnome-base/libgtop-2.28.3[introspection]
  18         >=app-eselect/eselect-gnome-shell-extensions-20111211
  19 "
  20 RDEPEND="${COMMON_DEPEND}
  21         >=dev-libs/gjs-1.29
  22         dev-libs/gobject-introspection:=
  23         dev-libs/atk[introspection]
  24         gnome-base/gnome-menus:3[introspection]
  25         >=gnome-base/gnome-shell-3.14.2
  26         <gnome-base/gnome-shell-3.29
  27         media-libs/clutter:1.0[introspection]
  28         net-libs/telepathy-glib[introspection]
  29         x11-libs/gdk-pixbuf:2[introspection]
  30         x11-libs/gtk+:3[introspection]
  31         x11-libs/pango[introspection]
  32         x11-themes/adwaita-icon-theme
  33         x11-wm/mutter[introspection]
  34         <x11-wm/mutter-3.29
  35 "
  36 DEPEND="${COMMON_DEPEND}
  37         >=sys-devel/gettext-0.19.6
  38         virtual/pkgconfig
  39 "
  40 # eautoreconf needs gnome-base/gnome-common
  41
  42 DISABLE_AUTOFORMATTING="yes"
  43 DOC_CONTENTS="Installed extensions installed are initially disabled by default.
  44 To change the system default and enable some extensions, you can use
  45 # eselect gnome-shell-extensions
  46
  47 Alternatively, to enable/disable extensions on a per-user basis,
  48 you can use the https://extensions.gnome.org/ web interface, the
  49 gnome-extra/gnome-tweaks GUI, or modify the org.gnome.shell
  50 enabled-extensions gsettings key from the command line or a script."
  51
  52 src_configure() {
  53         gnome2_src_configure --enable-extensions=all
  54 }
  55
  56 src_install() {
  57         gnome2_src_install
  58
  59         local example="example@gnome-shell-extensions.gcampax.github.com"
  60         if use examples; then
  61                 mv "${ED}usr/share/gnome-shell/extensions/${example}" \
  62                         "${ED}usr/share/doc/${PF}/" || die
  63         else
  64                 rm -r "${ED}usr/share/gnome-shell/extensions/${example}" || die
  65         fi
  66
  67         readme.gentoo_create_doc
  68 }
  69
  70 pkg_postinst() {
  71         gnome2_pkg_postinst
  72
  73         ebegin "Updating list of installed extensions"
  74         eselect gnome-shell-extensions update
  75         eend $?
  76
  77         readme.gentoo_print_elog
  78 }