gnome-base/libgnome/libgnome-2.32.1-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GCONF_DEBUG="yes"
   6 GNOME2_LA_PUNT="yes"
   7 GNOME_TARBALL_SUFFIX="bz2"
   8
   9 inherit gnome2 eutils
  10
  11 DESCRIPTION="Essential Gnome Libraries"
  12 HOMEPAGE="https://library.gnome.org/devel/libgnome/stable/"
  13
  14 LICENSE="LGPL-2"
  15 SLOT="0"
  16 KEYWORDS="alpha amd64 arm ~arm64 ia64 ~mips ppc ppc64 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
  17 IUSE="branding"
  18
  19 SRC_URI="${SRC_URI}
  20         branding? ( mirror://gentoo/gentoo-gdm-theme-r3.tar.bz2 )"
  21
  22 RDEPEND="
  23         >=gnome-base/gconf-2
  24         >=dev-libs/glib-2.16:2
  25         >=gnome-base/gnome-vfs-2.5.3
  26         >=gnome-base/libbonobo-2.13
  27         >=dev-libs/popt-1.7
  28         media-libs/libcanberra
  29 "
  30 DEPEND="${RDEPEND}
  31         >=dev-lang/perl-5
  32         dev-util/gtk-doc-am
  33         >=dev-util/intltool-0.40
  34         virtual/pkgconfig
  35 "
  36
  37 PDEPEND="gnome-base/gvfs"
  38
  39 src_prepare() {
  40         # Make sure menus have icons. People don't like change
  41         epatch "${FILESDIR}/${PN}-2.28.0-menus-have-icons.patch"
  42
  43         # Remove UTF-8 character from headers
  44         # https://bugs.gentoo.org/639336
  45         epatch "${FILESDIR}"/${PN}-2.32.1-utf8-header.patch
  46
  47         use branding && epatch "${FILESDIR}"/${PN}-2.26.0-branding.patch
  48
  49         # Default to Adwaita theme over Clearlooks to proper gtk3 support
  50         sed -i -e 's/Clearlooks/Adwaita/' schemas/desktop_gnome_interface.schemas.in.in || die
  51
  52         gnome2_src_prepare
  53 }
  54
  55 src_configure() {
  56         gnome2_src_configure \
  57                 --disable-static \
  58                 --enable-canberra \
  59                 --disable-esd
  60 }
  61
  62 src_install() {
  63         gnome2_src_install
  64
  65         if use branding; then
  66                 # Add gentoo backgrounds
  67                 dodir /usr/share/pixmaps/backgrounds/gnome/gentoo
  68                 insinto /usr/share/pixmaps/backgrounds/gnome/gentoo
  69                 doins "${WORKDIR}"/gentoo-emergence/gentoo-emergence.png
  70                 doins "${WORKDIR}"/gentoo-cow/gentoo-cow-alpha.png
  71         fi
  72 }