games-strategy/wargus-data/wargus-data-0-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cdrom
   7
   8 DESCRIPTION="Warcraft II data for wargus (needs DOS CD)"
   9 HOMEPAGE="http://wargus.sourceforge.net/"
  10 SRC_URI=""
  11
  12 LICENSE="all-rights-reserved"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE=""
  16
  17 # wargus is needed for wartool (bug #578340)
  18 DEPEND="
  19         games-strategy/wargus
  20         media-sound/cdparanoia
  21         media-sound/timidity++
  22         media-video/ffmpeg2theora"
  23 # wrt bug #419331
  24 RESTRICT="userpriv"
  25
  26 S=${WORKDIR}
  27
  28 src_configure() {
  29         export CDROM_NAME="WARCRAFT2"
  30         cdrom_get_cds data/rezdat.war
  31 }
  32
  33 src_compile() {
  34         # cdparanoia needs write acces to the cdrom device
  35         # this fixes sandbox violation wrt #418051
  36         local save_sandbox_write=${SANDBOX_WRITE}
  37         addwrite /dev
  38         "${EPREFIX}"/usr/bin/wartool -v -r "${CDROM_ROOT}"/data "${S}"/ || die
  39         SANDBOX_WRITE=${save_sandbox_write}
  40 }
  41
  42 src_install() {
  43         insinto /usr/share/stratagus/wargus
  44         doins -r .
  45 }