games-util/springlobby/springlobby-0.269.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 WX_GTK_VER="3.0"
   7 inherit cmake xdg-utils wxwidgets
   8
   9 DESCRIPTION="The official lobby client for SpringRTS community games"
  10 HOMEPAGE="https://springlobby.springrts.com"
  11 SRC_URI="https://springlobby.springrts.com/dl/stable/${P}.tar.bz2"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="debug +libnotify +nls +sound"
  17
  18 RDEPEND="
  19         dev-libs/openssl:0=
  20         net-misc/curl
  21         sys-libs/zlib[minizip]
  22         x11-libs/libICE
  23         x11-libs/libSM
  24         x11-libs/libXext
  25         x11-libs/wxGTK:${WX_GTK_VER}[X]
  26         libnotify? ( x11-libs/libnotify )
  27         sound? (
  28                 media-libs/alure
  29                 media-libs/openal
  30         )
  31 "
  32
  33 DEPEND="${RDEPEND}"
  34
  35 BDEPEND="nls? ( sys-devel/gettext )"
  36
  37 src_configure() {
  38         setup-wxwidgets
  39         local mycmakeargs=(
  40                 -DOPTION_NOTIFY=$(usex libnotify)
  41                 -DOPTION_SOUND=$(usex sound)
  42                 -DOPTION_TRANSLATION_SUPPORT=$(usex nls)
  43                 -DAUX_VERSION="(Gentoo,${ARCH})"
  44                 )
  45         cmake_src_configure
  46 }
  47
  48 pkg_postinst() {
  49         xdg_icon_cache_update
  50 }
  51
  52 pkg_postrm() {
  53         xdg_icon_cache_update
  54 }