gnome-base/gnome-applets/gnome-applets-3.34.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit gnome2
   6
   7 DESCRIPTION="Applets for the GNOME Flashback Panel"
   8 HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-applets/"
   9
  10 LICENSE="GPL-2+ FDL-1.1"
  11 SLOT="0"
  12 IUSE="ipv6 tracker upower"
  13 KEYWORDS="~amd64"
  14
  15 # FIXME: automagic wireless-tools
  16 # TODO: gucharmap could be optional, but no knob
  17 # TODO: libgweather could be optional, but no knob
  18 RDEPEND="
  19         >=x11-libs/gtk+-3.20.0:3[X]
  20         >=dev-libs/glib-2.44.0:2
  21         >=gnome-base/gnome-panel-3.24.1
  22         >=gnome-base/libgtop-2.11.92:=
  23         >=x11-libs/libwnck-3.14.1:3
  24         >=x11-libs/libnotify-0.7
  25         upower? ( >=sys-power/upower-0.9.4:= )
  26         >=sys-apps/dbus-1.1.2
  27         >=dev-libs/dbus-glib-0.74
  28         >=x11-themes/adwaita-icon-theme-3.14.0
  29         >=dev-libs/libxml2-2.5.0:2
  30         >=dev-libs/libgweather-3.28.0:2=
  31         >=gnome-extra/gucharmap-2.33.0:2.90
  32         >=sys-auth/polkit-0.97
  33         x11-libs/libX11
  34         tracker? ( app-misc/tracker:0/2.0 )
  35 "
  36 # app-text/docbook-sgml-utils for jw binary
  37 DEPEND="${RDEPEND}
  38         app-text/docbook-sgml-utils
  39         app-text/docbook-xml-dtd:4.1.2
  40         dev-libs/libxslt
  41         dev-util/glib-utils
  42         >=dev-util/intltool-0.35.0
  43         dev-util/itstool
  44         sys-devel/gettext
  45         x11-base/xorg-proto
  46         virtual/pkgconfig
  47 " # yelp-tools and autoconf-archive for eautoreconf
  48
  49 src_configure() {
  50         gnome2_src_configure \
  51                 --disable-static \
  52                 $(use_with upower) \
  53                 --disable-battstat \
  54                 --disable-cpufreq \
  55                 $(use_enable tracker tracker-search-bar) \
  56                 $(use_enable ipv6)
  57 }