games-util/xboxdrv/xboxdrv-0.8.8_p20190118.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python2_7 python3_6 )
   7
   8 inherit linux-info python-any-r1 scons-utils toolchain-funcs systemd udev
   9
  10 COMMIT="6e5e8a57628095d8d0c8bbb38187afb0f3a42112"
  11 DESCRIPTION="Userspace Xbox 360 Controller driver"
  12 HOMEPAGE="https://xboxdrv.gitlab.io"
  13 SRC_URI="https://github.com/chewi/xboxdrv/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17
  18 RDEPEND="
  19         dev-libs/boost:=
  20         dev-libs/dbus-glib
  21         dev-libs/glib:2
  22         sys-apps/dbus
  23         virtual/libudev:=
  24         virtual/libusb:1
  25         x11-libs/libX11
  26 "
  27
  28 DEPEND="
  29         ${RDEPEND}
  30 "
  31
  32 BDEPEND="
  33         dev-util/glib-utils
  34         virtual/pkgconfig
  35 "
  36
  37 S="${WORKDIR}/${PN}-${COMMIT}"
  38
  39 CONFIG_CHECK="~INPUT_EVDEV ~INPUT_JOYDEV ~INPUT_UINPUT ~!JOYSTICK_XPAD"
  40
  41 src_prepare() {
  42         default
  43
  44         # Make it clearer that this is a patched fork.
  45         echo -n "${PV%_*}.${PV#*_p}-gentoo" > VERSION || die
  46 }
  47
  48 src_compile() {
  49         escons \
  50                 BUILD=custom \
  51                 CXX="$(tc-getCXX)" \
  52                 AR="$(tc-getAR)" \
  53                 RANLIB="$(tc-getRANLIB)" \
  54                 CXXFLAGS="-Wall ${CXXFLAGS}" \
  55                 LINKFLAGS="${LDFLAGS}"
  56 }
  57
  58 src_install() {
  59         dobin xboxdrv
  60         doman doc/xboxdrv.1
  61         dodoc AUTHORS NEWS PROTOCOL README.md TODO
  62
  63         newinitd "${FILESDIR}"/xboxdrv.initd xboxdrv
  64         newconfd "${FILESDIR}"/xboxdrv.confd xboxdrv
  65
  66         insinto /etc/dbus-1/system.d
  67         doins "${FILESDIR}"/org.seul.Xboxdrv.conf
  68
  69         udev_newrules "${FILESDIR}"/xboxdrv.udev-rules 99-xbox-controller.rules
  70         systemd_dounit "${FILESDIR}"/xboxdrv.service
  71 }
  72
  73 pkg_postinst() {
  74         udev_reload
  75 }