gnome-base/gnome-menus/gnome-menus-3.13.3-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="yes"
   7
   8 inherit eutils gnome2
   9
  10 DESCRIPTION="Library for the Desktop Menu fd.o specification"
  11 HOMEPAGE="https://git.gnome.org/browse/gnome-menus"
  12
  13 LICENSE="GPL-2+ LGPL-2+"
  14 SLOT="3"
  15 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  16
  17 IUSE="+introspection test"
  18
  19 COMMON_DEPEND="
  20         >=dev-libs/glib-2.29.15:2
  21         introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
  22 "
  23 # Older versions of slot 0 install the menu editor and the desktop directories
  24 RDEPEND="${COMMON_DEPEND}
  25         !<gnome-base/gnome-menus-3.0.1-r1:0
  26 "
  27 DEPEND="${COMMON_DEPEND}
  28         >=dev-util/intltool-0.40
  29         sys-devel/gettext
  30         virtual/pkgconfig
  31         test? ( dev-libs/gjs )
  32 "
  33
  34 src_prepare() {
  35         # Don't show KDE standalone settings desktop files in GNOME others menu
  36         epatch "${FILESDIR}/${PN}-3.8.0-ignore_kde_standalone.patch"
  37
  38         # desktop-entries: support multiple desktops in XDG_CURRENT_DESKTOP
  39         # (from 'master')
  40         epatch "${FILESDIR}"/${P}-multiple-desktop{,2}.patch
  41
  42         gnome2_src_prepare
  43 }
  44
  45 src_configure() {
  46         DOCS="AUTHORS ChangeLog HACKING NEWS README"
  47
  48         # Do NOT compile with --disable-debug/--enable-debug=no
  49         # It disables api usage checks
  50         gnome2_src_configure \
  51                 $(use_enable introspection) \
  52                 --disable-static
  53 }