git-svn.perl

   1 #!/usr/bin/perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use 5.008;
   5 use warnings;
   6 use strict;
   7 use vars qw/    $AUTHOR $VERSION
   8                 $sha1 $sha1_short $_revision $_repository
   9                 $_q $_authors $_authors_prog %users/;
  10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  11 $VERSION = '@@GIT_VERSION@@';
  12
  13 use Carp qw/croak/;
  14 use Digest::MD5;
  15 use IO::File qw//;
  16 use File::Basename qw/dirname basename/;
  17 use File::Path qw/mkpath/;
  18 use File::Spec;
  19 use File::Find;
  20 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  21 use IPC::Open3;
  22 use Memoize;
  23
  24 use Git::SVN;
  25 use Git::SVN::Editor;
  26 use Git::SVN::Fetcher;
  27 use Git::SVN::Ra;
  28 use Git::SVN::Prompt;
  29 use Git::SVN::Log;
  30 use Git::SVN::Migration;
  31
  32 use Git::SVN::Utils qw(fatal can_compress);
  33 use Git qw(
  34         git_cmd_try
  35         command
  36         command_oneline
  37         command_noisy
  38         command_output_pipe
  39         command_close_pipe
  40         command_bidi_pipe
  41         command_close_bidi_pipe
  42 );
  43
  44 BEGIN {
  45         Memoize::memoize 'Git::config';
  46         Memoize::memoize 'Git::config_bool';
  47 }
  48
  49
  50 # From which subdir have we been invoked?
  51 my $cmd_dir_prefix = eval {
  52         command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
  53 } || '';
  54
  55 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  56 $ENV{GIT_DIR} ||= '.git';
  57 $Git::SVN::Ra::_log_window_size = 100;
  58
  59 if (! exists $ENV{SVN_SSH} && exists $ENV{GIT_SSH}) {
  60         $ENV{SVN_SSH} = $ENV{GIT_SSH};
  61 }
  62
  63 if (exists $ENV{SVN_SSH} && $^O eq 'msys') {
  64         $ENV{SVN_SSH} =~ s/\\/\\\\/g;
  65         $ENV{SVN_SSH} =~ s/(.*)/"$1"/;
  66 }
  67
  68 $Git::SVN::Log::TZ = $ENV{TZ};
  69 $ENV{TZ} = 'UTC';
  70 $| = 1; # unbuffer STDOUT
  71
  72 # All SVN commands do it.  Otherwise we may die on SIGPIPE when the remote
  73 # repository decides to close the connection which we expect to be kept alive.
  74 $SIG{PIPE} = 'IGNORE';
  75
  76 # Given a dot separated version number, "subtract" it from
  77 # the SVN::Core::VERSION; non-negaitive return means the SVN::Core
  78 # is at least at the version the caller asked for.
  79 sub compare_svn_version {
  80         my (@ours) = split(/\./, $SVN::Core::VERSION);
  81         my (@theirs) = split(/\./, $_[0]);
  82         my ($i, $diff);
  83
  84         for ($i = 0; $i < @ours && $i < @theirs; $i++) {
  85                 $diff = $ours[$i] - $theirs[$i];
  86                 return $diff if ($diff);
  87         }
  88         return 1 if ($i < @ours);
  89         return -1 if ($i < @theirs);
  90         return 0;
  91 }
  92
  93 sub _req_svn {
  94         require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  95         require SVN::Ra;
  96         require SVN::Delta;
  97         if (::compare_svn_version('1.1.0') < 0) {
  98                 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
  99         }
 100 }
 101
 102 $sha1 = qr/[a-f\d]{40}/;
 103 $sha1_short = qr/[a-f\d]{4,40}/;
 104 my ($_stdin, $_help, $_edit,
 105         $_message, $_file, $_branch_dest,
 106         $_template, $_shared,
 107         $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
 108         $_merge, $_strategy, $_preserve_merges, $_dry_run, $_local,
 109         $_prefix, $_no_checkout, $_url, $_verbose,
 110         $_commit_url, $_tag, $_merge_info, $_interactive);
 111
 112 # This is a refactoring artifact so Git::SVN can get at this git-svn switch.
 113 sub opt_prefix { return $_prefix || '' }
 114
 115 $Git::SVN::Fetcher::_placeholder_filename = ".gitignore";
 116 $_q ||= 0;
 117 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
 118                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
 119                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
 120                     'ignore-paths=s' => \$Git::SVN::Fetcher::_ignore_regex,
 121                     'ignore-refs=s' => \$Git::SVN::Ra::_ignore_refs_regex );
 122 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
 123                 'authors-file|A=s' => \$_authors,
 124                 'authors-prog=s' => \$_authors_prog,
 125                 'repack:i' => \$Git::SVN::_repack,
 126                 'noMetadata' => \$Git::SVN::_no_metadata,
 127                 'useSvmProps' => \$Git::SVN::_use_svm_props,
 128                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
 129                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
 130                 'no-checkout' => \$_no_checkout,
 131                 'quiet|q+' => \$_q,
 132                 'repack-flags|repack-args|repack-opts=s' =>
 133                    \$Git::SVN::_repack_flags,
 134                 'use-log-author' => \$Git::SVN::_use_log_author,
 135                 'add-author-from' => \$Git::SVN::_add_author_from,
 136                 'localtime' => \$Git::SVN::_localtime,
 137                 %remote_opts );
 138
 139 my ($_trunk, @_tags, @_branches, $_stdlayout);
 140 my %icv;
 141 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
 142                   'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
 143                   'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
 144                   'stdlayout|s' => \$_stdlayout,
 145                   'minimize-url|m!' => \$Git::SVN::_minimize_url,
 146                   'no-metadata' => sub { $icv{noMetadata} = 1 },
 147                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
 148                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
 149                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
 150                   'rewrite-uuid=s' => sub { $icv{rewriteUUID} = $_[1] },
 151                   %remote_opts );
 152 my %cmt_opts = ( 'edit|e' => \$_edit,
 153                 'rmdir' => \$Git::SVN::Editor::_rmdir,
 154                 'find-copies-harder' => \$Git::SVN::Editor::_find_copies_harder,
 155                 'l=i' => \$Git::SVN::Editor::_rename_limit,
 156                 'copy-similarity|C=i'=> \$Git::SVN::Editor::_cp_similarity
 157 );
 158
 159 my %cmd = (
 160         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
 161                         { 'revision|r=s' => \$_revision,
 162                           'fetch-all|all' => \$_fetch_all,
 163                           'parent|p' => \$_fetch_parent,
 164                            %fc_opts } ],
 165         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 166                         { 'revision|r=s' => \$_revision,
 167                           'preserve-empty-dirs' =>
 168                                 \$Git::SVN::Fetcher::_preserve_empty_dirs,
 169                           'placeholder-filename=s' =>
 170                                 \$Git::SVN::Fetcher::_placeholder_filename,
 171                            %fc_opts, %init_opts } ],
 172         init => [ \&cmd_init, "Initialize a repo for tracking" .
 173                           " (requires URL argument)",
 174                           \%init_opts ],
 175         'multi-init' => [ \&cmd_multi_init,
 176                           "Deprecated alias for ".
 177                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 178                           \%init_opts ],
 179         dcommit => [ \&cmd_dcommit,
 180                      'Commit several diffs to merge with upstream',
 181                         { 'merge|m|M' => \$_merge,
 182                           'strategy|s=s' => \$_strategy,
 183                           'verbose|v' => \$_verbose,
 184                           'dry-run|n' => \$_dry_run,
 185                           'fetch-all|all' => \$_fetch_all,
 186                           'commit-url=s' => \$_commit_url,
 187                           'revision|r=i' => \$_revision,
 188                           'no-rebase' => \$_no_rebase,
 189                           'mergeinfo=s' => \$_merge_info,
 190                           'interactive|i' => \$_interactive,
 191                         %cmt_opts, %fc_opts } ],
 192         branch => [ \&cmd_branch,
 193                     'Create a branch in the SVN repository',
 194                     { 'message|m=s' => \$_message,
 195                       'destination|d=s' => \$_branch_dest,
 196                       'dry-run|n' => \$_dry_run,
 197                       'tag|t' => \$_tag,
 198                       'username=s' => \$Git::SVN::Prompt::_username,
 199                       'commit-url=s' => \$_commit_url } ],
 200         tag => [ sub { $_tag = 1; cmd_branch(@_) },
 201                  'Create a tag in the SVN repository',
 202                  { 'message|m=s' => \$_message,
 203                    'destination|d=s' => \$_branch_dest,
 204                    'dry-run|n' => \$_dry_run,
 205                    'username=s' => \$Git::SVN::Prompt::_username,
 206                    'commit-url=s' => \$_commit_url } ],
 207         'set-tree' => [ \&cmd_set_tree,
 208                         "Set an SVN repository to a git tree-ish",
 209                         { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
 210         'create-ignore' => [ \&cmd_create_ignore,
 211                              'Create a .gitignore per svn:ignore',
 212                              { 'revision|r=i' => \$_revision
 213                              } ],
 214         'mkdirs' => [ \&cmd_mkdirs ,
 215                       "recreate empty directories after a checkout",
 216                       { 'revision|r=i' => \$_revision } ],
 217         'propget' => [ \&cmd_propget,
 218                        'Print the value of a property on a file or directory',
 219                        { 'revision|r=i' => \$_revision } ],
 220         'proplist' => [ \&cmd_proplist,
 221                        'List all properties of a file or directory',
 222                        { 'revision|r=i' => \$_revision } ],
 223         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 224                         { 'revision|r=i' => \$_revision
 225                         } ],
 226         'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
 227                         { 'revision|r=i' => \$_revision
 228                         } ],
 229         'multi-fetch' => [ \&cmd_multi_fetch,
 230                            "Deprecated alias for $0 fetch --all",
 231                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 232         'migrate' => [ sub { },
 233                        # no-op, we automatically run this anyways,
 234                        'Migrate configuration/metadata/layout from
 235                         previous versions of git-svn',
 236                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 237                          %remote_opts } ],
 238         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 239                         { 'limit=i' => \$Git::SVN::Log::limit,
 240                           'revision|r=s' => \$_revision,
 241                           'verbose|v' => \$Git::SVN::Log::verbose,
 242                           'incremental' => \$Git::SVN::Log::incremental,
 243                           'oneline' => \$Git::SVN::Log::oneline,
 244                           'show-commit' => \$Git::SVN::Log::show_commit,
 245                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 246                           'authors-file|A=s' => \$_authors,
 247                           'color' => \$Git::SVN::Log::color,
 248                           'pager=s' => \$Git::SVN::Log::pager
 249                         } ],
 250         'find-rev' => [ \&cmd_find_rev,
 251                         "Translate between SVN revision numbers and tree-ish",
 252                         {} ],
 253         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 254                         { 'merge|m|M' => \$_merge,
 255                           'verbose|v' => \$_verbose,
 256                           'strategy|s=s' => \$_strategy,
 257                           'local|l' => \$_local,
 258                           'fetch-all|all' => \$_fetch_all,
 259                           'dry-run|n' => \$_dry_run,
 260                           'preserve-merges|p' => \$_preserve_merges,
 261                           %fc_opts } ],
 262         'commit-diff' => [ \&cmd_commit_diff,
 263                            'Commit a diff between two trees',
 264                         { 'message|m=s' => \$_message,
 265                           'file|F=s' => \$_file,
 266                           'revision|r=s' => \$_revision,
 267                         %cmt_opts } ],
 268         'info' => [ \&cmd_info,
 269                     "Show info about the latest SVN revision
 270                      on the current branch",
 271                     { 'url' => \$_url, } ],
 272         'blame' => [ \&Git::SVN::Log::cmd_blame,
 273                     "Show what revision and author last modified each line of a file",
 274                     { 'git-format' => \$Git::SVN::Log::_git_format } ],
 275         'reset' => [ \&cmd_reset,
 276                      "Undo fetches back to the specified SVN revision",
 277                      { 'revision|r=s' => \$_revision,
 278                        'parent|p' => \$_fetch_parent } ],
 279         'gc' => [ \&cmd_gc,
 280                   "Compress unhandled.log files in .git/svn and remove " .
 281                   "index files in .git/svn",
 282                 {} ],
 283 );
 284
 285 use Term::ReadLine;
 286 package FakeTerm;
 287 sub new {
 288         my ($class, $reason) = @_;
 289         return bless \$reason, shift;
 290 }
 291 sub readline {
 292         my $self = shift;
 293         die "Cannot use readline on FakeTerm: $$self";
 294 }
 295 package main;
 296
 297 my $term = eval {
 298         $ENV{"GIT_SVN_NOTTY"}
 299                 ? new Term::ReadLine 'git-svn', \*STDIN, \*STDOUT
 300                 : new Term::ReadLine 'git-svn';
 301 };
 302 if ($@) {
 303         $term = new FakeTerm "$@: going non-interactive";
 304 }
 305
 306 my $cmd;
 307 for (my $i = 0; $i < @ARGV; $i++) {
 308         if (defined $cmd{$ARGV[$i]}) {
 309                 $cmd = $ARGV[$i];
 310                 splice @ARGV, $i, 1;
 311                 last;
 312         } elsif ($ARGV[$i] eq 'help') {
 313                 $cmd = $ARGV[$i+1];
 314                 usage(0);
 315         }
 316 };
 317
 318 # make sure we're always running at the top-level working directory
 319 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
 320         unless (-d $ENV{GIT_DIR}) {
 321                 if ($git_dir_user_set) {
 322                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 323                             "but it is not a directory\n";
 324                 }
 325                 my $git_dir = delete $ENV{GIT_DIR};
 326                 my $cdup = undef;
 327                 git_cmd_try {
 328                         $cdup = command_oneline(qw/rev-parse --show-cdup/);
 329                         $git_dir = '.' unless ($cdup);
 330                         chomp $cdup if ($cdup);
 331                         $cdup = "." unless ($cdup && length $cdup);
 332                 } "Already at toplevel, but $git_dir not found\n";
 333                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 334                 unless (-d $git_dir) {
 335                         die "$git_dir still not found after going to ",
 336                             "'$cdup'\n";
 337                 }
 338                 $ENV{GIT_DIR} = $git_dir;
 339         }
 340         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 341 }
 342
 343 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 344
 345 read_git_config(\%opts);
 346 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
 347         Getopt::Long::Configure('pass_through');
 348 }
 349 my $rv = GetOptions(%opts, 'h|H' => \$_help, 'version|V' => \$_version,
 350                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 351                     'id|i=s' => \$Git::SVN::default_ref_id,
 352                     'svn-remote|remote|R=s' => sub {
 353                        $Git::SVN::no_reuse_existing = 1;
 354                        $Git::SVN::default_repo_id = $_[1] });
 355 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 356
 357 usage(0) if $_help;
 358 version() if $_version;
 359 usage(1) unless defined $cmd;
 360 load_authors() if $_authors;
 361 if (defined $_authors_prog) {
 362         $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
 363 }
 364
 365 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 366         Git::SVN::Migration::migration_check();
 367 }
 368 Git::SVN::init_vars();
 369 eval {
 370         Git::SVN::verify_remotes_sanity();
 371         $cmd{$cmd}->[0]->(@ARGV);
 372         post_fetch_checkout();
 373 };
 374 fatal $@ if $@;
 375 exit 0;
 376
 377 ####################### primary functions ######################
 378 sub usage {
 379         my $exit = shift || 0;
 380         my $fd = $exit ? \*STDERR : \*STDOUT;
 381         print $fd <<"";
 382 git-svn - bidirectional operations between a single Subversion tree and git
 383 Usage: git svn <command> [options] [arguments]\n
 384
 385         print $fd "Available commands:\n" unless $cmd;
 386
 387         foreach (sort keys %cmd) {
 388                 next if $cmd && $cmd ne $_;
 389                 next if /^multi-/; # don't show deprecated commands
 390                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 391                 foreach (sort keys %{$cmd{$_}->[2]}) {
 392                         # mixed-case options are for .git/config only
 393                         next if /[A-Z]/ && /^[a-z]+$/i;
 394                         # prints out arguments as they should be passed:
 395                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 396                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 397                                                         "--$_" : "-$_" }
 398                                                 split /\|/,$_)," $x\n";
 399                 }
 400         }
 401         print $fd <<"";
 402 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 403 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 404 one git repository and want to keep them separate.  See git-svn(1) for more
 405 information.
 406
 407         exit $exit;
 408 }
 409
 410 sub version {
 411         ::_req_svn();
 412         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 413         exit 0;
 414 }
 415
 416 sub ask {
 417         my ($prompt, %arg) = @_;
 418         my $valid_re = $arg{valid_re};
 419         my $default = $arg{default};
 420         my $resp;
 421         my $i = 0;
 422
 423         if ( !( defined($term->IN)
 424             && defined( fileno($term->IN) )
 425             && defined( $term->OUT )
 426             && defined( fileno($term->OUT) ) ) ){
 427                 return defined($default) ? $default : undef;
 428         }
 429
 430         while ($i++ < 10) {
 431                 $resp = $term->readline($prompt);
 432                 if (!defined $resp) { # EOF
 433                         print "\n";
 434                         return defined $default ? $default : undef;
 435                 }
 436                 if ($resp eq '' and defined $default) {
 437                         return $default;
 438                 }
 439                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 440                         return $resp;
 441                 }
 442         }
 443         return undef;
 444 }
 445
 446 sub do_git_init_db {
 447         unless (-d $ENV{GIT_DIR}) {
 448                 my @init_db = ('init');
 449                 push @init_db, "--template=$_template" if defined $_template;
 450                 if (defined $_shared) {
 451                         if ($_shared =~ /[a-z]/) {
 452                                 push @init_db, "--shared=$_shared";
 453                         } else {
 454                                 push @init_db, "--shared";
 455                         }
 456                 }
 457                 command_noisy(@init_db);
 458                 $_repository = Git->repository(Repository => ".git");
 459         }
 460         my $set;
 461         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 462         foreach my $i (keys %icv) {
 463                 die "'$set' and '$i' cannot both be set\n" if $set;
 464                 next unless defined $icv{$i};
 465                 command_noisy('config', "$pfx.$i", $icv{$i});
 466                 $set = $i;
 467         }
 468         my $ignore_paths_regex = \$Git::SVN::Fetcher::_ignore_regex;
 469         command_noisy('config', "$pfx.ignore-paths", $$ignore_paths_regex)
 470                 if defined $$ignore_paths_regex;
 471         my $ignore_refs_regex = \$Git::SVN::Ra::_ignore_refs_regex;
 472         command_noisy('config', "$pfx.ignore-refs", $$ignore_refs_regex)
 473                 if defined $$ignore_refs_regex;
 474
 475         if (defined $Git::SVN::Fetcher::_preserve_empty_dirs) {
 476                 my $fname = \$Git::SVN::Fetcher::_placeholder_filename;
 477                 command_noisy('config', "$pfx.preserve-empty-dirs", 'true');
 478                 command_noisy('config', "$pfx.placeholder-filename", $$fname);
 479         }
 480 }
 481
 482 sub init_subdir {
 483         my $repo_path = shift or return;
 484         mkpath([$repo_path]) unless -d $repo_path;
 485         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 486         $ENV{GIT_DIR} = '.git';
 487         $_repository = Git->repository(Repository => $ENV{GIT_DIR});
 488 }
 489
 490 sub cmd_clone {
 491         my ($url, $path) = @_;
 492         if (!defined $path &&
 493             (defined $_trunk || @_branches || @_tags ||
 494              defined $_stdlayout) &&
 495             $url !~ m#^[a-z\+]+://#) {
 496                 $path = $url;
 497         }
 498         $path = basename($url) if !defined $path || !length $path;
 499         my $authors_absolute = $_authors ? File::Spec->rel2abs($_authors) : "";
 500         cmd_init($url, $path);
 501         command_oneline('config', 'svn.authorsfile', $authors_absolute)
 502             if $_authors;
 503         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 504 }
 505
 506 sub cmd_init {
 507         if (defined $_stdlayout) {
 508                 $_trunk = 'trunk' if (!defined $_trunk);
 509                 @_tags = 'tags' if (! @_tags);
 510                 @_branches = 'branches' if (! @_branches);
 511         }
 512         if (defined $_trunk || @_branches || @_tags) {
 513                 return cmd_multi_init(@_);
 514         }
 515         my $url = shift or die "SVN repository location required ",
 516                                "as a command-line argument\n";
 517         $url = canonicalize_url($url);
 518         init_subdir(@_);
 519         do_git_init_db();
 520
 521         if ($Git::SVN::_minimize_url eq 'unset') {
 522                 $Git::SVN::_minimize_url = 0;
 523         }
 524
 525         Git::SVN->init($url);
 526 }
 527
 528 sub cmd_fetch {
 529         if (grep /^\d+=./, @_) {
 530                 die "'<rev>=<commit>' fetch arguments are ",
 531                     "no longer supported.\n";
 532         }
 533         my ($remote) = @_;
 534         if (@_ > 1) {
 535                 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
 536         }
 537         $Git::SVN::no_reuse_existing = undef;
 538         if ($_fetch_parent) {
 539                 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 540                 unless ($gs) {
 541                         die "Unable to determine upstream SVN information from ",
 542                             "working tree history\n";
 543                 }
 544                 # just fetch, don't checkout.
 545                 $_no_checkout = 'true';
 546                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 547         } elsif ($_fetch_all) {
 548                 cmd_multi_fetch();
 549         } else {
 550                 $remote ||= $Git::SVN::default_repo_id;
 551                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 552         }
 553 }
 554
 555 sub cmd_set_tree {
 556         my (@commits) = @_;
 557         if ($_stdin || !@commits) {
 558                 print "Reading from stdin...\n";
 559                 @commits = ();
 560                 while (<STDIN>) {
 561                         if (/\b($sha1_short)\b/o) {
 562                                 unshift @commits, $1;
 563                         }
 564                 }
 565         }
 566         my @revs;
 567         foreach my $c (@commits) {
 568                 my @tmp = command('rev-parse',$c);
 569                 if (scalar @tmp == 1) {
 570                         push @revs, $tmp[0];
 571                 } elsif (scalar @tmp > 1) {
 572                         push @revs, reverse(command('rev-list',@tmp));
 573                 } else {
 574                         fatal "Failed to rev-parse $c";
 575                 }
 576         }
 577         my $gs = Git::SVN->new;
 578         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 579         $gs->fetch;
 580         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 581                 fatal "There are new revisions that were fetched ",
 582                       "and need to be merged (or acknowledged) ",
 583                       "before committing.\nlast rev: $r_last\n",
 584                       " current: $gs->{last_rev}";
 585         }
 586         $gs->set_tree($_) foreach @revs;
 587         print "Done committing ",scalar @revs," revisions to SVN\n";
 588         unlink $gs->{index};
 589 }
 590
 591 sub split_merge_info_range {
 592         my ($range) = @_;
 593         if ($range =~ /(\d+)-(\d+)/) {
 594                 return (int($1), int($2));
 595         } else {
 596                 return (int($range), int($range));
 597         }
 598 }
 599
 600 sub combine_ranges {
 601         my ($in) = @_;
 602
 603         my @fnums = ();
 604         my @arr = split(/,/, $in);
 605         for my $element (@arr) {
 606                 my ($start, $end) = split_merge_info_range($element);
 607                 push @fnums, $start;
 608         }
 609
 610         my @sorted = @arr [ sort {
 611                 $fnums[$a] <=> $fnums[$b]
 612         } 0..$#arr ];
 613
 614         my @return = ();
 615         my $last = -1;
 616         my $first = -1;
 617         for my $element (@sorted) {
 618                 my ($start, $end) = split_merge_info_range($element);
 619
 620                 if ($last == -1) {
 621                         $first = $start;
 622                         $last = $end;
 623                         next;
 624                 }
 625                 if ($start <= $last+1) {
 626                         if ($end > $last) {
 627                                 $last = $end;
 628                         }
 629                         next;
 630                 }
 631                 if ($first == $last) {
 632                         push @return, "$first";
 633                 } else {
 634                         push @return, "$first-$last";
 635                 }
 636                 $first = $start;
 637                 $last = $end;
 638         }
 639
 640         if ($first != -1) {
 641                 if ($first == $last) {
 642                         push @return, "$first";
 643                 } else {
 644                         push @return, "$first-$last";
 645                 }
 646         }
 647
 648         return join(',', @return);
 649 }
 650
 651 sub merge_revs_into_hash {
 652         my ($hash, $minfo) = @_;
 653         my @lines = split(' ', $minfo);
 654
 655         for my $line (@lines) {
 656                 my ($branchpath, $revs) = split(/:/, $line);
 657
 658                 if (exists($hash->{$branchpath})) {
 659                         # Merge the two revision sets
 660                         my $combined = "$hash->{$branchpath},$revs";
 661                         $hash->{$branchpath} = combine_ranges($combined);
 662                 } else {
 663                         # Just do range combining for consolidation
 664                         $hash->{$branchpath} = combine_ranges($revs);
 665                 }
 666         }
 667 }
 668
 669 sub merge_merge_info {
 670         my ($mergeinfo_one, $mergeinfo_two) = @_;
 671         my %result_hash = ();
 672
 673         merge_revs_into_hash(\%result_hash, $mergeinfo_one);
 674         merge_revs_into_hash(\%result_hash, $mergeinfo_two);
 675
 676         my $result = '';
 677         # Sort below is for consistency's sake
 678         for my $branchname (sort keys(%result_hash)) {
 679                 my $revlist = $result_hash{$branchname};
 680                 $result .= "$branchname:$revlist\n"
 681         }
 682         return $result;
 683 }
 684
 685 sub populate_merge_info {
 686         my ($d, $gs, $uuid, $linear_refs, $rewritten_parent) = @_;
 687
 688         my %parentshash;
 689         read_commit_parents(\%parentshash, $d);
 690         my @parents = @{$parentshash{$d}};
 691         if ($#parents > 0) {
 692                 # Merge commit
 693                 my $all_parents_ok = 1;
 694                 my $aggregate_mergeinfo = '';
 695                 my $rooturl = $gs->repos_root;
 696
 697                 if (defined($rewritten_parent)) {
 698                         # Replace first parent with newly-rewritten version
 699                         shift @parents;
 700                         unshift @parents, $rewritten_parent;
 701                 }
 702
 703                 foreach my $parent (@parents) {
 704                         my ($branchurl, $svnrev, $paruuid) =
 705                                 cmt_metadata($parent);
 706
 707                         unless (defined($svnrev)) {
 708                                 # Should have been caught be preflight check
 709                                 fatal "merge commit $d has ancestor $parent, but that change "
 710                      ."does not have git-svn metadata!";
 711                         }
 712                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 713                                 fatal "commit $parent git-svn metadata changed mid-run!";
 714                         }
 715                         my $branchpath = $1;
 716
 717                         my $ra = Git::SVN::Ra->new($branchurl);
 718                         my (undef, undef, $props) =
 719                                 $ra->get_dir(canonicalize_path("."), $svnrev);
 720                         my $par_mergeinfo = $props->{'svn:mergeinfo'};
 721                         unless (defined $par_mergeinfo) {
 722                                 $par_mergeinfo = '';
 723                         }
 724                         # Merge previous mergeinfo values
 725                         $aggregate_mergeinfo =
 726                                 merge_merge_info($aggregate_mergeinfo,
 727                                                                  $par_mergeinfo, 0);
 728
 729                         next if $parent eq $parents[0]; # Skip first parent
 730                         # Add new changes being placed in tree by merge
 731                         my @cmd = (qw/rev-list --reverse/,
 732                                            $parent, qw/--not/);
 733                         foreach my $par (@parents) {
 734                                 unless ($par eq $parent) {
 735                                         push @cmd, $par;
 736                                 }
 737                         }
 738                         my @revsin = ();
 739                         my ($revlist, $ctx) = command_output_pipe(@cmd);
 740                         while (<$revlist>) {
 741                                 my $irev = $_;
 742                                 chomp $irev;
 743                                 my (undef, $csvnrev, undef) =
 744                                         cmt_metadata($irev);
 745                                 unless (defined $csvnrev) {
 746                                         # A child is missing SVN annotations...
 747                                         # this might be OK, or might not be.
 748                                         warn "W:child $irev is merged into revision "
 749                                                  ."$d but does not have git-svn metadata. "
 750                                                  ."This means git-svn cannot determine the "
 751                                                  ."svn revision numbers to place into the "
 752                                                  ."svn:mergeinfo property. You must ensure "
 753                                                  ."a branch is entirely committed to "
 754                                                  ."SVN before merging it in order for "
 755                                                  ."svn:mergeinfo population to function "
 756                                                  ."properly";
 757                                 }
 758                                 push @revsin, $csvnrev;
 759                         }
 760                         command_close_pipe($revlist, $ctx);
 761
 762                         last unless $all_parents_ok;
 763
 764                         # We now have a list of all SVN revnos which are
 765                         # merged by this particular parent. Integrate them.
 766                         next if $#revsin == -1;
 767                         my $newmergeinfo = "$branchpath:" . join(',', @revsin);
 768                         $aggregate_mergeinfo =
 769                                 merge_merge_info($aggregate_mergeinfo,
 770                                                                  $newmergeinfo, 1);
 771                 }
 772                 if ($all_parents_ok and $aggregate_mergeinfo) {
 773                         return $aggregate_mergeinfo;
 774                 }
 775         }
 776
 777         return undef;
 778 }
 779
 780 sub cmd_dcommit {
 781         my $head = shift;
 782         command_noisy(qw/update-index --refresh/);
 783         git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
 784                 'Cannot dcommit with a dirty index.  Commit your changes first, '
 785                 . "or stash them with `git stash'.\n";
 786         $head ||= 'HEAD';
 787
 788         my $old_head;
 789         if ($head ne 'HEAD') {
 790                 $old_head = eval {
 791                         command_oneline([qw/symbolic-ref -q HEAD/])
 792                 };
 793                 if ($old_head) {
 794                         $old_head =~ s{^refs/heads/}{};
 795                 } else {
 796                         $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
 797                 }
 798                 command(['checkout', $head], STDERR => 0);
 799         }
 800
 801         my @refs;
 802         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
 803         unless ($gs) {
 804                 die "Unable to determine upstream SVN information from ",
 805                     "$head history.\nPerhaps the repository is empty.";
 806         }
 807
 808         if (defined $_commit_url) {
 809                 $url = $_commit_url;
 810         } else {
 811                 $url = eval { command_oneline('config', '--get',
 812                               "svn-remote.$gs->{repo_id}.commiturl") };
 813                 if (!$url) {
 814                         $url = $gs->full_pushurl
 815                 }
 816         }
 817
 818         my $last_rev = $_revision if defined $_revision;
 819         if ($url) {
 820                 print "Committing to $url ...\n";
 821         }
 822         my ($linear_refs, $parents) = linearize_history($gs, \@refs);
 823         if ($_no_rebase && scalar(@$linear_refs) > 1) {
 824                 warn "Attempting to commit more than one change while ",
 825                      "--no-rebase is enabled.\n",
 826                      "If these changes depend on each other, re-running ",
 827                      "without --no-rebase may be required."
 828         }
 829
 830         if (defined $_interactive){
 831                 my $ask_default = "y";
 832                 foreach my $d (@$linear_refs){
 833                         my ($fh, $ctx) = command_output_pipe(qw(show --summary), "$d");
 834                         while (<$fh>){
 835                                 print $_;
 836                         }
 837                         command_close_pipe($fh, $ctx);
 838                         $_ = ask("Commit this patch to SVN? ([y]es (default)|[n]o|[q]uit|[a]ll): ",
 839                                  valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 840                                  default => $ask_default);
 841                         die "Commit this patch reply required" unless defined $_;
 842                         if (/^[nq]/i) {
 843                                 exit(0);
 844                         } elsif (/^a/i) {
 845                                 last;
 846                         }
 847                 }
 848         }
 849
 850         my $expect_url = $url;
 851
 852         my $push_merge_info = eval {
 853                 command_oneline(qw/config --get svn.pushmergeinfo/)
 854                 };
 855         if (not defined($push_merge_info)
 856                         or $push_merge_info eq "false"
 857                         or $push_merge_info eq "no"
 858                         or $push_merge_info eq "never") {
 859                 $push_merge_info = 0;
 860         }
 861
 862         unless (defined($_merge_info) || ! $push_merge_info) {
 863                 # Preflight check of changes to ensure no issues with mergeinfo
 864                 # This includes check for uncommitted-to-SVN parents
 865                 # (other than the first parent, which we will handle),
 866                 # information from different SVN repos, and paths
 867                 # which are not underneath this repository root.
 868                 my $rooturl = $gs->repos_root;
 869                 foreach my $d (@$linear_refs) {
 870                         my %parentshash;
 871                         read_commit_parents(\%parentshash, $d);
 872                         my @realparents = @{$parentshash{$d}};
 873                         if ($#realparents > 0) {
 874                                 # Merge commit
 875                                 shift @realparents; # Remove/ignore first parent
 876                                 foreach my $parent (@realparents) {
 877                                         my ($branchurl, $svnrev, $paruuid) = cmt_metadata($parent);
 878                                         unless (defined $paruuid) {
 879                                                 # A parent is missing SVN annotations...
 880                                                 # abort the whole operation.
 881                                                 fatal "$parent is merged into revision $d, "
 882                                                          ."but does not have git-svn metadata. "
 883                                                          ."Either dcommit the branch or use a "
 884                                                          ."local cherry-pick, FF merge, or rebase "
 885                                                          ."instead of an explicit merge commit.";
 886                                         }
 887
 888                                         unless ($paruuid eq $uuid) {
 889                                                 # Parent has SVN metadata from different repository
 890                                                 fatal "merge parent $parent for change $d has "
 891                                                          ."git-svn uuid $paruuid, while current change "
 892                                                          ."has uuid $uuid!";
 893                                         }
 894
 895                                         unless ($branchurl =~ /^\Q$rooturl\E(.*)/) {
 896                                                 # This branch is very strange indeed.
 897                                                 fatal "merge parent $parent for $d is on branch "
 898                                                          ."$branchurl, which is not under the "
 899                                                          ."git-svn root $rooturl!";
 900                                         }
 901                                 }
 902                         }
 903                 }
 904         }
 905
 906         my $rewritten_parent;
 907         Git::SVN::remove_username($expect_url);
 908         if (defined($_merge_info)) {
 909                 $_merge_info =~ tr{ }{\n};
 910         }
 911         while (1) {
 912                 my $d = shift @$linear_refs or last;
 913                 unless (defined $last_rev) {
 914                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 915                         unless (defined $last_rev) {
 916                                 fatal "Unable to extract revision information ",
 917                                       "from commit $d~1";
 918                         }
 919                 }
 920                 if ($_dry_run) {
 921                         print "diff-tree $d~1 $d\n";
 922                 } else {
 923                         my $cmt_rev;
 924
 925                         unless (defined($_merge_info) || ! $push_merge_info) {
 926                                 $_merge_info = populate_merge_info($d, $gs,
 927                                                              $uuid,
 928                                                              $linear_refs,
 929                                                              $rewritten_parent);
 930                         }
 931
 932                         my %ed_opts = ( r => $last_rev,
 933                                         log => get_commit_entry($d)->{log},
 934                                         ra => Git::SVN::Ra->new($url),
 935                                         config => SVN::Core::config_get_config(
 936                                                 $Git::SVN::Ra::config_dir
 937                                         ),
 938                                         tree_a => "$d~1",
 939                                         tree_b => $d,
 940                                         editor_cb => sub {
 941                                                print "Committed r$_[0]\n";
 942                                                $cmt_rev = $_[0];
 943                                         },
 944                                         mergeinfo => $_merge_info,
 945                                         svn_path => '');
 946                         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
 947                                 print "No changes\n$d~1 == $d\n";
 948                         } elsif ($parents->{$d} && @{$parents->{$d}}) {
 949                                 $gs->{inject_parents_dcommit}->{$cmt_rev} =
 950                                                                $parents->{$d};
 951                         }
 952                         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 953                         $last_rev = $cmt_rev;
 954                         next if $_no_rebase;
 955
 956                         # we always want to rebase against the current HEAD,
 957                         # not any head that was passed to us
 958                         my @diff = command('diff-tree', $d,
 959                                            $gs->refname, '--');
 960                         my @finish;
 961                         if (@diff) {
 962                                 @finish = rebase_cmd();
 963                                 print STDERR "W: $d and ", $gs->refname,
 964                                              " differ, using @finish:\n",
 965                                              join("\n", @diff), "\n";
 966                         } else {
 967                                 print "No changes between current HEAD and ",
 968                                       $gs->refname,
 969                                       "\nResetting to the latest ",
 970                                       $gs->refname, "\n";
 971                                 @finish = qw/reset --mixed/;
 972                         }
 973                         command_noisy(@finish, $gs->refname);
 974
 975                         $rewritten_parent = command_oneline(qw/rev-parse HEAD/);
 976
 977                         if (@diff) {
 978                                 @refs = ();
 979                                 my ($url_, $rev_, $uuid_, $gs_) =
 980                                               working_head_info('HEAD', \@refs);
 981                                 my ($linear_refs_, $parents_) =
 982                                               linearize_history($gs_, \@refs);
 983                                 if (scalar(@$linear_refs) !=
 984                                     scalar(@$linear_refs_)) {
 985                                         fatal "# of revisions changed ",
 986                                           "\nbefore:\n",
 987                                           join("\n", @$linear_refs),
 988                                           "\n\nafter:\n",
 989                                           join("\n", @$linear_refs_), "\n",
 990                                           'If you are attempting to commit ',
 991                                           "merges, try running:\n\t",
 992                                           'git rebase --interactive',
 993                                           '--preserve-merges ',
 994                                           $gs->refname,
 995                                           "\nBefore dcommitting";
 996                                 }
 997                                 if ($url_ ne $expect_url) {
 998                                         if ($url_ eq $gs->metadata_url) {
 999                                                 print
1000                                                   "Accepting rewritten URL:",
1001                                                   " $url_\n";
1002                                         } else {
1003                                                 fatal
1004                                                   "URL mismatch after rebase:",
1005                                                   " $url_ != $expect_url";
1006                                         }
1007                                 }
1008                                 if ($uuid_ ne $uuid) {
1009                                         fatal "uuid mismatch after rebase: ",
1010                                               "$uuid_ != $uuid";
1011                                 }
1012                                 # remap parents
1013                                 my (%p, @l, $i);
1014                                 for ($i = 0; $i < scalar @$linear_refs; $i++) {
1015                                         my $new = $linear_refs_->[$i] or next;
1016                                         $p{$new} =
1017                                                 $parents->{$linear_refs->[$i]};
1018                                         push @l, $new;
1019                                 }
1020                                 $parents = \%p;
1021                                 $linear_refs = \@l;
1022                         }
1023                 }
1024         }
1025
1026         if ($old_head) {
1027                 my $new_head = command_oneline(qw/rev-parse HEAD/);
1028                 my $new_is_symbolic = eval {
1029                         command_oneline(qw/symbolic-ref -q HEAD/);
1030                 };
1031                 if ($new_is_symbolic) {
1032                         print "dcommitted the branch ", $head, "\n";
1033                 } else {
1034                         print "dcommitted on a detached HEAD because you gave ",
1035                               "a revision argument.\n",
1036                               "The rewritten commit is: ", $new_head, "\n";
1037                 }
1038                 command(['checkout', $old_head], STDERR => 0);
1039         }
1040
1041         unlink $gs->{index};
1042 }
1043
1044 sub cmd_branch {
1045         my ($branch_name, $head) = @_;
1046
1047         unless (defined $branch_name && length $branch_name) {
1048                 die(($_tag ? "tag" : "branch") . " name required\n");
1049         }
1050         $head ||= 'HEAD';
1051
1052         my (undef, $rev, undef, $gs) = working_head_info($head);
1053         my $src = $gs->full_pushurl;
1054
1055         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1056         my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
1057         my $glob;
1058         if ($#{$allglobs} == 0) {
1059                 $glob = $allglobs->[0];
1060         } else {
1061                 unless(defined $_branch_dest) {
1062                         die "Multiple ",
1063                             $_tag ? "tag" : "branch",
1064                             " paths defined for Subversion repository.\n",
1065                             "You must specify where you want to create the ",
1066                             $_tag ? "tag" : "branch",
1067                             " with the --destination argument.\n";
1068                 }
1069                 foreach my $g (@{$allglobs}) {
1070                         my $re = Git::SVN::Editor::glob2pat($g->{path}->{left});
1071                         if ($_branch_dest =~ /$re/) {
1072                                 $glob = $g;
1073                                 last;
1074                         }
1075                 }
1076                 unless (defined $glob) {
1077                         my $dest_re = qr/\b\Q$_branch_dest\E\b/;
1078                         foreach my $g (@{$allglobs}) {
1079                                 $g->{path}->{left} =~ /$dest_re/ or next;
1080                                 if (defined $glob) {
1081                                         die "Ambiguous destination: ",
1082                                             $_branch_dest, "\nmatches both '",
1083                                             $glob->{path}->{left}, "' and '",
1084                                             $g->{path}->{left}, "'\n";
1085                                 }
1086                                 $glob = $g;
1087                         }
1088                         unless (defined $glob) {
1089                                 die "Unknown ",
1090                                     $_tag ? "tag" : "branch",
1091                                     " destination $_branch_dest\n";
1092                         }
1093                 }
1094         }
1095         my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
1096         my $url;
1097         if (defined $_commit_url) {
1098                 $url = $_commit_url;
1099         } else {
1100                 $url = eval { command_oneline('config', '--get',
1101                         "svn-remote.$gs->{repo_id}.commiturl") };
1102                 if (!$url) {
1103                         $url = $remote->{pushurl} || $remote->{url};
1104                 }
1105         }
1106         my $dst = join '/', $url, $lft, $branch_name, ($rgt || ());
1107
1108         if ($dst =~ /^https:/ && $src =~ /^http:/) {
1109                 $src=~s/^http:/https:/;
1110         }
1111
1112         ::_req_svn();
1113
1114         my $ctx = SVN::Client->new(
1115                 auth    => Git::SVN::Ra::_auth_providers(),
1116                 log_msg => sub {
1117                         ${ $_[0] } = defined $_message
1118                                 ? $_message
1119                                 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
1120                                 . $branch_name;
1121                 },
1122         );
1123
1124         eval {
1125                 $ctx->ls($dst, 'HEAD', 0);
1126         } and die "branch ${branch_name} already exists\n";
1127
1128         print "Copying ${src} at r${rev} to ${dst}...\n";
1129         $ctx->copy($src, $rev, $dst)
1130                 unless $_dry_run;
1131
1132         $gs->fetch_all;
1133 }
1134
1135 sub cmd_find_rev {
1136         my $revision_or_hash = shift or die "SVN or git revision required ",
1137                                             "as a command-line argument\n";
1138         my $result;
1139         if ($revision_or_hash =~ /^r\d+$/) {
1140                 my $head = shift;
1141                 $head ||= 'HEAD';
1142                 my @refs;
1143                 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
1144                 unless ($gs) {
1145                         die "Unable to determine upstream SVN information from ",
1146                             "$head history\n";
1147                 }
1148                 my $desired_revision = substr($revision_or_hash, 1);
1149                 $result = $gs->rev_map_get($desired_revision, $uuid);
1150         } else {
1151                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
1152                 $result = $rev;
1153         }
1154         print "$result\n" if $result;
1155 }
1156
1157 sub auto_create_empty_directories {
1158         my ($gs) = @_;
1159         my $var = eval { command_oneline('config', '--get', '--bool',
1160                                          "svn-remote.$gs->{repo_id}.automkdirs") };
1161         # By default, create empty directories by consulting the unhandled log,
1162         # but allow setting it to 'false' to skip it.
1163         return !($var && $var eq 'false');
1164 }
1165
1166 sub cmd_rebase {
1167         command_noisy(qw/update-index --refresh/);
1168         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1169         unless ($gs) {
1170                 die "Unable to determine upstream SVN information from ",
1171                     "working tree history\n";
1172         }
1173         if ($_dry_run) {
1174                 print "Remote Branch: " . $gs->refname . "\n";
1175                 print "SVN URL: " . $url . "\n";
1176                 return;
1177         }
1178         if (command(qw/diff-index HEAD --/)) {
1179                 print STDERR "Cannot rebase with uncommited changes:\n";
1180                 command_noisy('status');
1181                 exit 1;
1182         }
1183         unless ($_local) {
1184                 # rebase will checkout for us, so no need to do it explicitly
1185                 $_no_checkout = 'true';
1186                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
1187         }
1188         command_noisy(rebase_cmd(), $gs->refname);
1189         if (auto_create_empty_directories($gs)) {
1190                 $gs->mkemptydirs;
1191         }
1192 }
1193
1194 sub cmd_show_ignore {
1195         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1196         $gs ||= Git::SVN->new;
1197         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1198         $gs->prop_walk($gs->{path}, $r, sub {
1199                 my ($gs, $path, $props) = @_;
1200                 print STDOUT "\n# $path\n";
1201                 my $s = $props->{'svn:ignore'} or return;
1202                 $s =~ s/[\r\n]+/\n/g;
1203                 $s =~ s/^\n+//;
1204                 chomp $s;
1205                 $s =~ s#^#$path#gm;
1206                 print STDOUT "$s\n";
1207         });
1208 }
1209
1210 sub cmd_show_externals {
1211         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1212         $gs ||= Git::SVN->new;
1213         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1214         $gs->prop_walk($gs->{path}, $r, sub {
1215                 my ($gs, $path, $props) = @_;
1216                 print STDOUT "\n# $path\n";
1217                 my $s = $props->{'svn:externals'} or return;
1218                 $s =~ s/[\r\n]+/\n/g;
1219                 chomp $s;
1220                 $s =~ s#^#$path#gm;
1221                 print STDOUT "$s\n";
1222         });
1223 }
1224
1225 sub cmd_create_ignore {
1226         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1227         $gs ||= Git::SVN->new;
1228         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1229         $gs->prop_walk($gs->{path}, $r, sub {
1230                 my ($gs, $path, $props) = @_;
1231                 # $path is of the form /path/to/dir/
1232                 $path = '.' . $path;
1233                 # SVN can have attributes on empty directories,
1234                 # which git won't track
1235                 mkpath([$path]) unless -d $path;
1236                 my $ignore = $path . '.gitignore';
1237                 my $s = $props->{'svn:ignore'} or return;
1238                 open(GITIGNORE, '>', $ignore)
1239                   or fatal("Failed to open `$ignore' for writing: $!");
1240                 $s =~ s/[\r\n]+/\n/g;
1241                 $s =~ s/^\n+//;
1242                 chomp $s;
1243                 # Prefix all patterns so that the ignore doesn't apply
1244                 # to sub-directories.
1245                 $s =~ s#^#/#gm;
1246                 print GITIGNORE "$s\n";
1247                 close(GITIGNORE)
1248                   or fatal("Failed to close `$ignore': $!");
1249                 command_noisy('add', '-f', $ignore);
1250         });
1251 }
1252
1253 sub cmd_mkdirs {
1254         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1255         $gs ||= Git::SVN->new;
1256         $gs->mkemptydirs($_revision);
1257 }
1258
1259 sub canonicalize_path {
1260         my ($path) = @_;
1261         my $dot_slash_added = 0;
1262         if (substr($path, 0, 1) ne "/") {
1263                 $path = "./" . $path;
1264                 $dot_slash_added = 1;
1265         }
1266         # File::Spec->canonpath doesn't collapse x/../y into y (for a
1267         # good reason), so let's do this manually.
1268         $path =~ s#/+#/#g;
1269         $path =~ s#/\.(?:/|$)#/#g;
1270         $path =~ s#/[^/]+/\.\.##g;
1271         $path =~ s#/$##g;
1272         $path =~ s#^\./## if $dot_slash_added;
1273         $path =~ s#^/##;
1274         $path =~ s#^\.$##;
1275         return $path;
1276 }
1277
1278 sub canonicalize_url {
1279         my ($url) = @_;
1280         $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
1281         return $url;
1282 }
1283
1284 # get_svnprops(PATH)
1285 # ------------------
1286 # Helper for cmd_propget and cmd_proplist below.
1287 sub get_svnprops {
1288         my $path = shift;
1289         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1290         $gs ||= Git::SVN->new;
1291
1292         # prefix THE PATH by the sub-directory from which the user
1293         # invoked us.
1294         $path = $cmd_dir_prefix . $path;
1295         fatal("No such file or directory: $path") unless -e $path;
1296         my $is_dir = -d $path ? 1 : 0;
1297         $path = $gs->{path} . '/' . $path;
1298
1299         # canonicalize the path (otherwise libsvn will abort or fail to
1300         # find the file)
1301         $path = canonicalize_path($path);
1302
1303         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
1304         my $props;
1305         if ($is_dir) {
1306                 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
1307         }
1308         else {
1309                 (undef, $props) = $gs->ra->get_file($path, $r, undef);
1310         }
1311         return $props;
1312 }
1313
1314 # cmd_propget (PROP, PATH)
1315 # ------------------------
1316 # Print the SVN property PROP for PATH.
1317 sub cmd_propget {
1318         my ($prop, $path) = @_;
1319         $path = '.' if not defined $path;
1320         usage(1) if not defined $prop;
1321         my $props = get_svnprops($path);
1322         if (not defined $props->{$prop}) {
1323                 fatal("`$path' does not have a `$prop' SVN property.");
1324         }
1325         print $props->{$prop} . "\n";
1326 }
1327
1328 # cmd_proplist (PATH)
1329 # -------------------
1330 # Print the list of SVN properties for PATH.
1331 sub cmd_proplist {
1332         my $path = shift;
1333         $path = '.' if not defined $path;
1334         my $props = get_svnprops($path);
1335         print "Properties on '$path':\n";
1336         foreach (sort keys %{$props}) {
1337                 print "  $_\n";
1338         }
1339 }
1340
1341 sub cmd_multi_init {
1342         my $url = shift;
1343         unless (defined $_trunk || @_branches || @_tags) {
1344                 usage(1);
1345         }
1346
1347         $_prefix = '' unless defined $_prefix;
1348         if (defined $url) {
1349                 $url = canonicalize_url($url);
1350                 init_subdir(@_);
1351         }
1352         do_git_init_db();
1353         if (defined $_trunk) {
1354                 $_trunk =~ s#^/+##;
1355                 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
1356                 # try both old-style and new-style lookups:
1357                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
1358                 unless ($gs_trunk) {
1359                         my ($trunk_url, $trunk_path) =
1360                                               complete_svn_url($url, $_trunk);
1361                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
1362                                                    undef, $trunk_ref);
1363                 }
1364         }
1365         return unless @_branches || @_tags;
1366         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
1367         foreach my $path (@_branches) {
1368                 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
1369         }
1370         foreach my $path (@_tags) {
1371                 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
1372         }
1373 }
1374
1375 sub cmd_multi_fetch {
1376         $Git::SVN::no_reuse_existing = undef;
1377         my $remotes = Git::SVN::read_all_remotes();
1378         foreach my $repo_id (sort keys %$remotes) {
1379                 if ($remotes->{$repo_id}->{url}) {
1380                         Git::SVN::fetch_all($repo_id, $remotes);
1381                 }
1382         }
1383 }
1384
1385 # this command is special because it requires no metadata
1386 sub cmd_commit_diff {
1387         my ($ta, $tb, $url) = @_;
1388         my $usage = "Usage: $0 commit-diff -r<revision> ".
1389                     "<tree-ish> <tree-ish> [<URL>]";
1390         fatal($usage) if (!defined $ta || !defined $tb);
1391         my $svn_path = '';
1392         if (!defined $url) {
1393                 my $gs = eval { Git::SVN->new };
1394                 if (!$gs) {
1395                         fatal("Needed URL or usable git-svn --id in ",
1396                               "the command-line\n", $usage);
1397                 }
1398                 $url = $gs->{url};
1399                 $svn_path = $gs->{path};
1400         }
1401         unless (defined $_revision) {
1402                 fatal("-r|--revision is a required argument\n", $usage);
1403         }
1404         if (defined $_message && defined $_file) {
1405                 fatal("Both --message/-m and --file/-F specified ",
1406                       "for the commit message.\n",
1407                       "I have no idea what you mean");
1408         }
1409         if (defined $_file) {
1410                 $_message = file_to_s($_file);
1411         } else {
1412                 $_message ||= get_commit_entry($tb)->{log};
1413         }
1414         my $ra ||= Git::SVN::Ra->new($url);
1415         my $r = $_revision;
1416         if ($r eq 'HEAD') {
1417                 $r = $ra->get_latest_revnum;
1418         } elsif ($r !~ /^\d+$/) {
1419                 die "revision argument: $r not understood by git-svn\n";
1420         }
1421         my %ed_opts = ( r => $r,
1422                         log => $_message,
1423                         ra => $ra,
1424                         tree_a => $ta,
1425                         tree_b => $tb,
1426                         editor_cb => sub { print "Committed r$_[0]\n" },
1427                         svn_path => $svn_path );
1428         if (!Git::SVN::Editor->new(\%ed_opts)->apply_diff) {
1429                 print "No changes\n$ta == $tb\n";
1430         }
1431 }
1432
1433 sub escape_uri_only {
1434         my ($uri) = @_;
1435         my @tmp;
1436         foreach (split m{/}, $uri) {
1437                 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
1438                 push @tmp, $_;
1439         }
1440         join('/', @tmp);
1441 }
1442
1443 sub escape_url {
1444         my ($url) = @_;
1445         if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1446                 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1447                 $url = "$scheme://$domain$uri";
1448         }
1449         $url;
1450 }
1451
1452 sub cmd_info {
1453         my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1454         my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1455         if (exists $_[1]) {
1456                 die "Too many arguments specified\n";
1457         }
1458
1459         my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1460
1461         if (!$file_type && !$diff_status) {
1462                 print STDERR "svn: '$path' is not under version control\n";
1463                 exit 1;
1464         }
1465
1466         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1467         unless ($gs) {
1468                 die "Unable to determine upstream SVN information from ",
1469                     "working tree history\n";
1470         }
1471
1472         # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1473         $path = "." if $path eq "";
1474
1475         my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1476
1477         if ($_url) {
1478                 print escape_url($full_url), "\n";
1479                 return;
1480         }
1481
1482         my $result = "Path: $path\n";
1483         $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1484         $result .= "URL: " . escape_url($full_url) . "\n";
1485
1486         eval {
1487                 my $repos_root = $gs->repos_root;
1488                 Git::SVN::remove_username($repos_root);
1489                 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1490         };
1491         if ($@) {
1492                 $result .= "Repository Root: (offline)\n";
1493         }
1494         ::_req_svn();
1495         $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1496                 (::compare_svn_version('1.5.4') <= 0 || $file_type ne "dir");
1497         $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1498
1499         $result .= "Node Kind: " .
1500                    ($file_type eq "dir" ? "directory" : "file") . "\n";
1501
1502         my $schedule = $diff_status eq "A"
1503                        ? "add"
1504                        : ($diff_status eq "D" ? "delete" : "normal");
1505         $result .= "Schedule: $schedule\n";
1506
1507         if ($diff_status eq "A") {
1508                 print $result, "\n";
1509                 return;
1510         }
1511
1512         my ($lc_author, $lc_rev, $lc_date_utc);
1513         my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1514         my $log = command_output_pipe(@args);
1515         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1516         while (<$log>) {
1517                 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1518                         $lc_author = $1;
1519                         $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1520                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
1521                         (undef, $lc_rev, undef) = ::extract_metadata($1);
1522                 }
1523         }
1524         close $log;
1525
1526         Git::SVN::Log::set_local_timezone();
1527
1528         $result .= "Last Changed Author: $lc_author\n";
1529         $result .= "Last Changed Rev: $lc_rev\n";
1530         $result .= "Last Changed Date: " .
1531                    Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1532
1533         if ($file_type ne "dir") {
1534                 my $text_last_updated_date =
1535                     ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1536                 $result .=
1537                     "Text Last Updated: " .
1538                     Git::SVN::Log::format_svn_date($text_last_updated_date) .
1539                     "\n";
1540                 my $checksum;
1541                 if ($diff_status eq "D") {
1542                         my ($fh, $ctx) =
1543                             command_output_pipe(qw(cat-file blob), "HEAD:$path");
1544                         if ($file_type eq "link") {
1545                                 my $file_name = <$fh>;
1546                                 $checksum = md5sum("link $file_name");
1547                         } else {
1548                                 $checksum = md5sum($fh);
1549                         }
1550                         command_close_pipe($fh, $ctx);
1551                 } elsif ($file_type eq "link") {
1552                         my $file_name =
1553                             command(qw(cat-file blob), "HEAD:$path");
1554                         $checksum =
1555                             md5sum("link " . $file_name);
1556                 } else {
1557                         open FILE, "<", $path or die $!;
1558                         $checksum = md5sum(\*FILE);
1559                         close FILE or die $!;
1560                 }
1561                 $result .= "Checksum: " . $checksum . "\n";
1562         }
1563
1564         print $result, "\n";
1565 }
1566
1567 sub cmd_reset {
1568         my $target = shift || $_revision or die "SVN revision required\n";
1569         $target = $1 if $target =~ /^r(\d+)$/;
1570         $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1571         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1572         unless ($gs) {
1573                 die "Unable to determine upstream SVN information from ".
1574                     "history\n";
1575         }
1576         my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1577         die "Cannot find SVN revision $target\n" unless defined($c);
1578         $gs->rev_map_set($r, $c, 'reset', $uuid);
1579         print "r$r = $c ($gs->{ref_id})\n";
1580 }
1581
1582 sub cmd_gc {
1583         if (!can_compress()) {
1584                 warn "Compress::Zlib could not be found; unhandled.log " .
1585                      "files will not be compressed.\n";
1586         }
1587         find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1588 }
1589
1590 ########################### utility functions #########################
1591
1592 sub rebase_cmd {
1593         my @cmd = qw/rebase/;
1594         push @cmd, '-v' if $_verbose;
1595         push @cmd, qw/--merge/ if $_merge;
1596         push @cmd, "--strategy=$_strategy" if $_strategy;
1597         push @cmd, "--preserve-merges" if $_preserve_merges;
1598         @cmd;
1599 }
1600
1601 sub post_fetch_checkout {
1602         return if $_no_checkout;
1603         return if verify_ref('HEAD^0');
1604         my $gs = $Git::SVN::_head or return;
1605
1606         # look for "trunk" ref if it exists
1607         my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1608         my $fetch = $remote->{fetch};
1609         if ($fetch) {
1610                 foreach my $p (keys %$fetch) {
1611                         basename($fetch->{$p}) eq 'trunk' or next;
1612                         $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1613                         last;
1614                 }
1615         }
1616
1617         command_noisy(qw(update-ref HEAD), $gs->refname);
1618         return unless verify_ref('HEAD^0');
1619
1620         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1621         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1622         return if -f $index;
1623
1624         return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1625         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1626         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1627         print STDERR "Checked out HEAD:\n  ",
1628                      $gs->full_url, " r", $gs->last_rev, "\n";
1629         if (auto_create_empty_directories($gs)) {
1630                 $gs->mkemptydirs($gs->last_rev);
1631         }
1632 }
1633
1634 sub complete_svn_url {
1635         my ($url, $path) = @_;
1636         $path =~ s#/+$##;
1637         if ($path !~ m#^[a-z\+]+://#) {
1638                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1639                         fatal("E: '$path' is not a complete URL ",
1640                               "and a separate URL is not specified");
1641                 }
1642                 return ($url, $path);
1643         }
1644         return ($path, '');
1645 }
1646
1647 sub complete_url_ls_init {
1648         my ($ra, $repo_path, $switch, $pfx) = @_;
1649         unless ($repo_path) {
1650                 print STDERR "W: $switch not specified\n";
1651                 return;
1652         }
1653         $repo_path =~ s#/+$##;
1654         if ($repo_path =~ m#^[a-z\+]+://#) {
1655                 $ra = Git::SVN::Ra->new($repo_path);
1656                 $repo_path = '';
1657         } else {
1658                 $repo_path =~ s#^/+##;
1659                 unless ($ra) {
1660                         fatal("E: '$repo_path' is not a complete URL ",
1661                               "and a separate URL is not specified");
1662                 }
1663         }
1664         my $url = $ra->{url};
1665         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1666         my $k = "svn-remote.$gs->{repo_id}.url";
1667         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1668         if ($orig_url && ($orig_url ne $gs->{url})) {
1669                 die "$k already set: $orig_url\n",
1670                     "wanted to set to: $gs->{url}\n";
1671         }
1672         command_oneline('config', $k, $gs->{url}) unless $orig_url;
1673         my $remote_path = "$gs->{path}/$repo_path";
1674         $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1675         $remote_path =~ s#/+#/#g;
1676         $remote_path =~ s#^/##g;
1677         $remote_path .= "/*" if $remote_path !~ /\*/;
1678         my ($n) = ($switch =~ /^--(\w+)/);
1679         if (length $pfx && $pfx !~ m#/$#) {
1680                 die "--prefix='$pfx' must have a trailing slash '/'\n";
1681         }
1682         command_noisy('config',
1683                       '--add',
1684                       "svn-remote.$gs->{repo_id}.$n",
1685                       "$remote_path:refs/remotes/$pfx*" .
1686                         ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1687 }
1688
1689 sub verify_ref {
1690         my ($ref) = @_;
1691         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1692                                { STDERR => 0 }); };
1693 }
1694
1695 sub get_tree_from_treeish {
1696         my ($treeish) = @_;
1697         # $treeish can be a symbolic ref, too:
1698         my $type = command_oneline(qw/cat-file -t/, $treeish);
1699         my $expected;
1700         while ($type eq 'tag') {
1701                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1702         }
1703         if ($type eq 'commit') {
1704                 $expected = (grep /^tree /, command(qw/cat-file commit/,
1705                                                     $treeish))[0];
1706                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1707                 die "Unable to get tree from $treeish\n" unless $expected;
1708         } elsif ($type eq 'tree') {
1709                 $expected = $treeish;
1710         } else {
1711                 die "$treeish is a $type, expected tree, tag or commit\n";
1712         }
1713         return $expected;
1714 }
1715
1716 sub get_commit_entry {
1717         my ($treeish) = shift;
1718         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1719         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1720         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1721         open my $log_fh, '>', $commit_editmsg or croak $!;
1722
1723         my $type = command_oneline(qw/cat-file -t/, $treeish);
1724         if ($type eq 'commit' || $type eq 'tag') {
1725                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1726                                                          $type, $treeish);
1727                 my $in_msg = 0;
1728                 my $author;
1729                 my $saw_from = 0;
1730                 my $msgbuf = "";
1731                 while (<$msg_fh>) {
1732                         if (!$in_msg) {
1733                                 $in_msg = 1 if (/^\s*$/);
1734                                 $author = $1 if (/^author (.*>)/);
1735                         } elsif (/^git-svn-id: /) {
1736                                 # skip this for now, we regenerate the
1737                                 # correct one on re-fetch anyways
1738                                 # TODO: set *:merge properties or like...
1739                         } else {
1740                                 if (/^From:/ || /^Signed-off-by:/) {
1741                                         $saw_from = 1;
1742                                 }
1743                                 $msgbuf .= $_;
1744                         }
1745                 }
1746                 $msgbuf =~ s/\s+$//s;
1747                 if ($Git::SVN::_add_author_from && defined($author)
1748                     && !$saw_from) {
1749                         $msgbuf .= "\n\nFrom: $author";
1750                 }
1751                 print $log_fh $msgbuf or croak $!;
1752                 command_close_pipe($msg_fh, $ctx);
1753         }
1754         close $log_fh or croak $!;
1755
1756         if ($_edit || ($type eq 'tree')) {
1757                 chomp(my $editor = command_oneline(qw(var GIT_EDITOR)));
1758                 system('sh', '-c', $editor.' "$@"', $editor, $commit_editmsg);
1759         }
1760         rename $commit_editmsg, $commit_msg or croak $!;
1761         {
1762                 require Encode;
1763                 # SVN requires messages to be UTF-8 when entering the repo
1764                 local $/;
1765                 open $log_fh, '<', $commit_msg or croak $!;
1766                 binmode $log_fh;
1767                 chomp($log_entry{log} = <$log_fh>);
1768
1769                 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1770                 my $msg = $log_entry{log};
1771
1772                 eval { $msg = Encode::decode($enc, $msg, 1) };
1773                 if ($@) {
1774                         die "Could not decode as $enc:\n", $msg,
1775                             "\nPerhaps you need to set i18n.commitencoding\n";
1776                 }
1777
1778                 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1779                 die "Could not encode as UTF-8:\n$msg\n" if $@;
1780
1781                 $log_entry{log} = $msg;
1782
1783                 close $log_fh or croak $!;
1784         }
1785         unlink $commit_msg;
1786         \%log_entry;
1787 }
1788
1789 sub s_to_file {
1790         my ($str, $file, $mode) = @_;
1791         open my $fd,'>',$file or croak $!;
1792         print $fd $str,"\n" or croak $!;
1793         close $fd or croak $!;
1794         chmod ($mode &~ umask, $file) if (defined $mode);
1795 }
1796
1797 sub file_to_s {
1798         my $file = shift;
1799         open my $fd,'<',$file or croak "$!: file: $file\n";
1800         local $/;
1801         my $ret = <$fd>;
1802         close $fd or croak $!;
1803         $ret =~ s/\s*$//s;
1804         return $ret;
1805 }
1806
1807 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1808 sub load_authors {
1809         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1810         my $log = $cmd eq 'log';
1811         while (<$authors>) {
1812                 chomp;
1813                 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1814                 my ($user, $name, $email) = ($1, $2, $3);
1815                 if ($log) {
1816                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1817                 } else {
1818                         $users{$user} = [$name, $email];
1819                 }
1820         }
1821         close $authors or croak $!;
1822 }
1823
1824 # convert GetOpt::Long specs for use by git-config
1825 sub read_git_config {
1826         my $opts = shift;
1827         my @config_only;
1828         foreach my $o (keys %$opts) {
1829                 # if we have mixedCase and a long option-only, then
1830                 # it's a config-only variable that we don't need for
1831                 # the command-line.
1832                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1833                 my $v = $opts->{$o};
1834                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1835                 $key =~ s/-//g;
1836                 my $arg = 'git config';
1837                 $arg .= ' --int' if ($o =~ /[:=]i$/);
1838                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1839                 if (ref $v eq 'ARRAY') {
1840                         chomp(my @tmp = `$arg --get-all svn.$key`);
1841                         @$v = @tmp if @tmp;
1842                 } else {
1843                         chomp(my $tmp = `$arg --get svn.$key`);
1844                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1845                                 $$v = $tmp;
1846                         }
1847                 }
1848         }
1849         delete @$opts{@config_only} if @config_only;
1850 }
1851
1852 sub extract_metadata {
1853         my $id = shift or return (undef, undef, undef);
1854         my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1855                                                         \s([a-f\d\-]+)$/ix);
1856         if (!defined $rev || !$uuid || !$url) {
1857                 # some of the original repositories I made had
1858                 # identifiers like this:
1859                 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1860         }
1861         return ($url, $rev, $uuid);
1862 }
1863
1864 sub cmt_metadata {
1865         return extract_metadata((grep(/^git-svn-id: /,
1866                 command(qw/cat-file commit/, shift)))[-1]);
1867 }
1868
1869 sub cmt_sha2rev_batch {
1870         my %s2r;
1871         my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1872         my $list = shift;
1873
1874         foreach my $sha (@{$list}) {
1875                 my $first = 1;
1876                 my $size = 0;
1877                 print $out $sha, "\n";
1878
1879                 while (my $line = <$in>) {
1880                         if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1881                                 last;
1882                         } elsif ($first &&
1883                                $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1884                                 $first = 0;
1885                                 $size = $1;
1886                                 next;
1887                         } elsif ($line =~ /^(git-svn-id: )/) {
1888                                 my (undef, $rev, undef) =
1889                                                       extract_metadata($line);
1890                                 $s2r{$sha} = $rev;
1891                         }
1892
1893                         $size -= length($line);
1894                         last if ($size == 0);
1895                 }
1896         }
1897
1898         command_close_bidi_pipe($pid, $in, $out, $ctx);
1899
1900         return \%s2r;
1901 }
1902
1903 sub working_head_info {
1904         my ($head, $refs) = @_;
1905         my @args = qw/rev-list --first-parent --pretty=medium/;
1906         my ($fh, $ctx) = command_output_pipe(@args, $head);
1907         my $hash;
1908         my %max;
1909         while (<$fh>) {
1910                 if ( m{^commit ($::sha1)$} ) {
1911                         unshift @$refs, $hash if $hash and $refs;
1912                         $hash = $1;
1913                         next;
1914                 }
1915                 next unless s{^\s*(git-svn-id:)}{$1};
1916                 my ($url, $rev, $uuid) = extract_metadata($_);
1917                 if (defined $url && defined $rev) {
1918                         next if $max{$url} and $max{$url} < $rev;
1919                         if (my $gs = Git::SVN->find_by_url($url)) {
1920                                 my $c = $gs->rev_map_get($rev, $uuid);
1921                                 if ($c && $c eq $hash) {
1922                                         close $fh; # break the pipe
1923                                         return ($url, $rev, $uuid, $gs);
1924                                 } else {
1925                                         $max{$url} ||= $gs->rev_map_max;
1926                                 }
1927                         }
1928                 }
1929         }
1930         command_close_pipe($fh, $ctx);
1931         (undef, undef, undef, undef);
1932 }
1933
1934 sub read_commit_parents {
1935         my ($parents, $c) = @_;
1936         chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1937         $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1938         @{$parents->{$c}} = split(/ /, $p);
1939 }
1940
1941 sub linearize_history {
1942         my ($gs, $refs) = @_;
1943         my %parents;
1944         foreach my $c (@$refs) {
1945                 read_commit_parents(\%parents, $c);
1946         }
1947
1948         my @linear_refs;
1949         my %skip = ();
1950         my $last_svn_commit = $gs->last_commit;
1951         foreach my $c (reverse @$refs) {
1952                 next if $c eq $last_svn_commit;
1953                 last if $skip{$c};
1954
1955                 unshift @linear_refs, $c;
1956                 $skip{$c} = 1;
1957
1958                 # we only want the first parent to diff against for linear
1959                 # history, we save the rest to inject when we finalize the
1960                 # svn commit
1961                 my $fp_a = verify_ref("$c~1");
1962                 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1963                 if (!$fp_a || !$fp_b) {
1964                         die "Commit $c\n",
1965                             "has no parent commit, and therefore ",
1966                             "nothing to diff against.\n",
1967                             "You should be working from a repository ",
1968                             "originally created by git-svn\n";
1969                 }
1970                 if ($fp_a ne $fp_b) {
1971                         die "$c~1 = $fp_a, however parsing commit $c ",
1972                             "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1973                 }
1974
1975                 foreach my $p (@{$parents{$c}}) {
1976                         $skip{$p} = 1;
1977                 }
1978         }
1979         (\@linear_refs, \%parents);
1980 }
1981
1982 sub find_file_type_and_diff_status {
1983         my ($path) = @_;
1984         return ('dir', '') if $path eq '';
1985
1986         my $diff_output =
1987             command_oneline(qw(diff --cached --name-status --), $path) || "";
1988         my $diff_status = (split(' ', $diff_output))[0] || "";
1989
1990         my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1991
1992         return (undef, undef) if !$diff_status && !$ls_tree;
1993
1994         if ($diff_status eq "A") {
1995                 return ("link", $diff_status) if -l $path;
1996                 return ("dir", $diff_status) if -d $path;
1997                 return ("file", $diff_status);
1998         }
1999
2000         my $mode = (split(' ', $ls_tree))[0] || "";
2001
2002         return ("link", $diff_status) if $mode eq "120000";
2003         return ("dir", $diff_status) if $mode eq "040000";
2004         return ("file", $diff_status);
2005 }
2006
2007 sub md5sum {
2008         my $arg = shift;
2009         my $ref = ref $arg;
2010         my $md5 = Digest::MD5->new();
2011         if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
2012                 $md5->addfile($arg) or croak $!;
2013         } elsif ($ref eq 'SCALAR') {
2014                 $md5->add($$arg) or croak $!;
2015         } elsif (!$ref) {
2016                 $md5->add($arg) or croak $!;
2017         } else {
2018                 fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
2019         }
2020         return $md5->hexdigest();
2021 }
2022
2023 sub gc_directory {
2024         if (can_compress() && -f $_ && basename($_) eq "unhandled.log") {
2025                 my $out_filename = $_ . ".gz";
2026                 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
2027                 binmode $in_fh;
2028                 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
2029                                 die "Unable to open $out_filename: $!\n";
2030
2031                 my $res;
2032                 while ($res = sysread($in_fh, my $str, 1024)) {
2033                         $gz->gzwrite($str) or
2034                                 die "Unable to write: ".$gz->gzerror()."!\n";
2035                 }
2036                 unlink $_ or die "unlink $File::Find::name: $!\n";
2037         } elsif (-f $_ && basename($_) eq "index") {
2038                 unlink $_ or die "unlink $_: $!\n";
2039         }
2040 }
2041
2042
2043 package Git::IndexInfo;
2044 use strict;
2045 use warnings;
2046 use Git qw/command_input_pipe command_close_pipe/;
2047
2048 sub new {
2049         my ($class) = @_;
2050         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
2051         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
2052 }
2053
2054 sub remove {
2055         my ($self, $path) = @_;
2056         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
2057                 return ++$self->{nr};
2058         }
2059         undef;
2060 }
2061
2062 sub update {
2063         my ($self, $mode, $hash, $path) = @_;
2064         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
2065                 return ++$self->{nr};
2066         }
2067         undef;
2068 }
2069
2070 sub DESTROY {
2071         my ($self) = @_;
2072         command_close_pipe($self->{gui}, $self->{ctx});
2073 }
2074
2075 package Git::SVN::GlobSpec;
2076 use strict;
2077 use warnings;
2078
2079 sub new {
2080         my ($class, $glob, $pattern_ok) = @_;
2081         my $re = $glob;
2082         $re =~ s!/+$!!g; # no need for trailing slashes
2083         my (@left, @right, @patterns);
2084         my $state = "left";
2085         my $die_msg = "Only one set of wildcard directories " .
2086                                 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
2087         for my $part (split(m|/|, $glob)) {
2088                 if ($part =~ /\*/ && $part ne "*") {
2089                         die "Invalid pattern in '$glob': $part\n";
2090                 } elsif ($pattern_ok && $part =~ /[{}]/ &&
2091                          $part !~ /^\{[^{}]+\}/) {
2092                         die "Invalid pattern in '$glob': $part\n";
2093                 }
2094                 if ($part eq "*") {
2095                         die $die_msg if $state eq "right";
2096                         $state = "pattern";
2097                         push(@patterns, "[^/]*");
2098                 } elsif ($pattern_ok && $part =~ /^\{(.*)\}$/) {
2099                         die $die_msg if $state eq "right";
2100                         $state = "pattern";
2101                         my $p = quotemeta($1);
2102                         $p =~ s/\\,/|/g;
2103                         push(@patterns, "(?:$p)");
2104                 } else {
2105                         if ($state eq "left") {
2106                                 push(@left, $part);
2107                         } else {
2108                                 push(@right, $part);
2109                                 $state = "right";
2110                         }
2111                 }
2112         }
2113         my $depth = @patterns;
2114         if ($depth == 0) {
2115                 die "One '*' is needed in glob: '$glob'\n";
2116         }
2117         my $left = join('/', @left);
2118         my $right = join('/', @right);
2119         $re = join('/', @patterns);
2120         $re = join('\/',
2121                    grep(length, quotemeta($left), "($re)", quotemeta($right)));
2122         my $left_re = qr/^\/\Q$left\E(\/|$)/;
2123         bless { left => $left, right => $right, left_regex => $left_re,
2124                 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
2125 }
2126
2127 sub full_path {
2128         my ($self, $path) = @_;
2129         return (length $self->{left} ? "$self->{left}/" : '') .
2130                $path . (length $self->{right} ? "/$self->{right}" : '');
2131 }
2132
2133 __END__
2134
2135 Data structures:
2136
2137
2138 $remotes = { # returned by read_all_remotes()
2139         'svn' => {
2140                 # svn-remote.svn.url=https://svn.musicpd.org
2141                 url => 'https://svn.musicpd.org',
2142                 # svn-remote.svn.fetch=mpd/trunk:trunk
2143                 fetch => {
2144                         'mpd/trunk' => 'trunk',
2145                 },
2146                 # svn-remote.svn.tags=mpd/tags/*:tags/*
2147                 tags => {
2148                         path => {
2149                                 left => 'mpd/tags',
2150                                 right => '',
2151                                 regex => qr!mpd/tags/([^/]+)$!,
2152                                 glob => 'tags/*',
2153                         },
2154                         ref => {
2155                                 left => 'tags',
2156                                 right => '',
2157                                 regex => qr!tags/([^/]+)$!,
2158                                 glob => 'tags/*',
2159                         },
2160                 }
2161         }
2162 };
2163
2164 $log_entry hashref as returned by libsvn_log_entry()
2165 {
2166         log => 'whitespace-formatted log entry
2167 ',                                              # trailing newline is preserved
2168         revision => '8',                        # integer
2169         date => '2004-02-24T17:01:44.108345Z',  # commit date
2170         author => 'committer name'
2171 };
2172
2173
2174 # this is generated by generate_diff();
2175 @mods = array of diff-index line hashes, each element represents one line
2176         of diff-index output
2177
2178 diff-index line ($m hash)
2179 {
2180         mode_a => first column of diff-index output, no leading ':',
2181         mode_b => second column of diff-index output,
2182         sha1_b => sha1sum of the final blob,
2183         chg => change type [MCRADT],
2184         file_a => original file name of a file (iff chg is 'C' or 'R')
2185         file_b => new/current file name of a file (any chg)
2186 }
2187 ;
2188
2189 # retval of read_url_paths{,_all}();
2190 $l_map = {
2191         # repository root url
2192         'https://svn.musicpd.org' => {
2193                 # repository path               # GIT_SVN_ID
2194                 'mpd/trunk'             =>      'trunk',
2195                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
2196         },
2197 }
2198
2199 Notes:
2200         I don't trust the each() function on unless I created %hash myself
2201         because the internal iterator may not have started at base.