gnome-base/libgnome-keyring/libgnome-keyring-3.12.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GCONF_DEBUG="yes"
   6 GNOME2_LA_PUNT="yes"
   7 VALA_MIN_API_VERSION="0.16"
   8 VALA_USE_DEPEND="vapigen"
   9 PYTHON_COMPAT=( python2_7 )
  10
  11 inherit gnome2 python-any-r1 vala multilib-minimal
  12
  13 DESCRIPTION="Compatibility library for accessing secrets"
  14 HOMEPAGE="https://wiki.gnome.org/Projects/GnomeKeyring"
  15
  16 LICENSE="LGPL-2+ GPL-2+" # tests are GPL-2
  17 SLOT="0"
  18 IUSE="debug +introspection test vala"
  19 RESTRICT="!test? ( test )"
  20 REQUIRED_USE="vala? ( introspection )"
  21 KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~sparc-solaris"
  22
  23 RDEPEND="
  24         >=dev-libs/glib-2.16.0:2[${MULTILIB_USEDEP}]
  25         >=dev-libs/libgcrypt-1.2.2:0=[${MULTILIB_USEDEP}]
  26         >=sys-apps/dbus-1[${MULTILIB_USEDEP}]
  27         >=gnome-base/gnome-keyring-3.1.92
  28         introspection? ( >=dev-libs/gobject-introspection-1.30.0 )
  29 "
  30 DEPEND="${RDEPEND}
  31         dev-util/gtk-doc-am
  32         >=dev-util/intltool-0.35
  33         sys-devel/gettext
  34         virtual/pkgconfig
  35         test? ( $(python_gen_any_dep '
  36                 dev-python/pygobject:2[${PYTHON_USEDEP}]
  37                 dev-python/dbus-python[${PYTHON_USEDEP}]') )
  38         vala? ( $(vala_depend) )
  39 "
  40
  41 src_prepare() {
  42         epatch "${FILESDIR}"/${PV}-vala-0.42-compat.patch
  43         use vala && vala_src_prepare
  44         gnome2_src_prepare
  45
  46         # FIXME: Remove silly CFLAGS, report upstream
  47         sed -e 's:CFLAGS="$CFLAGS -g:CFLAGS="$CFLAGS:' \
  48                 -e 's:CFLAGS="$CFLAGS -O0:CFLAGS="$CFLAGS:' \
  49                 -i configure.ac configure || die "sed failed"
  50 }
  51
  52 multilib_src_configure() {
  53         ECONF_SOURCE="${S}" gnome2_src_configure \
  54                 $(multilib_native_use_enable vala)
  55
  56         if multilib_is_native_abi; then
  57                 ln -s "${S}"/docs/reference/gnome-keyring/html docs/reference/gnome-keyring/html || die
  58         fi
  59 }
  60
  61 multilib_src_install() {
  62         gnome2_src_install
  63 }
  64
  65 multilib_src_test() {
  66         unset DBUS_SESSION_BUS_ADDRESS
  67         dbus-launch emake check || die "tests failed"
  68 }