games-strategy/scorched3d/scorched3d-44-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 WX_GTK_VER=3.0
   7
   8 inherit autotools eutils wxwidgets
   9
  10 DESCRIPTION="Multi-player tank battle in 3D (OpenGL)"
  11 HOMEPAGE="http://www.scorched3d.co.uk/"
  12 SRC_URI="mirror://sourceforge/scorched3d/Scorched3D-${PV}-src.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~ppc64 ~x86"
  17 IUSE="dedicated mysql"
  18
  19 RDEPEND="
  20         dev-libs/expat
  21         media-fonts/dejavu
  22         media-libs/libpng:0=
  23         media-libs/libsdl[video]
  24         media-libs/sdl-net
  25         sys-libs/zlib
  26         virtual/jpeg:0
  27         !dedicated? (
  28                 virtual/opengl
  29                 virtual/glu
  30                 media-libs/glew:0=
  31                 media-libs/libogg
  32                 media-libs/libvorbis
  33                 media-libs/openal
  34                 media-libs/freealut
  35                 x11-libs/wxGTK:${WX_GTK_VER}[X]
  36                 media-libs/freetype:2
  37                 sci-libs/fftw:3.0=
  38         )
  39         mysql? ( virtual/mysql )"
  40 DEPEND="${RDEPEND}
  41         !dedicated? ( virtual/pkgconfig )"
  42
  43 S=${WORKDIR}/scorched
  44
  45 PATCHES=(
  46         "${FILESDIR}"/${P}-fixups.patch
  47         "${FILESDIR}"/${P}-gcc43.patch
  48         "${FILESDIR}"/${P}-odbc.patch
  49         "${FILESDIR}"/${P}-win32.patch
  50         "${FILESDIR}"/${P}-freetype.patch
  51         "${FILESDIR}"/${P}-jpeg9.patch
  52         "${FILESDIR}"/${P}-wxgtk.patch
  53         "${FILESDIR}"/${P}-fix-c++14.patch
  54 )
  55
  56 pkg_setup() {
  57         setup-wxwidgets
  58 }
  59
  60 src_prepare() {
  61         edos2unix \
  62                 src/launcher/wxdialogs/SettingsDialog.cpp \
  63                 src/launcher/wxdialogs/DisplayDialog.cpp \
  64                 src/launcher/wxdialogs/Display.cpp \
  65                 src/launcher/wxdialogs/KeyDialog.cpp
  66         default
  67         eautoreconf
  68 }
  69
  70 src_configure() {
  71         econf \
  72                 --datadir="${EPREFIX}"/usr/share/${PN} \
  73                 --with-fftw="${EPREFIX}"/usr \
  74                 --with-ogg="${EPREFIX}"/usr \
  75                 --with-vorbis="${EPREFIX}"/usr \
  76                 --with-docdir="${EPREFIX}"/usr/share/doc/${PF} \
  77                 --with-wx-config="${WX_CONFIG}" \
  78                 --without-pgsql \
  79                 $(use_with mysql) \
  80                 $(use_enable dedicated serveronly)
  81 }
  82
  83 src_install() {
  84         default
  85
  86         # remove bundled fonts
  87         rm "${ED%/}"/usr/share/${PN}/data/fonts/* || die
  88         dosym ../../../fonts/dejavu/DejaVuSans.ttf /usr/share/${PN}/data/fonts/dejavusans.ttf
  89         dosym ../../../fonts/dejavu/DejaVuSansCondensed-Bold.ttf /usr/share/${PN}/data/fonts/dejavusconbd.ttf
  90         dosym ../../../fonts/dejavu/DejaVuSansMono-Bold.ttf /usr/share/${PN}/data/fonts/dejavusmobd.ttf
  91
  92         if ! use dedicated; then
  93                 newicon data/images/tank-old.bmp ${PN}.bmp
  94                 make_desktop_entry ${PN} "Scorched 3D" /usr/share/pixmaps/${PN}.bmp
  95         fi
  96 }