gnome-extra/gnome-shell-extension-gsconnect/gnome-shell-extension-gsconnect-33-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit gnome2-utils meson readme.gentoo-r1
   6
   7 DESCRIPTION="KDE Connect implementation for Gnome Shell"
   8 HOMEPAGE="https://github.com/andyholmes/gnome-shell-extension-gsconnect"
   9 SRC_URI="https://github.com/andyholmes/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="GPL-2+"
  12 SLOT="0"
  13 KEYWORDS="amd64 x86"
  14 IUSE="nautilus"
  15
  16 COMMON_DEPEND="dev-libs/glib:2"
  17 RDEPEND="${COMMON_DEPEND}
  18         app-eselect/eselect-gnome-shell-extensions
  19         >=dev-libs/gjs-1.48
  20         =gnome-base/gnome-shell-3.34*
  21         gnome-base/gvfs
  22         gnome-extra/evolution-data-server
  23         || ( media-libs/libcanberra media-libs/gsound )
  24         nautilus? (
  25                 dev-python/nautilus-python
  26                 gnome-base/nautilus[introspection] )
  27 "
  28 DEPEND="${COMMON_DEPEND}"
  29 BDEPEND="
  30         virtual/pkgconfig
  31 "
  32
  33 DISABLE_AUTOFORMATTING="yes"
  34 DOC_CONTENTS="For knowing more about how to do the setup, please visit:
  35 https://github.com/andyholmes/gnome-shell-extension-gsconnect/wiki/Installation"
  36
  37 PATCHES=(
  38         # Shell Notifications: set a limit of 10 notifications from GSConnect
  39         "${FILESDIR}/${P}-notifications-limit.patch"
  40 )
  41
  42 src_configure() {
  43         # nemo support relies on nemo-python from https://github.com/linuxmint/nemo-extensions
  44         # https://bugs.gentoo.org/694388
  45         meson_src_configure \
  46                 -Dnemo=false \
  47                 $(meson_use nautilus)
  48 }
  49
  50 src_install() {
  51         meson_src_install
  52         readme.gentoo_create_doc
  53 }
  54
  55 pkg_preinst() {
  56         gnome2_schemas_savelist
  57 }
  58
  59 pkg_postinst() {
  60         gnome2_schemas_update
  61         ebegin "Updating list of installed extensions"
  62         eselect gnome-shell-extensions update
  63         eend $?
  64         readme.gentoo_print_elog
  65 }
  66
  67 pkg_postrm() {
  68         gnome2_schemas_update
  69 }