gnome-base/gnome-desktop/gnome-desktop-2.32.1-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 GCONF_DEBUG="yes"
   6 GNOME2_LA_PUNT="yes"
   7 GNOME_TARBALL_SUFFIX="bz2"
   8 PYTHON_COMPAT=( python2_7 )
   9
  10 inherit gnome2 python-r1
  11
  12 DESCRIPTION="Libraries for the gnome desktop that are not part of the UI"
  13 HOMEPAGE="https://www.gnome.org/"
  14
  15 LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
  16 SLOT="2"
  17 KEYWORDS="~alpha amd64 arm ~ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
  18 IUSE="license-docs"
  19 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  20
  21 # Note: gnome-desktop:2 and :3 install identical files in /usr/share/gnome/help
  22 # and /usr/share/omf when --enable-desktop-docs is passed to configure. To avoid
  23 # file conflict and pointless duplication, gnome-desktop:2[doc] will simply use
  24 # the files that are installed by :3[doc]
  25 # Note: depend on glib-2.34 to make sure users upgrade glib before gnome-desktop
  26 # to get a fix for bug #450930
  27 RDEPEND=">=x11-libs/gtk+-2.18:2
  28         >=dev-libs/glib-2.34:2
  29         >=x11-libs/libXrandr-1.2
  30         >=gnome-base/gconf-2:2
  31         >=x11-libs/startup-notification-0.5
  32         ${PYTHON_DEPS}
  33 "
  34 DEPEND="${RDEPEND}
  35         dev-util/gtk-doc-am
  36         >=dev-util/intltool-0.40
  37         virtual/pkgconfig
  38         >=app-text/gnome-doc-utils-0.3.2
  39         ~app-text/docbook-xml-dtd-4.1.2
  40         x11-base/xorg-proto
  41 "
  42 PDEPEND=">=dev-python/pygtk-2.8:2[${PYTHON_USEDEP}]
  43         >=dev-python/pygobject-2.14:2[${PYTHON_USEDEP}]
  44         license-docs? ( gnome-base/gnome-desktop:3[doc(+)] )
  45 "
  46
  47 # Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xproto
  48 # Includes X11/extensions/Xrandr.h that includes randr.h from randrproto (and
  49 # eventually libXrandr shouldn't RDEPEND on randrproto)
  50
  51 src_prepare() {
  52         epatch "${FILESDIR}"/${P}-gold.patch
  53         epatch "${FILESDIR}"/${P}-thumbnails.patch #450930
  54         gnome2_src_prepare
  55 }
  56
  57 src_configure() {
  58         python_setup
  59         gnome2_src_configure \
  60                 --with-gnome-distributor=Gentoo \
  61                 --disable-scrollkeeper \
  62                 --disable-static \
  63                 --disable-deprecations \
  64                 --disable-desktop-docs
  65         # desktop-docs will be built by gnome-desktop:3
  66 }
  67
  68 src_install() {
  69         DOCS="AUTHORS ChangeLog HACKING NEWS README"
  70         gnome2_src_install
  71         # python-r1.eclass doesn't like versioned python shebangs
  72         sed -e 's@#!\(.*python.*\)@#!/usr/bin/env python@' -i gnome-about/gnome-about
  73         python_doscript gnome-about/gnome-about
  74 }