games-strategy/warmux/warmux-11.04.1-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools eutils
   7
   8 DESCRIPTION="A free Worms clone"
   9 HOMEPAGE="http://gna.org/projects/warmux/"
  10 SRC_URI="http://download.gna.org/warmux/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
  15 IUSE="debug nls unicode"
  16
  17 RDEPEND="
  18         dev-libs/libxml2
  19         media-libs/libsdl[joystick,video,X]
  20         media-libs/sdl-image[jpeg,png]
  21         media-libs/sdl-mixer[vorbis]
  22         media-libs/sdl-ttf
  23         media-libs/sdl-net
  24         media-libs/sdl-gfx
  25         media-fonts/dejavu
  26         net-misc/curl
  27         x11-libs/libX11
  28         nls? ( virtual/libintl )
  29         unicode? ( dev-libs/fribidi )"
  30 DEPEND="${RDEPEND}
  31         virtual/pkgconfig
  32         nls? ( sys-devel/gettext )"
  33
  34 S=${WORKDIR}/${PN}-11.04
  35
  36 PATCHES=(
  37         "${FILESDIR}"/${P}-gentoo.patch
  38         "${FILESDIR}"/${P}-zlib.patch
  39         "${FILESDIR}"/${P}-action.patch
  40         "${FILESDIR}"/${P}-gcc47.patch
  41         "${FILESDIR}"/${P}-stat.patch
  42         "${FILESDIR}"/${P}-fix-c++14.patch
  43 )
  44
  45 src_prepare() {
  46         default
  47         eautoreconf
  48 }
  49
  50 src_configure() {
  51         econf \
  52                 --with-localedir-name="${EPREFIX}"/usr/share/locale \
  53                 --with-datadir-name="${EPREFIX}"/usr/share/${PN} \
  54                 --with-font-path="${EPREFIX}"/usr/share/fonts/dejavu/DejaVuSans.ttf \
  55                 $(use_enable debug) \
  56                 $(use_enable nls) \
  57                 $(use_enable unicode fribidi)
  58 }
  59
  60 src_install() {
  61         default
  62
  63         rm -f "${ED%/}"/usr/share/${PN}/font/DejaVuSans.ttf || die
  64         doicon data/icon/warmux.svg
  65         make_desktop_entry warmux Warmux
  66 }