gnome-base/nautilus/nautilus-3.20.4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6 GNOME2_LA_PUNT="yes" # Needed with USE 'sendto'
   7
   8 inherit gnome2 readme.gentoo-r1 virtualx
   9
  10 DESCRIPTION="A file manager for the GNOME desktop"
  11 HOMEPAGE="https://wiki.gnome.org/Apps/Nautilus"
  12
  13 LICENSE="GPL-2+ LGPL-2+ FDL-1.1"
  14 SLOT="0"
  15 IUSE="exif gnome +introspection packagekit +previewer selinux sendto tracker xmp"
  16
  17 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
  18
  19 # FIXME: tests fails under Xvfb, but pass when building manually
  20 # "FAIL: check failed in nautilus-file.c, line 8307"
  21 # need org.gnome.SessionManager service (aka gnome-session) but cannot find it
  22 RESTRICT="test"
  23
  24 # Require {glib,gdbus-codegen}-2.30.0 due to GDBus API changes between 2.29.92
  25 # and 2.30.0
  26 COMMON_DEPEND="
  27         >=dev-libs/glib-2.45.7:2[dbus]
  28         >=x11-libs/pango-1.28.3
  29         >=x11-libs/gtk+-3.19.12:3[introspection?]
  30         >=dev-libs/libxml2-2.7.8:2
  31         >=gnome-base/gnome-desktop-3:3=
  32
  33         gnome-base/dconf
  34         >=gnome-base/gsettings-desktop-schemas-3.8.0
  35         x11-libs/libX11
  36         x11-libs/libXext
  37         x11-libs/libXrender
  38
  39         exif? ( >=media-libs/libexif-0.6.20 )
  40         introspection? ( >=dev-libs/gobject-introspection-0.6.4:= )
  41         selinux? ( >=sys-libs/libselinux-2 )
  42         tracker? ( >=app-misc/tracker-0.16:= )
  43         xmp? ( >=media-libs/exempi-2.1.0:2 )
  44 "
  45 DEPEND="${COMMON_DEPEND}
  46         >=dev-lang/perl-5
  47         >=dev-util/gdbus-codegen-2.33
  48         >=dev-util/gtk-doc-am-1.10
  49         >=dev-util/intltool-0.50
  50         sys-devel/gettext
  51         virtual/pkgconfig
  52         x11-proto/xproto
  53 "
  54 RDEPEND="${COMMON_DEPEND}
  55         packagekit? ( app-admin/packagekit-base )
  56         sendto? ( !<gnome-extra/nautilus-sendto-3.0.1 )
  57 "
  58
  59 # For eautoreconf
  60 #       gnome-base/gnome-common
  61 #       dev-util/gtk-doc-am"
  62
  63 PDEPEND="
  64         gnome? ( x11-themes/adwaita-icon-theme )
  65         tracker? ( >=gnome-extra/nautilus-tracker-tags-0.12 )
  66         previewer? ( >=gnome-extra/sushi-0.1.9 )
  67         sendto? ( >=gnome-extra/nautilus-sendto-3.0.1 )
  68         >=gnome-base/gvfs-1.14[gtk]
  69 "
  70 # Need gvfs[gtk] for recent:/// support
  71
  72 src_prepare() {
  73         if use previewer; then
  74                 DOC_CONTENTS="nautilus uses gnome-extra/sushi to preview media files.
  75                         To activate the previewer, select a file and press space; to
  76                         close the previewer, press space again."
  77         fi
  78         gnome2_src_prepare
  79 }
  80
  81 src_configure() {
  82         gnome2_src_configure \
  83                 --disable-profiling \
  84                 --disable-update-mimedb \
  85                 $(use_enable exif libexif) \
  86                 $(use_enable introspection) \
  87                 $(use_enable packagekit) \
  88                 $(use_enable sendto nst-extension) \
  89                 $(use_enable selinux) \
  90                 $(use_enable tracker) \
  91                 $(use_enable xmp)
  92 }
  93
  94 src_test() {
  95         virtx emake check
  96 }
  97
  98 src_install() {
  99         use previewer && readme.gentoo_create_doc
 100         gnome2_src_install
 101 }
 102
 103 pkg_postinst() {
 104         gnome2_pkg_postinst
 105
 106         if use previewer; then
 107                 readme.gentoo_print_elog
 108         else
 109                 elog "To preview media files, emerge nautilus with USE=previewer"
 110         fi
 111 }