gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-3.6.1-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6
   7 inherit autotools eutils gnome2 virtualx
   8
   9 DESCRIPTION="Cinnamon's settings daemon"
  10 HOMEPAGE="http://developer.linuxmint.com/projects/cinnamon-projects.html"
  11 SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 KEYWORDS="amd64 x86"
  16 IUSE="+colord cups input_devices_wacom smartcard systemd"
  17 RESTRICT=test
  18
  19 # udev is non-optional since lots of plugins, not just gudev, pull it in
  20 RDEPEND="
  21         >=dev-libs/glib-2.38:2
  22         dev-libs/libgudev:=
  23         >=gnome-base/libgnomekbd-3.6
  24         >=gnome-base/librsvg-2.36.2
  25         >=gnome-extra/cinnamon-desktop-2.8.0:0=
  26         media-libs/fontconfig
  27         >=media-libs/lcms-2.2:2
  28         media-libs/libcanberra:0=[gtk3]
  29         sys-apps/dbus
  30         >=sys-auth/polkit-0.97
  31         x11-libs/gdk-pixbuf:2
  32         >=x11-libs/gtk+-3.9.10:3
  33         >=x11-libs/libnotify-0.7.3:0=
  34         x11-libs/libX11
  35         x11-libs/libXext
  36         x11-libs/libXfixes
  37         x11-libs/libXi
  38         x11-libs/libxklavier
  39         >=sys-power/upower-0.9.11
  40
  41         colord? ( >=x11-misc/colord-0.1.27:= )
  42         cups? ( >=net-print/cups-1.4[dbus] )
  43         input_devices_wacom? (
  44                 >=dev-libs/libwacom-0.7
  45                 x11-drivers/xf86-input-wacom
  46                 x11-libs/libXtst )
  47         smartcard? ( >=dev-libs/nss-3.11.2 )
  48         systemd? ( sys-apps/systemd:0= )
  49         !systemd? (     sys-auth/elogind:0= )
  50 "
  51 DEPEND="${RDEPEND}
  52         dev-libs/libxml2:2
  53         >=dev-util/intltool-0.37.1
  54         x11-base/xorg-proto
  55         virtual/pkgconfig
  56 "
  57
  58 src_prepare() {
  59         # make colord and wacom optional
  60         eapply "${FILESDIR}"/${PN}-3.0.1-optional.patch
  61
  62         # Disable broken test
  63         sed -e '/g_test_add_func ("\/color\/edid/d' \
  64                 -i plugins/color/gcm-self-test.c || die
  65
  66         eautoreconf
  67         gnome2_src_prepare
  68 }
  69
  70 src_configure() {
  71         # no point in disabling gudev since other plugins pull it in
  72         gnome2_src_configure \
  73                 --disable-static \
  74                 --enable-gudev \
  75                 --enable-polkit \
  76                 --enable-logind \
  77                 $(use_enable colord color) \
  78                 $(use_enable cups) \
  79                 $(use_enable smartcard smartcard-support) \
  80                 $(use_enable input_devices_wacom wacom)
  81 }
  82
  83 src_test() {
  84         virtx emake check
  85 }