gnome-base/gvfs/gvfs-1.30.4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 GNOME2_LA_PUNT="yes"
   6
   7 inherit autotools bash-completion-r1 gnome2 systemd
   8
   9 DESCRIPTION="Virtual filesystem implementation for gio"
  10 HOMEPAGE="https://wiki.gnome.org/Projects/gvfs"
  11
  12 LICENSE="LGPL-2+"
  13 SLOT="0"
  14
  15 IUSE="afp archive bluray cdda fuse google gnome-keyring gnome-online-accounts gphoto2 gtk +http ios mtp nfs policykit samba systemd test +udev udisks zeroconf"
  16 REQUIRED_USE="
  17         cdda? ( udev )
  18         google? ( gnome-online-accounts )
  19         mtp? ( udev )
  20         udisks? ( udev )
  21         systemd? ( udisks )
  22 "
  23 KEYWORDS="alpha amd64 arm ~arm64 ia64 ~mips ppc ppc64 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
  24
  25 RDEPEND="
  26         app-crypt/gcr:=
  27         >=dev-libs/glib-2.49.3:2
  28         sys-apps/dbus
  29         dev-libs/libxml2:2
  30         net-misc/openssh
  31         afp? ( >=dev-libs/libgcrypt-1.2.2:0= )
  32         archive? ( app-arch/libarchive:= )
  33         bluray? ( media-libs/libbluray:= )
  34         fuse? ( >=sys-fs/fuse-2.8.0 )
  35         gnome-keyring? ( app-crypt/libsecret )
  36         gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.7.1:= )
  37         google? (
  38                 >=dev-libs/libgdata-0.17.7:=[crypt,gnome-online-accounts]
  39                 >=net-libs/gnome-online-accounts-3.17.1:= )
  40         gphoto2? ( >=media-libs/libgphoto2-2.5.0:= )
  41         gtk? ( >=x11-libs/gtk+-3.0:3 )
  42         http? ( >=net-libs/libsoup-2.42:2.4 )
  43         ios? (
  44                 >=app-pda/libimobiledevice-1.2:=
  45                 >=app-pda/libplist-1:= )
  46         mtp? ( >=media-libs/libmtp-1.1.12 )
  47         nfs? ( >=net-fs/libnfs-1.9.7 )
  48         policykit? (
  49                 sys-auth/polkit
  50                 sys-libs/libcap )
  51         samba? ( >=net-fs/samba-4[client] )
  52         systemd? ( >=sys-apps/systemd-206:0= )
  53         udev? (
  54                 cdda? ( dev-libs/libcdio-paranoia )
  55                 virtual/libgudev:=
  56                 virtual/libudev:= )
  57         udisks? ( >=sys-fs/udisks-1.97:2 )
  58         zeroconf? ( >=net-dns/avahi-0.6 )
  59 "
  60 DEPEND="${RDEPEND}
  61         app-text/docbook-xsl-stylesheets
  62         dev-libs/libxslt
  63         >=sys-devel/gettext-0.19.4
  64         virtual/pkgconfig
  65         dev-util/gdbus-codegen
  66         dev-util/gtk-doc-am
  67         test? (
  68                 >=dev-python/twisted-core-12.3.0
  69                 || (
  70                         net-analyzer/netcat
  71                         net-analyzer/netcat6 ) )
  72         !udev? ( >=dev-libs/libgcrypt-1.2.2:0 )
  73 "
  74 # libgcrypt.m4, provided by libgcrypt, needed for eautoreconf, bug #399043
  75 # test dependencies needed per https://bugzilla.gnome.org/700162
  76
  77 # Tests with multiple failures, this is being handled upstream at:
  78 # https://bugzilla.gnome.org/700162
  79 RESTRICT="test"
  80
  81 PATCHES=(
  82         "${FILESDIR}"/${PN}-1.30.2-sysmacros.patch #580234
  83 )
  84
  85 src_prepare() {
  86         if ! use udev; then
  87                 sed -e 's/gvfsd-burn/ /' \
  88                         -e 's/burn.mount.in/ /' \
  89                         -e 's/burn.mount/ /' \
  90                         -i daemon/Makefile.am || die
  91
  92                 # Uncomment when eautoreconf stops being needed always
  93                 eautoreconf
  94         fi
  95
  96         gnome2_src_prepare
  97 }
  98
  99 src_configure() {
 100         # --enable-documentation installs man pages
 101         # --disable-obexftp, upstream bug #729945
 102         gnome2_src_configure \
 103                 --disable-gdu \
 104                 --disable-hal \
 105                 --enable-bash-completion \
 106                 --enable-documentation \
 107                 --enable-gcr \
 108                 --with-bash-completion-dir="$(get_bashcompdir)" \
 109                 --with-dbus-service-dir="${EPREFIX}"/usr/share/dbus-1/services \
 110                 --with-systemduserunitdir="$(systemd_get_userunitdir)" \
 111                 $(use_enable afp) \
 112                 $(use_enable archive) \
 113                 $(use_enable bluray) \
 114                 $(use_enable cdda) \
 115                 $(use_enable fuse) \
 116                 $(use_enable gnome-keyring keyring) \
 117                 $(use_enable gnome-online-accounts goa) \
 118                 $(use_enable google) \
 119                 $(use_enable gphoto2) \
 120                 $(use_enable gtk) \
 121                 $(use_enable http) \
 122                 $(use_enable ios afc) \
 123                 $(use_enable mtp libmtp) \
 124                 $(use_enable nfs) \
 125                 $(use_enable policykit admin) \
 126                 $(use_enable samba) \
 127                 $(use_enable systemd libsystemd-login) \
 128                 $(use_enable udev gudev) \
 129                 $(use_enable udev) \
 130                 $(use_enable udisks udisks2) \
 131                 $(use_enable zeroconf avahi)
 132 }