gnome-extra/gnome-documents/gnome-documents-3.18.2-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7
   8 inherit gnome2
   9
  10 DESCRIPTION="A document manager application for GNOME"
  11 HOMEPAGE="https://wiki.gnome.org/Apps/Documents"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 IUSE=""
  16 KEYWORDS="~amd64 ~x86"
  17
  18 # Need gdk-pixbuf-2.25 for gdk_pixbuf_get_pixels_with_length
  19 COMMON_DEPEND="
  20         >=app-misc/tracker-1:=
  21         >=app-text/evince-3.13.3[introspection]
  22         dev-libs/gjs
  23         >=dev-libs/glib-2.39.3:2
  24         >=dev-libs/gobject-introspection-1.31.6:=
  25         >=dev-libs/libgdata-0.13.3:=[crypt,gnome-online-accounts,introspection]
  26         gnome-base/gnome-desktop:3=
  27         >=media-libs/clutter-1.10:1.0
  28         >=media-libs/clutter-gtk-1.3.2:1.0[introspection]
  29         >=net-libs/gnome-online-accounts-3.2.0
  30         >=net-libs/libsoup-2.41.3:2.4
  31         >=net-libs/libzapojit-0.0.2
  32         >=net-libs/webkit-gtk-2.6:4
  33         >=x11-libs/gdk-pixbuf-2.25:2[introspection]
  34         >=x11-libs/gtk+-3.15.5:3[introspection]
  35         x11-libs/pango[introspection]
  36 "
  37 RDEPEND="${COMMON_DEPEND}
  38         media-libs/clutter[introspection]
  39         net-misc/gnome-online-miners
  40         sys-apps/dbus
  41         x11-themes/gnome-icon-theme-symbolic
  42 "
  43 DEPEND="${COMMON_DEPEND}
  44         dev-libs/libxslt
  45         >=dev-util/intltool-0.50.1
  46         dev-util/itstool
  47         virtual/pkgconfig
  48 "
  49 # eautoreconf requires yelp-tools
  50
  51 src_prepare() {
  52         # Prevent sandbox violation, https://bugzilla.gnome.org/show_bug.cgi?id=758097
  53         sed -i -e '/-rm -f $(appdir)\/org.gnome.Books.data.gresource/d' data/Makefile.{am,in} || die
  54         gnome2_src_prepare
  55 }