gnome-base/libgnomecanvas/libgnomecanvas-2.30.3-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GCONF_DEBUG="no"
   6 GNOME_TARBALL_SUFFIX="bz2"
   7 GNOME2_LA_PUNT="yes"
   8
   9 inherit eutils gnome2 multilib multilib-minimal virtualx
  10
  11 DESCRIPTION="The Gnome 2 Canvas library"
  12 HOMEPAGE="https://library.gnome.org/devel/libgnomecanvas/stable/"
  13
  14 LICENSE="LGPL-2"
  15 SLOT="0"
  16 KEYWORDS="~alpha amd64 arm ~arm64 ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="glade"
  18
  19 RDEPEND=">=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  20         >=x11-libs/gtk+-2.24.23:2[${MULTILIB_USEDEP}]
  21         >=media-libs/libart_lgpl-2.3.21-r2[${MULTILIB_USEDEP}]
  22         >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}]
  23         glade? ( >=gnome-base/libglade-2.6.4-r1:2.0[${MULTILIB_USEDEP}] )"
  24
  25 DEPEND="${RDEPEND}
  26         >=dev-lang/perl-5
  27         sys-devel/gettext
  28         dev-util/glib-utils
  29         >=dev-util/intltool-0.35
  30         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
  31
  32 src_prepare() {
  33         gnome2_src_prepare
  34
  35         # Fix intltoolize broken file, see upstream #577133
  36         sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
  37                 || die "sed failed"
  38
  39         # Don't build demos that are not even installed, bug #226299
  40         sed 's/^\(SUBDIRS =.*\)demos\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  41                 || die "sed 2 failed"
  42 }
  43
  44 multilib_src_configure() {
  45         ECONF_SOURCE=${S} \
  46         gnome2_src_configure \
  47                 $(use_enable glade) \
  48                 --disable-static
  49
  50         ln -s "${S}"/docs/reference/html docs/reference/html || die
  51 }
  52
  53 multilib_src_install() {
  54         gnome2_src_install
  55 }
  56
  57 multilib_src_install_all() {
  58         DOCS="AUTHORS ChangeLog NEWS README"
  59         einstalldocs
  60 }
  61
  62 multilib_src_test() {
  63         Xemake check || die "Test phase failed"
  64 }