games-strategy/satellite-reign/satellite-reign-1.13.06.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit eutils desktop xdg-utils
   7
   8 MY_PN="SatelliteReignLinux"
   9 MY_PV="${PV/.}"
  10 MY_PV="0${MY_PV/./_}"
  11
  12 DESCRIPTION="Real-time, class-based strategy game set in a cyberpunk city"
  13 HOMEPAGE="http://satellitereign.com/"
  14 SRC_URI="${MY_PN}${MY_PV}.zip"
  15 LICENSE="all-rights-reserved"
  16 SLOT="0"
  17 KEYWORDS="-* ~amd64 ~x86"
  18 IUSE="+gui"
  19 RESTRICT="bindist fetch splitdebug"
  20
  21 BDEPEND="app-arch/unzip"
  22
  23 RDEPEND="
  24         virtual/opengl
  25         x11-libs/libX11
  26         x11-libs/libXcursor
  27         x11-libs/libXrandr
  28         gui? (
  29                 dev-libs/glib:2
  30                 x11-libs/gdk-pixbuf:2
  31                 x11-libs/gtk+:2
  32         )
  33 "
  34
  35 S="${WORKDIR}"
  36
  37 DIR="/opt/${PN}"
  38 QA_PREBUILT="${DIR}/*"
  39
  40 pkg_nofetch() {
  41         einfo "Please buy and download ${SRC_URI} from:"
  42         einfo "  https://www.humblebundle.com/store/${PN}"
  43         einfo "and move it to your distfiles directory."
  44 }
  45
  46 src_install() {
  47         exeinto "${DIR}"
  48         newexe ${MY_PN}.$(usex amd64 x86_64 x86) ${MY_PN}
  49         make_wrapper ${PN} "${DIR}"/${MY_PN}
  50
  51         insinto "${DIR}"
  52         doins -r ${MY_PN}_Data/
  53         rm -r "${ED}/${DIR}"/${MY_PN}_Data/*/$(usex amd64 x86 x86_64) || die
  54
  55         if ! use gui; then
  56                 rm "${ED}/${DIR}"/${MY_PN}_Data/Plugins/*/ScreenSelector.so || die
  57         fi
  58
  59         newicon -s 128 ${MY_PN}_Data/Resources/UnityPlayer.png ${PN}.png
  60         make_desktop_entry ${PN} "Satellite Reign"
  61 }
  62
  63 pkg_postinst() { xdg_icon_cache_update; }
  64 pkg_postrm() { xdg_icon_cache_update; }