gnome-base/nautilus/nautilus-3.32.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit gnome.org gnome2-utils meson readme.gentoo-r1 virtualx xdg
   7
   8 DESCRIPTION="Default file manager for the GNOME desktop"
   9 HOMEPAGE="https://wiki.gnome.org/Apps/Nautilus"
  10
  11 LICENSE="GPL-3+ LGPL-2.1+"
  12 SLOT="0"
  13 IUSE="gnome +gstreamer gtk-doc +introspection packagekit +previewer seccomp selinux sendto"
  14
  15 KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
  16
  17 COMMON_DEPEND="
  18         >=dev-libs/glib-2.58.1:2
  19         >=media-libs/gexiv2-0.10.0
  20         gstreamer? ( media-libs/gstreamer:1.0
  21                 media-libs/gst-plugins-base:1.0 )
  22         >=app-arch/gnome-autoar-0.2.1
  23         gnome-base/gsettings-desktop-schemas
  24         >=x11-libs/gtk+-3.22.27:3[X,introspection?]
  25         seccomp? ( sys-libs/libseccomp )
  26         >=x11-libs/pango-1.28.3
  27         selinux? ( >=sys-libs/libselinux-2.0 )
  28         >=app-misc/tracker-2.0:=
  29         x11-libs/libX11
  30         >=dev-libs/libxml2-2.7.8:2
  31         introspection? ( >=dev-libs/gobject-introspection-1.54:= )
  32 "
  33 RDEPEND="${COMMON_DEPEND}
  34         packagekit? ( app-admin/packagekit-base )
  35         seccomp? ( >=sys-apps/bubblewrap-0.3.1 )
  36         sendto? ( !<gnome-extra/nautilus-sendto-3.0.1 )
  37         gstreamer? ( !<media-video/totem-3.31.91[nautilus] )
  38         >=app-misc/tracker-miners-2.0:=
  39 " # uses org.freedesktop.Tracker.Miner.Files gsettings schema from tracker-miners
  40 DEPEND="${COMMON_DEPEND}
  41         media-libs/fontconfig
  42 "
  43 BDEPEND="
  44         >=dev-util/gdbus-codegen-2.51.2
  45         dev-util/glib-utils
  46         gtk-doc? (
  47                 >=dev-util/gtk-doc-1.10
  48                 app-text/docbook-xml-dtd:4.1.2 )
  49         >=sys-devel/gettext-0.19.8
  50         virtual/pkgconfig
  51         x11-base/xorg-proto
  52 "
  53 PDEPEND="
  54         gnome? ( x11-themes/adwaita-icon-theme )
  55         previewer? ( >=gnome-extra/sushi-0.1.9 )
  56         sendto? ( >=gnome-extra/nautilus-sendto-3.0.1 )
  57         >=gnome-base/gvfs-1.14[gtk(+)]
  58 " # Need gvfs[gtk] for recent:/// support; always built (without USE=gtk) since gvfs-1.34
  59
  60 PATCHES=(
  61         "${FILESDIR}"/3.30.5-docs-build.patch # Always install pregenerated manpage, keeping docs option for gtk-doc
  62         "${FILESDIR}"/${PV}-optional-gstreamer.patch # Allow controlling audio-video-properties build
  63 )
  64
  65 src_prepare() {
  66         if use previewer; then
  67                 DOC_CONTENTS="nautilus uses gnome-extra/sushi to preview media files.
  68                         To activate the previewer, select a file and press space; to
  69                         close the previewer, press space again."
  70         fi
  71         xdg_src_prepare
  72 }
  73
  74 src_configure() {
  75         local emesonargs=(
  76                 $(meson_use gtk-doc docs)
  77                 -Dextensions=true # image file properties, sendto support; also required for -Dgstreamer=true
  78                 $(meson_use gstreamer) # gstreamer audio-video-properties extension
  79                 $(meson_use introspection)
  80                 $(meson_use packagekit)
  81                 $(meson_use selinux)
  82                 -Dprofiling=false
  83                 -Dtests=$(usex test all none)
  84         )
  85         meson_src_configure
  86 }
  87
  88 src_install() {
  89         use previewer && readme.gentoo_create_doc
  90         meson_src_install
  91 }
  92
  93 src_test() {
  94         virtx meson_src_test
  95 }
  96
  97 pkg_postinst() {
  98         xdg_pkg_postinst
  99         gnome2_schemas_update
 100
 101         if use previewer; then
 102                 readme.gentoo_print_elog
 103         else
 104                 elog "To preview media files, emerge nautilus with USE=previewer"
 105         fi
 106 }
 107
 108 pkg_postrm() {
 109         xdg_pkg_postrm
 110         gnome2_schemas_update
 111 }