gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-2.6.3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="yes"
   7 GNOME2_LA_PUNT="yes"
   8
   9 inherit autotools eutils gnome2 virtualx
  10
  11 DESCRIPTION="Cinnamon's settings daemon"
  12 HOMEPAGE="http://cinnamon.linuxmint.com/"
  13 SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="GPL-2+"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86"
  18 IUSE="+colord cups input_devices_wacom smartcard systemd"
  19
  20 # udev is non-optional since lots of plugins, not just gudev, pull it in
  21 RDEPEND="
  22         >=dev-libs/glib-2.38:2
  23         >=gnome-base/libgnomekbd-3.6
  24         >=gnome-base/librsvg-2.36.2
  25         >=gnome-extra/cinnamon-desktop-2.6.3:0=
  26         media-libs/fontconfig
  27         >=media-libs/lcms-2.2:2
  28         media-libs/libcanberra:0=[gtk3]
  29         >=media-sound/pulseaudio-0.9.16:0=
  30         sys-apps/dbus
  31         >=sys-auth/polkit-0.97
  32         || ( >=sys-power/upower-0.9.11:= sys-power/upower-pm-utils )
  33         x11-libs/gdk-pixbuf:2
  34         >=x11-libs/gtk+-3.9.10:3
  35         >=x11-libs/libnotify-0.7.3:0=
  36         x11-libs/libX11
  37         x11-libs/libXext
  38         x11-libs/libXfixes
  39         x11-libs/libXi
  40         x11-libs/libxklavier
  41         virtual/libgudev:=
  42
  43         colord? ( >=x11-misc/colord-0.1.27:= )
  44         cups? ( >=net-print/cups-1.4[dbus] )
  45         input_devices_wacom? (
  46                 >=dev-libs/libwacom-0.7
  47                 x11-drivers/xf86-input-wacom
  48                 x11-libs/libXtst )
  49         smartcard? ( >=dev-libs/nss-3.11.2 )
  50         systemd? ( sys-apps/systemd:0= )
  51         !systemd? ( sys-auth/consolekit:0= )
  52 "
  53 DEPEND="${RDEPEND}
  54         dev-libs/libxml2:2
  55         >=dev-util/intltool-0.37.1
  56         x11-proto/kbproto
  57         virtual/pkgconfig
  58 "
  59
  60 src_prepare() {
  61         # make colord and wacom optional
  62         epatch "${FILESDIR}"/${PN}-2.6.2-optional.patch
  63
  64         # Disable broken test
  65         sed -e '/g_test_add_func ("\/color\/edid/d' \
  66                 -i plugins/color/gcm-self-test.c || die
  67
  68         # Fix intltool unittest
  69         cat >>"${S}"/po/POTFILES.in <<EOF
  70 data/org.cinnamon.settings-daemon.peripherals.wacom.gschema.xml.in.in
  71 data/org.cinnamon.settings-daemon.plugins.background.gschema.xml.in
  72 data/org.cinnamon.settings-daemon.plugins.background.gschema.xml.in.in
  73 plugins/datetime/org.cinnamon.settingsdaemon.datetimemechanism.policy.in
  74 plugins/keyboard/csd-keyboard-xkb.c
  75 plugins/wacom/csd-wacom-device.c
  76 plugins/wacom/csd-wacom-osd-window.c
  77 plugins/wacom/org.cinnamon.settings-daemon.plugins.wacom.policy.in.in
  78 EOF
  79
  80         epatch_user
  81
  82         eautoreconf
  83         gnome2_src_prepare
  84 }
  85
  86 src_configure() {
  87         DOCS="AUTHORS ChangeLog MAINTAINERS README"
  88
  89         # no point in disabling gudev since other plugins pull it in
  90         gnome2_src_configure \
  91                 --disable-static \
  92                 --enable-gudev \
  93                 --enable-man \
  94                 --enable-polkit \
  95                 $(use_enable colord color) \
  96                 $(use_enable cups) \
  97                 $(use_enable smartcard smartcard-support) \
  98                 $(use_enable systemd logind) \
  99                 $(use_enable input_devices_wacom wacom)
 100 }
 101
 102 src_test() {
 103         unset DISPLAY
 104         Xemake check
 105 }