gnome-extra/gnome-shell-extensions/gnome-shell-extensions-3.18.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7
   8 inherit gnome2 readme.gentoo
   9
  10 DESCRIPTION="JavaScript extensions for GNOME Shell"
  11 HOMEPAGE="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 IUSE="examples"
  16 KEYWORDS="~amd64 ~x86"
  17
  18 COMMON_DEPEND="
  19         >=dev-libs/glib-2.26:2
  20         >=gnome-base/libgtop-2.28.3[introspection]
  21         >=app-eselect/eselect-gnome-shell-extensions-20111211
  22 "
  23 RDEPEND="${COMMON_DEPEND}
  24         >=dev-libs/gjs-1.29
  25         dev-libs/gobject-introspection:=
  26         dev-libs/atk[introspection]
  27         gnome-base/gnome-menus:3[introspection]
  28         >=gnome-base/gnome-shell-3.14.2
  29         media-libs/clutter:1.0[introspection]
  30         net-libs/telepathy-glib[introspection]
  31         x11-libs/gdk-pixbuf:2[introspection]
  32         x11-libs/gtk+:3[introspection]
  33         x11-libs/pango[introspection]
  34         x11-themes/gnome-icon-theme-symbolic
  35 "
  36 DEPEND="${COMMON_DEPEND}
  37         >=dev-util/intltool-0.50
  38         sys-devel/gettext
  39         virtual/pkgconfig
  40 "
  41 # eautoreconf needs gnome-base/gnome-common
  42
  43 DISABLE_AUTOFORMATTING="yes"
  44 DOC_CONTENTS="Installed extensions installed are initially disabled by default.
  45 To change the system default and enable some extensions, you can use
  46 # eselect gnome-shell-extensions
  47
  48 Alternatively, to enable/disable extensions on a per-user basis,
  49 you can use the https://extensions.gnome.org/ web interface, the
  50 gnome-extra/gnome-tweak-tool GUI, or modify the org.gnome.shell
  51 enabled-extensions gsettings key from the command line or a script."
  52
  53 src_configure() {
  54         gnome2_src_configure --enable-extensions=all
  55 }
  56
  57 src_install() {
  58         gnome2_src_install
  59
  60         local example="example@gnome-shell-extensions.gcampax.github.com"
  61         if use examples; then
  62                 mv "${ED}usr/share/gnome-shell/extensions/${example}" \
  63                         "${ED}usr/share/doc/${PF}/" || die
  64         else
  65                 rm -r "${ED}usr/share/gnome-shell/extensions/${example}" || die
  66         fi
  67
  68         readme.gentoo_create_doc
  69 }
  70
  71 pkg_postinst() {
  72         gnome2_pkg_postinst
  73
  74         ebegin "Updating list of installed extensions"
  75         eselect gnome-shell-extensions update
  76         eend $?
  77
  78         readme.gentoo_print_elog
  79 }