gnome-base/libbonoboui/libbonoboui-2.24.5-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GCONF_DEBUG="no"
   6 GNOME2_LA_PUNT="yes"
   7 GNOME_TARBALL_SUFFIX="bz2"
   8
   9 inherit eutils gnome2 virtualx
  10
  11 DESCRIPTION="User Interface part of libbonobo"
  12 HOMEPAGE="https://developer.gnome.org/libbonoboui/"
  13
  14 LICENSE="GPL-2 LGPL-2.1"
  15 SLOT="0"
  16 KEYWORDS="~alpha amd64 arm ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
  17 IUSE="examples test"
  18 RESTRICT="!test? ( test )"
  19
  20 # GTK+ dep due to bug #126565
  21 RDEPEND="
  22         >=gnome-base/libgnomecanvas-1.116
  23         >=gnome-base/libbonobo-2.22
  24         >=gnome-base/libgnome-2.13.7
  25         >=dev-libs/libxml2-2.4.20:2
  26         >=gnome-base/gconf-2:2
  27         >=x11-libs/gtk+-2.8.12:2
  28         >=dev-libs/glib-2.6.0:2
  29         >=gnome-base/libglade-1.99.11:2.0
  30         >=dev-libs/popt-1.5
  31 "
  32 DEPEND="${RDEPEND}
  33         dev-util/gtk-doc-am
  34         x11-apps/xrdb
  35         sys-devel/gettext
  36         virtual/pkgconfig
  37         >=dev-util/intltool-0.40
  38 "
  39
  40 src_prepare() {
  41         if ! use test; then
  42                 # don't waste time building tests
  43                 sed 's/tests//' -i Makefile.am Makefile.in || die "sed 1 failed"
  44         fi
  45
  46         if ! use examples; then
  47                 sed 's/samples//' -i Makefile.am Makefile.in || die "sed 2 failed"
  48         fi
  49
  50         gnome2_src_prepare
  51 }
  52
  53 src_configure() {
  54         addpredict "/root/.gnome2_private"
  55         gnome2_src_configure --disable-static
  56 }
  57
  58 src_test() {
  59         addpredict "/root/.gnome2_private"
  60         Xemake check
  61 }