gnome-extra/gnome-contacts/gnome-contacts-3.22.1-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 VALA_USE_DEPEND="vapigen"
   6 VALA_MIN_API_VERSION="0.24"
   7
   8 inherit gnome2 vala
   9
  10 DESCRIPTION="GNOME contact management application"
  11 HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 IUSE="v4l"
  16 KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86"
  17
  18 VALA_DEPEND="
  19         $(vala_depend)
  20         >=dev-libs/gobject-introspection-0.9.6:=
  21         dev-libs/folks[vala(+)]
  22         gnome-base/gnome-desktop:3=[introspection]
  23         gnome-extra/evolution-data-server[vala]
  24         net-libs/telepathy-glib[vala]
  25 "
  26 # Configure is wrong; it needs cheese-3.5.91, not 3.3.91
  27 # folks-0.11.4 to avoid build issues with vala-0.36, upstream 7a9001b056b4fb1d00375e7b2adeda9b7cf93c90
  28 RDEPEND="
  29         >=dev-libs/folks-0.11.4:=[eds,telepathy]
  30         >=dev-libs/glib-2.37.6:2
  31         >=dev-libs/libgee-0.10:0.8
  32         >=gnome-extra/evolution-data-server-3.13.90:=[gnome-online-accounts]
  33         >=gnome-base/gnome-desktop-3.0:3=
  34         media-libs/clutter:1.0
  35         media-libs/clutter-gtk:1.0
  36         media-libs/libchamplain:0.12
  37         net-libs/gnome-online-accounts:=
  38         >=net-libs/telepathy-glib-0.17.5
  39         >=sci-geosciences/geocode-glib-3.15.3
  40         x11-libs/cairo:=
  41         x11-libs/gdk-pixbuf:2
  42         >=x11-libs/gtk+-3.20.0:3
  43         x11-libs/pango
  44         v4l? ( >=media-video/cheese-3.5.91:= )
  45 "
  46 DEPEND="${RDEPEND}
  47         ${VALA_DEPEND}
  48         app-text/docbook-xml-dtd:4.2
  49         app-text/docbook-xsl-stylesheets
  50         dev-libs/libxslt
  51         >=dev-util/intltool-0.40
  52         >=sys-devel/gettext-0.17
  53         virtual/pkgconfig
  54 "
  55
  56 PATCHES=(
  57         "${FILESDIR}"/${PV}-fix-vala-0.35-part1.patch
  58         "${FILESDIR}"/${PV}-fix-vala-0.35-part2.patch
  59 )
  60
  61 src_prepare() {
  62         # Regenerate the pre-generated C sources, bug #471628
  63         if ! use v4l; then
  64                 touch src/*.vala
  65         fi
  66
  67         vala_src_prepare
  68         gnome2_src_prepare
  69 }
  70
  71 src_configure() {
  72         gnome2_src_configure \
  73                 --enable-man-pages \
  74                 $(use_with v4l cheese)
  75 }