gnome-base/gnome-control-center/gnome-control-center-3.30.3-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome.org gnome2-utils meson xdg
   7
   8 DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
   9 HOMEPAGE="https://git.gnome.org/browse/gnome-control-center/"
  10 SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="2"
  14 IUSE="+bluetooth +cups debug elogind flickr +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager systemd v4l wayland"
  15 REQUIRED_USE="
  16         flickr? ( gnome-online-accounts )
  17         ^^ ( elogind systemd )
  18 " # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
  19 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 x86 ~amd64-linux ~x86-linux ~x86-solaris"
  20
  21 # kerberos unfortunately means mit-krb5; build fails with heimdal
  22 # display panel requires colord and gnome-settings-daemon[colord]
  23 # wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
  24 # printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
  25 # >=polkit-0.114 for .policy files gettext ITS
  26 clutter_gtk_dep="media-libs/clutter-gtk:1.0"
  27 # First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
  28 COMMON_DEPEND="
  29         gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.25.3:= )
  30         >=media-sound/pulseaudio-2.0[glib]
  31         >=sys-apps/accountsservice-0.6.39
  32         >=x11-misc/colord-0.1.34:0=
  33         >=x11-libs/gdk-pixbuf-2.23.0:2
  34         >=dev-libs/glib-2.53.0:2
  35         >=gnome-base/gnome-desktop-3.27.90:3=
  36         >=gnome-base/gnome-settings-daemon-3.25.90[colord,input_devices_wacom?]
  37         >=gnome-base/gsettings-desktop-schemas-3.27.2
  38         dev-libs/libxml2:2
  39         >=sys-auth/polkit-0.114
  40         >=sys-power/upower-0.99.6:=
  41         x11-libs/libX11
  42         >=x11-libs/libXi-1.2
  43         flickr? ( >=media-libs/grilo-0.3.0:0.3= )
  44         >=x11-libs/gtk+-3.22.0:3[X,wayland=]
  45         cups? (
  46                 >=net-print/cups-1.7[dbus]
  47                 >=net-fs/samba-4.0.0[client]
  48         )
  49         v4l? (
  50                 ${clutter_gtk_dep}
  51                 >=media-video/cheese-3.28.0 )
  52         ibus? ( >=app-i18n/ibus-1.5.2 )
  53         wayland? ( dev-libs/libgudev )
  54         networkmanager? (
  55                 >=gnome-extra/nm-applet-1.8.0
  56                 >=net-misc/networkmanager-1.10.0:=[modemmanager]
  57                 >=net-misc/modemmanager-0.7.990 )
  58         bluetooth? ( >=net-wireless/gnome-bluetooth-3.18.2:= )
  59         input_devices_wacom? (
  60                 ${clutter_gtk_dep}
  61                 >=dev-libs/libwacom-0.27
  62                 >=media-libs/clutter-1.11.3:1.0 )
  63         kerberos? ( app-crypt/mit-krb5 )
  64
  65         x11-libs/cairo[glib]
  66         >=x11-libs/colord-gtk-0.1.24
  67         net-libs/libsoup:2.4
  68         media-libs/fontconfig
  69         gnome-base/libgtop:2=
  70         app-crypt/libsecret
  71         >=media-libs/libcanberra-0.13[gtk3]
  72         >=dev-libs/libpwquality-1.2.2
  73 "
  74 # systemd/elogind USE flagged because package manager will potentially try to satisfy a
  75 # "|| ( systemd ( elogind openrc-settingsd)" via systemd if openrc-settingsd isn't already installed.
  76 # libgnomekbd needed only for gkbd-keyboard-display tool
  77 # gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
  78 # <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
  79 #
  80 # mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
  81 # Also we need newer driver versions to allow wacom and libinput drivers to
  82 # not collide
  83 #
  84 # system-config-printer provides org.fedoraproject.Config.Printing service and interface
  85 # cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
  86 RDEPEND="${COMMON_DEPEND}
  87         systemd? ( >=sys-apps/systemd-31 )
  88         elogind? ( app-admin/openrc-settingsd
  89                 sys-auth/elogind )
  90         x11-themes/adwaita-icon-theme
  91         >=gnome-extra/gnome-color-manager-3.1.2
  92         cups? (
  93                 app-admin/system-config-printer
  94                 net-print/cups-pk-helper )
  95         >=gnome-base/libgnomekbd-3
  96         wayland? ( dev-libs/libinput )
  97         !wayland? (
  98                 >=x11-drivers/xf86-input-libinput-0.19.0
  99                 input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 ) )
 100         flickr? ( media-plugins/grilo-plugins:0.3[flickr,gnome-online-accounts] )
 101
 102         !<gnome-base/gdm-2.91.94
 103         !gnome-extra/gnome-media[pulseaudio]
 104         !<gnome-extra/gnome-media-2.32.0-r300
 105         !<net-wireless/gnome-bluetooth-3.3.2
 106 "
 107 # PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
 108 # gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
 109 PDEPEND=">=gnome-base/gnome-session-2.91.6-r1"
 110
 111 DEPEND="${COMMON_DEPEND}
 112         dev-libs/libxslt
 113         app-text/docbook-xsl-stylesheets
 114         app-text/docbook-xml-dtd:4.2
 115         x11-base/xorg-proto
 116         dev-libs/libxml2:2
 117         dev-util/gdbus-codegen
 118         dev-util/glib-utils
 119         >=sys-devel/gettext-0.19.8
 120         virtual/pkgconfig
 121 "
 122
 123 PATCHES=(
 124         # Patches from gnome-3-28 branch on top of 3.28.2
 125         # Makes some panels and dependencies optional
 126         # https://bugzilla.gnome.org/686840, 697478, 700145
 127         # Fix some absolute paths to be appropriate for Gentoo
 128         "${WORKDIR}"/patches/
 129         # Extra patch to fix incomplete USE=-cups support in patchset; amend it into the cups optionality commit for next patchset
 130         "${FILESDIR}"/${PV}-conditional-cups-tests.patch
 131 )
 132
 133 src_configure() {
 134         local emesonargs=(
 135                 $(meson_use bluetooth)
 136                 $(meson_use v4l cheese)
 137                 -Dcups=$(usex cups enabled disabled)
 138                 -Ddocumentation=true # manpage
 139                 -Dgoa=$(usex gnome-online-accounts enabled disabled)
 140                 -Dgrilo=$(usex flickr enabled disabled)
 141                 $(meson_use ibus)
 142                 -Dkerberos=$(usex kerberos enabled disabled)
 143                 $(meson_use networkmanager network_manager)
 144                 -Dtracing=false
 145                 $(meson_use input_devices_wacom wacom)
 146                 $(meson_use wayland)
 147                 # bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
 148         )
 149         meson_src_configure
 150 }
 151
 152 pkg_postinst() {
 153         xdg_pkg_postinst
 154         gnome2_schemas_update
 155 }
 156
 157 pkg_postrm() {
 158         xdg_pkg_postrm
 159         gnome2_schemas_update
 160 }