gnome-base/gnome-desktop/gnome-desktop-3.24.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit gnome2 virtualx
   6
   7 DESCRIPTION="Libraries for the gnome desktop that are not part of the UI"
   8 HOMEPAGE="https://git.gnome.org/browse/gnome-desktop"
   9
  10 LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
  11 SLOT="3/12" # subslot = libgnome-desktop-3 soname version
  12 IUSE="debug +introspection udev"
  13 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x86-solaris"
  14
  15 # cairo[X] needed for gnome-bg
  16 COMMON_DEPEND="
  17         app-text/iso-codes
  18         >=dev-libs/glib-2.44.0:2[dbus]
  19         >=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
  20         >=x11-libs/gtk+-3.3.6:3[X,introspection?]
  21         x11-libs/cairo:=[X]
  22         x11-libs/libX11
  23         x11-misc/xkeyboard-config
  24         >=gnome-base/gsettings-desktop-schemas-3.5.91
  25         introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
  26         udev? (
  27                 sys-apps/hwids
  28                 virtual/libudev:= )
  29 "
  30 RDEPEND="${COMMON_DEPEND}
  31         !<gnome-base/gnome-desktop-2.32.1-r1:2[doc]
  32 "
  33 DEPEND="${COMMON_DEPEND}
  34         app-text/docbook-xml-dtd:4.1.2
  35         dev-util/gdbus-codegen
  36         >=dev-util/gtk-doc-am-1.14
  37         >=dev-util/intltool-0.40.6
  38         dev-util/itstool
  39         sys-devel/gettext
  40         x11-proto/xproto
  41         virtual/pkgconfig
  42 "
  43
  44 # Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xproto
  45
  46 src_configure() {
  47         gnome2_src_configure \
  48                 --disable-static \
  49                 --with-gnome-distributor=Gentoo \
  50                 --enable-desktop-docs \
  51                 $(usex debug --enable-debug=yes ' ') \
  52                 $(use_enable debug debug-tools) \
  53                 $(use_enable introspection) \
  54                 $(use_enable udev)
  55 }
  56
  57 src_test() {
  58         virtx emake check
  59 }